Заполнить массив и записать в файл

[Amery]

Здравствуйте! Буду очень благодарна, если поможете.. как делать - ума не приложу(((
Нужно заполнить массив случайными числами (-200..200) и записать в файл

в Delphi это делала так:

procedure Run;
const rndnum=400;
var i ,cc: integer;
    a: array [1..rndnum] of integer;
    f: Textfile;
begin
randomize;
 for I:=1 to rndnum  do
 a[i]:= random(rndnum)-200;

 Assignfile(f, 'rnd.txt');
 ReWrite(f);
	cc:= 0 ;
  Writeln(f,'Rnd dw ' );
	for I:= 1 to rndnum do
   Begin
		IF cc=0 THEN
		 write(f, 'dw ', a[i])
		ELSE
		 write(f, ', ', a[i]);
    cc:=cc+1;
    if cc = 10 then
    Begin
    writeln (f);
    cc:=0;
    end;
    end;
   closefile(f);
end;

[B_N]

С чем именно сложности? Со случайными числами или с файлами7

[Amery]

проблема как записать в файл и с массивом тоже... код компилится но не работает

.model tiny
.code
.386
max equ 20
org 100h
start:
  mov ax, 3
  int 10h

; заполнение с помощью простейшего 
; генератора случайных чисел
  push 040h
  pop  es
  mov  dx, es:[6Ch] ; тики
  lea  di, ar 
  mov  cx, max
fill_Random:
  imul dx, 4e35h ; можно взять любое большое  
  mov  [di], dl
  inc  di
  LOOP fill_Random

; показ
  mov  cx, max
  lea  di, ar
 @1:
  mov  al, [di]
  CALL showDEC
  inc di
  LOOP @1

  int 20h
showDEC proc ; число в AL
 push ax
 push bx
 push cx
  xor cx, cx
  mov bl, 10
 @2:
  inc cx
  xor ah, ah
  div bl
  push ax
  or al, al
  jnz @2

 @3:
  pop ax
  mov al, ah
  add al, '0'
  int 29h
  LOOP @3

  mov al, ' '
  int 29h
  
 pop  cx
 pop  bx
 pop  ax
 ret
showDEC endp

ar db max dup(?)
end start

[Stilet]

проблема как записать в файл

для Int 21h
есть функи:
3dh - Открыть файл
3eh - закрыть
40h - писать

[B_N]

Сообщение от Amery

и с массивом тоже... код компилится но не работает

В смысле? Это

205 113 101 233 61 161 85 153 173 209 69 73 29 1 53 249 141 49 37 169

не тот результат, которого Вы ждёте?

[Amery]

у меня файл запускается и сразу закрывается(

[Amery]

поняла почему не показывало))))

[Amery]

у меня даже файл создать не получается(((
Может у кого есть пример, чтобы выдавал результат как прога на delphi?

[B_N]

Сообщение от Amery

у меня даже файл создать не получается(((
Может у кого есть пример, чтобы выдавал результат как прога на delphi?

Amery, Вы, если что-то не выходит, лучше выкладывайте сразу свой код. На такие общефилософские вопросы зачастую и не знаешь как ответить, меньше чем на страницу, да и вполне может быть, что Вы ошиблись в одной букве, а искать (тем более - писать) готовый пример может быть долго или просто некогда. Ниже пример записи в файл. (DOS, TASM)

			.model small
			.code
program:
			JMP			l_start

FILENAME	DB 'C:\HELLO.TXT', 0
FILETEXT	DB 'Hello, World!', 0
FILEHANDLE	DW ?
ERRORTEXT	DB 'Error!$'

l_start:
			PUSH		DS
			PUSH		ES
			
			MOV			AX, CS
			MOV			DS, AX
			MOV			ES, AX
			
			; Открываем файл
			
			XOR			CX, CX
			LEA			DX, FILENAME
			MOV			AH, 3Ch
			INT 		21h
			
			JC			l_error
			
			MOV			FILEHANDLE, AX
			
			; Находим длину строки
			
			LEA			DI, FILETEXT
			XOR			AX, AX
			MOV			CX, 255
			CLD
			REPNZ SCASB
			SUB			CX, 255
			NEG			CX
			DEC			CX
			CMP			CX, 0
			JB			l_error
			
			; Записываем строку в файл
			
			MOV			BX, FILEHANDLE
			MOV			AH, 40h
			LEA			DX, FILETEXT
			INT			21h
			
			JC			l_error
			
			; Закрываем файл
			
			MOV			BX, FILEHANDLE
			MOV			AH, 3Eh
			INT			21h	

			JC			l_error

			; выходим
l_exit:
			POP			ES
			POP			DS
			retf
l_error:
			; печатаем сообщение об ошибке
			
			LEA			DX, ERRORTEXT
			MOV			AH, 09h
			INT			21h
			JMP			l_exit

end program

[Amery]

спасибо, все получилось)