Диалоговое окно с выбором листов.

[kipish_lp]

Здравствуйте!
Помогите, пожалуйста. Надо сделать так: двойной клик левой клавишей мышки по первой ячейке строки, начиная с 8 строки, вызывает диалог: На какой лист копировать? И ниже список существующих не скрытых листов. Можно выбрать один лист, несколько, все. По кнопке ОК данная строка копируется на выбранные листы как есть.
С двойным кликом я разобралась, копировать умею. Как сделать такое диалоговое окно, где бы выводились все листы данной книги?

[Dophin]

Private Sub CommandButton1_Click()
Dim arr
Dim sh As Worksheet
Dim k As Long
ReDim arr(1 To ThisWorkbook.Sheets.Count)
For Each sh In Worksheets
If sh.Visible = True Then
k = k + 1
arr(k) = sh.Name
End If
Next sh
ListBox1.List = arr
End Sub

как то так

[EducatedFool]

Так подойдёт?



Вот весь код:

= модуль листа =
Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    If Target.Column = 1 And Target.Row >= 8 Then Cancel = True: UserForm1.Show
End Sub

= модуль формы =

Private Sub CommandButton1_Click()
    Dim sh As Worksheet
    For i = 0 To Me.ListBox1.ListCount - 1
        If Me.ListBox1.Selected(i) Then
            Set sh = Worksheets(Me.ListBox1.List(i))
            ActiveCell.EntireRow.Copy sh.Range("a" & sh.Rows.Count).End(xlUp).Offset(1)
        End If
    Next
    Unload Me
End Sub

Private Sub CommandButton2_Click()
    Unload Me
End Sub

Private Sub UserForm_Initialize()
    Dim sh As Worksheet
    For Each sh In ThisWorkbook.Worksheets
        If sh.Name <> ActiveSheet.Name And sh.Visible = xlSheetVisible Then Me.ListBox1.AddItem sh.Name
    Next sh
End Sub

[kipish_lp]

То что надо! Спасибо!