Навигация в документе

[viter.alex]

Попробуй так:

Sub AddButtonToPage(Anchor As Range, Name As String, Top As Single, Left As Single, Caption As String, MacroName As String)
  Dim btn As CommandButton
  
  'Добавление кнопки на страницу
  With Anchor.Document.Shapes.AddOLEControl("Forms.CommandButton.1", , , , , Anchor)
    Set btn = .OLEFormat.Object
    With btn
      .Name = Name
      .Caption = Caption
      .AutoSize = True
    End With
    .RelativeHorizontalPosition = wdRelativeHorizontalPositionPage
    .Left = Left
    .RelativeVerticalPosition = wdRelativeVerticalPositionPage
    .Top = Top - btn.Height
  End With
  
  'Добавление кода для кнопки в модуль ThisDocument
  Dim CodeModule As VBComponent
  Set CodeModule = Anchor.Document.VBProject.VBComponents(1)
  With CodeModule.CodeModule
    .InsertLines .CountOfDeclarationLines + .CountOfLines, String(2, vbCr)
    .InsertLines .CountOfDeclarationLines + .CountOfLines, "Private Sub " & Name & "_Click()" & vbCr & "Application.Run ""WebGoBack""" & vbCr & "End Sub"
  End With
End Sub

Sub Main()
  Dim oRng As Range
  Dim i As Long
  Set oRng = ActiveDocument.Range
  
  'Переход последовательно по страницам и вставка кнопок
  For i = 1 To ActiveDocument.Range.ComputeStatistics(wdStatisticPages)
    Set oRng = oRng.GoTo(wdGoToPage, wdGoToAbsolute, i)
    AddButtonToPage oRng, "Button" & i, oRng.Sections.First.PageSetup.TopMargin, oRng.Sections.First.PageSetup.LeftMargin, "К оглавлению", "Run" & i
  Next
End Sub

[kanapfelka]

Вот это да! Я бы никогда сходу такого не написал, ещё не пробовал, но всё равно огромное спасибо

[kanapfelka]

Выделяет CodeModule As VBComponent, и говорит user-defined type not defined.
В новом документе с рыбой AddButtonToPage говорит argument not optional, а Main выделяет btn As CommandButton и говорит user-defined type not defined.

[viter.alex]

Tools→References… и подключить Microsoft Visual Basic for Applications Extensibility и Microsoft Forms 2.0 Object Library. В безопасности макросов разрешить программный доступ к объектам VBA

[kanapfelka]

О классно, расставил, только иногда пропуская страницы и принимая стиль окружающего текста к тексту на кнопке.
Куда всунуть clearformatting?

[viter.alex]

Код в студию

[kanapfelka]

Так я не менял ничего

Sub AddButtonToPage(Anchor As Range, Name As String, Top As Single, Left As Single, Caption As String, MacroName As String)
  Dim btn As CommandButton
  
  'Добавление кнопки на страницу
  With Anchor.Document.Shapes.AddOLEControl("Forms.CommandButton.1", , , , , Anchor)
    Set btn = .OLEFormat.Object
    With btn
      .Name = Name
      .Caption = Caption
      .AutoSize = True
    End With
    .RelativeHorizontalPosition = wdRelativeHorizontalPositionPage
    .Left = Left
    .RelativeVerticalPosition = wdRelativeVerticalPositionPage
    .Top = Top - btn.Height
  End With
  
  'Добавление кода для кнопки в модуль ThisDocument
  Dim CodeModule As VBComponent
  Set CodeModule = Anchor.Document.VBProject.VBComponents(1)
  With CodeModule.CodeModule
    .InsertLines .CountOfDeclarationLines + .CountOfLines, String(2, vbCr)
    .InsertLines .CountOfDeclarationLines + .CountOfLines, "Private Sub " & Name & "_Click()" & vbCr & "Application.Run ""WebGoBack""" & vbCr & "End Sub"
  End With
End Sub

Sub Main()
  Dim oRng As Range
  Dim i As Long
  Set oRng = ActiveDocument.Range
  
  'Переход последовательно по страницам и вставка кнопок
  For i = 1 To ActiveDocument.Range.ComputeStatistics(wdStatisticPages)
    Set oRng = oRng.GoTo(wdGoToPage, wdGoToAbsolute, i)
    AddButtonToPage oRng, "Button" & i, oRng.Sections.First.PageSetup.TopMargin, oRng.Sections.First.PageSetup.LeftMargin, "К оглавлению", "Run" & i
  Next
End Sub

[Skif-F]

Может, я чего-то не понял, а не проще использовать "Схему документа"?
Главное сформатировать заголовки правильно, и макросы не потребуются!

[viter.alex]

Если ничего не менял, то как понять

Сообщение от kanapfelka

…принимая стиль окружающего текста к тексту на кнопке…

если кнопка вставляется над верхней границей страницы, а не в текст? Странно, что пропускаются страницы, попробуй вот так записать цикл в процедуре Main

  'Переход последовательно по страницам и вставка кнопок
  For i = 1 To ActiveDocument.Range.ComputeStatistics(wdStatisticPages)
    Set oRng = oRng.GoTo(wdGoToPage, wdGoToAbsolute, i)
    AddButtonToPage oRng, "Button" & i, oRng.Sections.First.PageSetup.TopMargin, oRng.Sections.First.PageSetup.LeftMargin, "К оглавлению", "Run" & i
    DoEvents
  Next

Замечание Skif-F совершенно корректно, но, как известно, у начальства свои тараканы в голове.

Добавлено позже
Странно, действительно меняет шрифт и пропускает страницы

[kanapfelka]

Сообщение от Skif-F

проще использовать "Схему документа"?
Главное сформатировать заголовки правильно, и макросы не потребуются!

Повторюсь, это делается не для бланков договоров, а для довольно-таки больших документов (50-300 страниц)