Запись данных в закрытую книгу

[Eresiarh]

Да все верно. Открыли, выбрали лист, ячейки, закрыли с параметром true(чтоб окошко не выскочило "сохранить изменения") и все.

[FormAlDeGid]

Сейчас код выглядит вот так:

Sub NextAuto_Утро_тест()
Dim FD As FileDialog, iFullFileName As String, SourceSheet As Worksheet
Dim iThisSheet As Worksheet, iNewName As String

    Set FD = Application.FileDialog(msoFileDialogFilePicker)
    With FD
        .Filters.Clear
        .Filters.Add "Текстовики ", "*.txt; *.csv"
        .Filters.Add "MS Excel", "*.xl*"
        .Filters.Add "Фсё", "*.*"
        .AllowMultiSelect = False
        .InitialFileName = ThisWorkbook.Path
        .Title = "Открытие документа"
        .ButtonName = "Открыть"
        If .Show = False Then
            MsgBox "Не выбрал файло!", 48, "Ошибка"
            Exit Sub
        Else
            iFullFileName = .SelectedItems(1)
        End If
    End With
    Set FD = Nothing
    Set iThisSheet = ActiveSheet
    iNewName = Left(iFullFileName, Len(iFullFileName) - 3) & "txt"
    Name iFullFileName As iNewName
    Application.ScreenUpdating = False
    Workbooks.OpenText Filename:=iNewName, StartRow:=2, DataType:=xlDelimited, Semicolon:=True
    Dim i As Long, a(), b(): Application.ScreenUpdating = False
    a = ActiveSheet.UsedRange.Value: b = Array(5, 3, 4, 6, 16, 9, 7): Cells.Delete
    [G:G].NumberFormat = "#,##0.00$": [C:C].NumberFormat = "0"
    For i = LBound(b) To UBound(b)
        Range(Cells(1, i + 1), Cells(UBound(a, 1), i + 1)) = Application.Index(a, 0, b(i))
    Next
    [G:G].HorizontalAlignment = xlRight: [A:F].HorizontalAlignment = xlLeft
    Rows(1).Font.Bold = False: Rows(1).HorizontalAlignment = xlLeft: [A:G].EntireColumn.AutoFit
    With ActiveSheet.UsedRange
        .Sort Key1:=[E1], Order1:=xlAscending, Header:=xlYes
        .Borders(xlEdgeLeft).LineStyle = xlContinuous
        .Borders(xlEdgeTop).LineStyle = xlContinuous
        .Borders(xlEdgeBottom).LineStyle = xlContinuous
        .Borders(xlEdgeRight).LineStyle = xlContinuous
        .Borders(xlInsideVertical).LineStyle = xlContinuous
        .Borders(xlInsideHorizontal).LineStyle = xlContinuous
    End With
    For i = 2 To UBound(a, 1)
        If Left$(Cells(i, 5), 1) = "N" Then Cells(i, 5).Font.Bold = True
    Next
    Set SourceSheet = ActiveSheet
    With iThisSheet
        SourceSheet.UsedRange.Copy .Cells(.UsedRange.Rows.Count + .UsedRange.Row, "D")
    End With
    ActiveWorkbook.Close SaveChanges:=False
    Name iNewName As iFullFileName
    Application.ScreenUpdating = True
    MsgBox "Все клево!", 64, ""
    Kill iFullFileName
End Sub

Но есть одно "НО" первая строка форматированна не так как другие а именно: в столбце H нет выделения жирным а в столбце J центровка влево а не в право.
Подскажите в каком месте отсутствие моего мозга пропустило кривизну моих рук?

[EducatedFool]

Но есть одно "НО" первая строка форматированна не так как другие а именно: в столбце H нет выделения жирным

А откуда оно там возьмётся???
Вы сначала снимаете "жирность" для всей первой строки: Rows(1).Font.Bold = False
а потом ставите её, начиная со 2-й строки:

For i = 2 To UBound(a, 1)
        If Left$(Cells(i, 5), 1) = "N" Then Cells(i, 5).Font.Bold = True
    Next

Откуда ж первая ячейка станет жирной?

а в столбце J центровка влево а не в право.

А где в коде написано, что должно быть вправо?
Вы же для первой строки сделали "влево"...
Rows(1).HorizontalAlignment = xlLeft

[FormAlDeGid]

EducatedFool благодарю за разъяснения.