Копировать диапазон и отдельные столбцы

[Arimle]

Здравствуйте,

Мне надо при нажатие "Button 1" в книге K3.XLSM некоторые данные копировался в другую книгу. Я старался кое-что делать, но некоторые вещи не получается. А именно,
1) Могу копировать диапазон, но не получается отдельные столбцы копировать. (Надо желтые столбцы копировать в другой лист)
2) В K3.XLSM количество записей может быть разные. Динамические диапазоны как можно копировать?
3) При копирование не получается "Insert". T.e., копируемые записи больше 5-ти тогда в книге "ЕH" "Total" не видно будет
4) Как можно в книге "ЕH" программно добавить формулу для всех копируемый записей ?

Помогите пожалуйста, как можно делать такое?

[IgorGO]

откладывайте деньги. решение не за горами

[Arimle]

Сообщение от IgorGO

откладывайте деньги. решение не за горами

Спасибо, IgorGO за ответь.
Но, дело не в денгах. Я сам хочу понять и делать.

[Arimle]

Я сейчас могу копировать отдельные столбцы, которые нужны мне. Но, insert не получается. Мне надо делать так что после insert данные в столбцы C, D, E и F в книге "EH" автоматически добавлялся и другие столбцы (G, H, I, …. U), где есть формулы. Можно
ли делать такое?

[Elixi]

Arimle,
честно скажу, что мне не понятно, что вам надо. Разбираться в вашем проекте что там и как сделано и где и что не получается, уж извините, нет время. Если что-то сказать к этому:

Сообщение от Arimle

Я сейчас могу копировать отдельные столбцы, которые нужны мне. Но, insert не получается

то пустые столбцы можно вставить например так:

    Columns("F:I").Insert Shift:=xlToRight

столбцы вставлены, теперь можете в них копировать ваши данные

[Arimle]

Спасибо, Elixi за ответ.
Еще раз попробую обяснить что у меня не получается.

Мне надо из K3.XLSM копировать некоторые столбцы (B, D, G, H) в EH.XLSX (в C, D, E, F). Это у меня получается.
В EH.XLSX есть данные и формулы. Количество копируемые записи может быть разные. При копирование столбцы в EH.XLSX надо добавить строки (где есть формулы), столко раз сколько добавился из K3.XLSM. Вот это у меня не получается.

Код который Вы предлагаете добавляет новые столбцы. Но, у меня есть столбцы, надо добавлять туда данные из K3.XLSM. Здесь проблема нету.
Проблема в том что, надо добавить строки где есть формулы, столко раз сколько добавился из K3.XLSM.

[Elixi]

Arimle,

Sub Makro1()
'   Если копировать прямо из листа в лист, можно таким образом.
'   Но сомневаюсь, что вам нужно именно это.

Dim RwFI As Long, RwK As Long, RwLI As Long
Dim Исходная As Excel.Worksheet, Конечная As Excel.Worksheet

'   1. У меня книги уже открыты. 2. Почему не работать прямо с листами?
Set Исходная = Workbooks("k3.xlsm").Worksheets("Rabotniki")
Set Конечная = Workbooks("EH.xlsx").Worksheets("EH")

RwFI = 3:
RwLI = Исходная.Cells(Исходная.Rows.Count, "B").End(xlUp).Row
RwK = Конечная.Cells(Конечная.Rows.Count, "B").End(xlUp).Row

For Rw = RwFI To RwLI
    With Конечная
        .Rows(RwK & ":" & RwK).Insert Shift:=xlDown
        .Cells(RwK, "C") = Исходная.Cells(Rw, "B")
        .Cells(RwK, "D") = Исходная.Cells(Rw, "H")
        .Cells(RwK, "E") = Исходная.Cells(Rw, "D")
        '   у вас там в исходнике оклад с точками, надо очищать
        .Cells(RwK, "F") = Replace(Replace(Исходная.Cells(Rw, "G"), _
                ".", ""), ",", ".")
        .Cells(RwK, "F").NumberFormat = "0.00"
        .Cells(RwK, "G") = 144
        .Cells(RwK, "H") = 150  '   что и откуда вставлять, знаете вы
        .Cells(RwK, "I").Formula = "=F" & RwK & "/G" & RwK & "*H" & RwK
        .Cells(RwK, "L").Formula = "=SUM(I" & RwK & ":K" & RwK & ")"
        .Cells(RwK, "N").Formula = "=IF(L" & RwK & "<=200,L" & RwK & _
                "*3%,IF(L" & RwK & ">200,6+(L" & RwK & "-200)*10%))"
        '   остальные формулы надо доработать...
        RwK = RwK + 1
    End With
Next Rw

End Sub

[Arimle]

Спасибо Вам, Elixi.
Вы очень помогли мне.

Только, у меня в этот момент EH.xlsx не открыта. По этому я открыл этот файл. Незнаю на столько правильно?

Dim Исходная As Excel.Worksheet, Конечная As Excel.Worksheet, КонечнаяWB As Excel.Workbook
'   1. У меня книги уже открыты. 2. Почему не работать прямо с листами?
Set КонечнаяWB = Workbooks.Open("D:\Vergi\kadr3\EH.xlsx")
Set Исходная = Workbooks("k3.xlsm").Worksheets("Rabotniki")
Set Конечная = Workbooks("EH.xlsx").Worksheets("EH")

Остальные формулы я постораюс сам доработать.