Запрет ввода букв

[Евгений Уральский]

На самом деле макрос хоть и маленький, но он некорректно будет работать с IP-адресами или если разряды в числе разделены пробелами. Или если дата введена в формате, отличном от системного. например "192.168.10.12", "123 456 789" или "01-01-2011". Это будет восприниматься как текст в связи с невозможностью преобразования в число или другой формат. Поэтому лучше все-таки делать проверку вводимых символов.

[Евгений Уральский]

Сообщение от Евгений Уральский

В общем, в итоге сделал и все пошло на ура:

Private Sub Worksheet_Change(ByVal Target As Range)
If (Target.Rows.Count = 1) And (Target.Columns.Count = 1) Then
Application.EnableEvents = False
If IsNumeric(Target.Value) <> True Then
TolkoTzifra = MsgBox("Вводите только цифры", vbOKOnly + vbCritical, "Ошибка")
Cells(Target.Row, Target.Column).Select
Selection.ClearContents
Selection.NumberFormat = "0.0"
Else:
Cells(Target.Row, Target.Column + 1).Select
End If
Application.EnableEvents = True
End If
End Sub

Не совсем все, как хотел..ведь символы теперь тоже не вводятся, как и буквы.. Необходима проверка алфавита, а не запрет "Только цифры"

[IgorGO]

на выбор два варианта:

Private Sub Worksheet_Change(ByVal Target As Range)
  Const BadChars As String = "xy..."
  Dim i As Long, s As String
  For Each cl In Target.Cells
    s = CStr(cl.Value)
    For i = 1 To Len(s)
      If InStr(BadChars, Mid(s, i, 1)) > 0 Then cl.ClearContents
    Next
  Next
End Sub

или

Private Sub Worksheet_Change(ByVal Target As Range)
  Const OkChar As String = "0123456789.,-_/\"
  Dim i As Long, s As String
  For Each cl In Target.Cells
    s = CStr(cl.Value)
    For i = 1 To Len(s)
      If InStr(OkChar, Mid(s, i, 1)) = 0 Then cl.ClearContents
    Next
  Next
End Sub

[nilem]

Еще вариантик. Запрет ввода русских прописных и строчных букв

Option Explicit
Option Compare Text

Private Sub Worksheet_Change(ByVal Target As Range)
If Target Like "*[а-я]*" Then
    With Application
        .EnableEvents = False: .Undo: .EnableEvents = True
    End With
End If
End Sub

[Евгений Уральский]

Уважаемый IgorGO , в первом варианте буквы прописываются превосходно А вот второй вроде работает.

[IgorGO]

в модуль листа надо положить одну из этих функций. (другую полностью закомментировать)
константы BadChars (или OkChar) необходимо заполнить соответственно недопустимыми или (для OkChar) разрешенными символами.

[fm12]

Private Sub Worksheet_Change(ByVal Target As Range)
Const OkChar As String = "0123456789.,-_/\"
Dim i As Long, s As String
For Each cl In Target.Cells
s = CStr(cl.Value)
For i = 1 To Len(s)
If InStr(OkChar, Mid(s, i, 1)) = 0 Then cl.ClearContents
Next
Next
End Sub

Можно ли добавить в этот код сообщение, которое будет выскакивать при вводе текста, например "Недопустимо"?

[IgorGO]

Private Sub Worksheet_Change(ByVal Target As Range)
  Const OkChar As String = "0123456789.,-_/\"
  Dim i As Long, s As String
  For Each cl In Target.Cells
    s = CStr(cl.Value)
    For i = 1 To Len(s)
      If InStr(OkChar, Mid(s, i, 1)) = 0 Then 
        msgbox "знак " & Mid(s, i, 1) & " запрещен!", vbokonly, "В ячейке " & cl.address
        cl.ClearContents
        Exit sub
      end if
    Next
  Next
End Sub

[fm12]

IgorGO, спасибо большое. Но есть еще просьба, можно ли сделать так чтоб все это было применимо только к столбцу "В" с 4-й строки.

[IgorGO]

Private Sub Worksheet_Change(ByVal Target As Range)
  Const OkChar As String = "0123456789.,-_/\"
  Dim i As Long, s As String, rg as range
  set rg = application.intersect(range("B4:B" & rows.count), target) 
  if rg is nothing then exit sub
  For Each cl In rg.Cells
    s = CStr(cl.Value)
    For i = 1 To Len(s)
      If InStr(OkChar, Mid(s, i, 1)) = 0 Then 
        msgbox "знак " & Mid(s, i, 1) & " запрещен!", vbokonly, "В ячейке " & cl.address
        cl.ClearContents
        Exit sub
      end if
    Next
  Next
End Sub

однако... внимательно читайте подпись