VBA_макрос: удалить всю строку в таблице, если в ней есть слово "удалить"

[Hugo121]

Что-то я загнул, можно было и попроще:

Option Explicit

Sub test()
Application.EnableEvents = False
Application.Calculation = xlCalculationManual
Application.ScreenUpdating = False: On Error Resume Next

    Do
        Range("L:L").Find(what:="удалить", LookIn:=xlValues, LookAt:=xlPart).EntireRow.Delete
    Loop Until Err
    
Application.EnableEvents = True
Application.ScreenUpdating = True
Application.Calculation = xlCalculationAutomatic
End Sub

Application.EnableEvents = False можно и не ставить, ну на всякий случай.
Основное - Application.Calculation = xlCalculationManual и LookIn:=xlValues

[jungo]

Вот так можно:

Dim AllRows As Object, FirstCell As Object, FoundCell As Object

    Application.ScreenUpdating = False

    Set FirstCell = Columns("L").Find(What:="удалить", LookAt:=xlWhole)
    If FirstCell Is Nothing Then GoTo Metka

    Set AllRows = Rows(FirstCell.Row)
    Set FoundCell = FirstCell

    Do
        Set FoundCell = Columns("L").FindNext(After:=FoundCell)
        Set AllRows = Union(Rows(FoundCell.Row), AllRows)
        If FoundCell.Address = FirstCell.Address Then Exit Do
    Loop
    AllRows.Delete
Metka:     Range("A1").Select

[Hugo121]

Не, прямо так не пойдёт.
Так пойдёт:

    Set FirstCell = Columns("L").Find(What:="удалить", LookIn:=xlValues, LookAt:=xlPart)

[макарошка]

Ай, какая красота! работает чисто)) Огромнейшее спасибо!!!

[SAS888]

Могу добавить.
1. С позволения авторов кода, предложенного выше, можно чуть упростить. Например, так:

Sub Main1()
    Dim x As Range, y As Range, fst As String
    Application.ScreenUpdating = False
    Set x = [L:L].Find("удалить")
    If Not x Is Nothing Then
        fst = x.Address
        Do
            If y Is Nothing Then Set y = x Else Set y = Union(y, x)
            Set x = [L:L].FindNext(x)
        Loop While fst <> x.Address
    End If
    If Not y Is Nothing Then y.EntireRow.Delete
End Sub

2. Ну, и я опять о том, что благодаря встроенным в Excel методам, во многих случаях можно обойтись без циклов. Задачу можно решить, например, следующим образом:

Sub Main2()
    Dim x As Range: Application.ScreenUpdating = False: Rows.Hidden = False
    Set x = [L:L].Find("удалить"): If x Is Nothing Then Exit Sub
    [L:L].ColumnDifferences(x).EntireRow.Hidden = True
    ActiveSheet.UsedRange.SpecialCells(xlCellTypeVisible).Delete
    Rows.Hidden = False
End Sub

[Hugo121]

Только вот опять же, в данной задаче просто так
Set x = [L:L].Find("удалить")
не годится...