Генератор случайно выборки из массива

[Palomnik1096]

Добрый день!

Суть программы следующая, есть массив, необходимо из этого массива выбрать случайным образом определенное пользователем количество данных. Например: пользователь выбирает массив состоящий из значений от 1 до N (допустим 15), потом заполняется массив этими значениями, потом пользователь выбирает сколько случайным образом значений необходимо выбрать из этого массива (допустим 5), далее генерируются 5 значений из 15 случайным образом и выводятся в столбик. Вопрос как сделать так, чтобы эти 5 случайным образом значений не повторялись? Вот код программы которую я написал, все работает ок!, только едиственная проблема не могу сделать так, чтобы значения из массива не повторялись.

Option Explicit
Option Base 1
Public Sub Упражнение_9_5()
Dim NKlienta() As Long, i As Long, Kolvo As Long, MKolvo As Long, j As Long, a As Long
Kolvo = InputBox("Ввведите общее количество клиентов", "Ввод количества клиентов")
ReDim NKlienta(Kolvo)
For i = 1 To Kolvo
    NKlienta(i) = i
Next
MKolvo = InputBox("Ввведите количество клиентов, которых необходимо случайным образом выбрать", "Ввод количества клиентов для выборки")
Randomize
    With Range("A1")
        For j = 1 To MKolvo
            a = Int(Rnd * Kolvo) + 1
            .Offset(j, 0) = a
        Next
    End With
End Sub

___________
Код нужно оформлять по правилам:
тегом [CODE]..[/СODE] (это кнопочка с решёточкой #)
Не забывайте об этом!
Модератор.

[Serge_Bliznykov]

загоняйте нужные значения клиентов в массив, его перемешивайте случайныйм образом, а потом берите подряд столько значений, сколько Вам надо. т.к. изначально повторов не было, то их не будет и в перемешанном массиве.

p.s. алгоритм перемешивания смотрите на форуме...

[IgorGO]

например так:

  ...
  Dim s As String
  Randomize: s = ""
  With Range("A1")
    For j = 1 To MKolvo
      Do: a = Int(Rnd * Kolvo) + 1: Loop Until InStr(s, "<" & a & ">") = 0
      .Offset(j, 0) = a: s = s & "<" & a & ">"
  ...

[Palomnik1096]

Спасибо!

Если может объясните смысл
Do
a = Int(Rnd * Kolvo) + 1
Loop Until InStr(s, "<" & a & ">") = 0

Точнее интересует
InStr(s, "<" & a & ">") = 0

Заранее благодарен.

[IgorGO]

я забранные номера элементов массива записываю в строку s = s & "<" & a & ">".
InStr(s, "<" & a & ">") = 0 - значит а нет в строке.
обрамляющие знаки (я взял <>) нужны для того чтобы корректно осуществить поиск. нельзя записать просто числа, потому что если потом искать "1" то единичка будет найдена в числах от 10 до 19.
а если искать "<1>" то в строке "<10>" совпадений нет.

[Palomnik1096]

Нихрена не понял, но все равно спасибо!

[IgorGO]

))
ладно.
1. генерируем случайное число а (например, получилось 12)
2. проверяем если ли в строке s такая последовательность симолов "<12>"
3. если нет забирем 12 элемент массива и в сроку s добавляем запись "<12>", что значит 12-й уже забран.
4. выполняем п.1

строка s последовательно заполняется значениями уже выпавших номеров <> - здесь это не меньше, больше - это кавычки, которыми обрамлено число. вместо них можно использовать любые другие, даже не обязательно разные.

[Palomnik1096]

 Randomize: s = ""
  With Range("A1")
    For j = 1 To MKolvo
      Do: a = Int(Rnd * Kolvo) + 1: Loop Until InStr(s, "<" & a & ">") = 0
      .Offset(j, 0) = a: s = s & "<" & a & ">"

А вот эту часть кода, я так понимаю можно было записать, как


[CODE]Randomize
s=""
For j = 1 To MKolvo
Do
a = Int(Rnd * Kolvo) + 1
Loop Until InStr(s, "<" & a & ">") = 0
.Offset(j, 0) = a
s = s & "<" & a & ">"
Next[CODE]

[IgorGO]

да, похоже.
только этот алгоритм при MKolvo > 60 просто рухнет из-за переполнения длины строки s.

на коллекциях все будет работать без ограничений и очень-очень быстро.

Public Sub Упражнение_9_5()
  Dim i As Long, Kolvo As Long, MKolvo As Long, a As Long, c As New Collection
  Kolvo = InputBox("Ввведите общее количество клиентов", "Ввод количества клиентов")
  For i = 1 To Kolvo
      c.Add i
  Next
  MKolvo = InputBox("Ввведите количество клиентов, которых необходимо случайным образом выбрать", "Ввод количества клиентов для выборки")
  Randomize
  With Range("A1")
    For i = 1 To MKolvo
      a = Int(Rnd() * c.Count + 1)
      .Offset(i, 0) = c.Item(a)
      c.Remove (a)
    Next
  End With
End Sub

[Palomnik1096]

Да вроде все работает и с предыдущим кодом, пробывал Kolvo =500, МKolvo =150, все работает, ничего не рушится