Перебор файлов с помощью CommandButton

[Puffi.Muffi]

Уважаемые программисты,

Подскажите, пожалуйста, как можно поступить:

Хотела сделать навигацию при поиске ячеек с определенной частью текста во всех excel-файлах, которые находятся в определенной папке.

Вот задумка:
1) Открывается первый файл

2) Появляется UserForm c 3мя CommandButton: "Previous", "Next", при их помощи можно переходить к предыдущей, либо следующей нужной ячейке; "Exit" для завершения процесса в любой момент; и TextBox в котором выводится содержание ячейки.

Т.е. открылся файл, если в данном файле две ячейки, содержащие (например) сочетание "BBB",
то появляется userform c TextBox в котором (напр.) "BBB44553",
при нажатии "Next" появлялось содержание следующей ячейки (напр.) "BBB22",

- если нажимаем в этот момент "Previous", то выводится "BBB44553",
- если "Next" то эта книга закрывается, т.к. в ней больше нет ячеек с таким содержанием, и открывается следующая книга, в TextBox появляется новая надпись с "BBB".

-если в нажать "Previous", то закроется этот файл, откроется предыдущий, выведется "BBB22",
- если "Next" то выведется следующая нужная ячейка данного файла если такая имеется, если нет, то этот файл закрывается, открывается новый

и т.д. пока не будут показаны поочередно при помощи ручного переключения все ячейки во всех файлах определенной папки с содержанием "BBB".

Не получается скомпоновать следующий код:

Часть I "Для навигации при поиске в определенном файле"
'********************************** *****************
Sub otkrivaet_perviy_fail_vivodit_1y_nu zhniy_text ()
Dim bb As Integer
bb = 1
status_treida = Worksheets("aacc").Cells(bb, 5).Value
mycheck = status_treida Like "*BBB*"
If mycheck = True Then
Cells(bb, 5).Select
UserForm1.TextBox1.Value = status_treida
UserForm1.Show
End If
End Sub


Private Sub CommandButton1_Click()
' "Previous"
Dim selA As Integer
selA = Selection.Row - 1

Unload UserForm1
status_treida = Worksheets("aacc").Cells(selA, 5).Value
mycheck = status_treida Like "*BBB*"
If mycheck = True Then
Cells(selA, 5).Select
UserForm1.TextBox1.Value = status_treida
UserForm1.Show
End If
End Sub

Private Sub CommandButton2_Click()
' "Next"
Dim selA As Integer
selA = Selection.Row + 1

Unload UserForm1
status_treida = Worksheets("aacc").Cells(selA, 5).Value
mycheck = status_treida Like "*BBB*"
If mycheck = True Then
Cells(selA, 5).Select
UserForm1.TextBox1.Value = status_treida
UserForm1.Show
End If
End Sub

Private Sub CommandButton3_Click()
' "Exit"
Unload UserForm1
End Sub
'********************************** *******************
Часть II "Перебор файлов"
'__________________________________ __________________________
Sub gfcmkjh()
Dim xDirect$, xFname$, InitialFoldr$
InitialFoldr$ = "C:\Users\" '<<< Startup folder to begin searching from
With Application.FileDialog(msoFileDialo gFolderPicker)
.InitialFileName = Application.DefaultFilePath & "\"
.Title = "Please select a folder to list Files from"
.InitialFileName = InitialFoldr$
.Show
If .SelectedItems.Count <> 0 Then
xDirect$ = .SelectedItems(1) & "\"
xFname$ = Dir(xDirect$, 7)
Do While xFname$ <> ""

HhHhH = "C:\Users\" & xFname$

Workbooks.Open Filename:=HhHhH
Workbooks(xFname$).Activate

'..........................

ActiveWorkbook.Close
xFname$ = Dir
Loop
End If
End With

End Sub
'__________________________________ _______________________

а нельзя ли сделать как-нибудь чтобы при нажатии кнопок первый код не прерывался? Возможно ли в основном коде написать то, что будет происходить при нажатии CommandButton, а не в "Private Sub CommandButton_Click()"
Что-нибудь вроде"If CommandButton1 = True then..." ?

Или как можно по-другому решить задачу?

С наилучшими пожеланиями,
Puffi.Muffi

[Puffi.Muffi]

Уважаемые профессионалы,

Плиз напишите, что Вы обо всем этом думаете:
Слишком долгое сообщение?
Не совсем ясная задача?
Требует много времени для решения?

Тут главный вопрос: Как можно кнопками на Фоме "Назад" и "Вперед" открывать поочередно файлы находящиеся в одной папке?

Спасибо за внимание,
Puffi.Muffi

[EducatedFool]

Как можно кнопками на Фоме "Назад" и "Вперед" открывать поочередно файлы находящиеся в одной папке?

Я себе делал подобное, - по нажатию Ctrl+> и Ctrl+< поочередно открывались файлы из заданной папки (предыдущий файл закрывался)

Private Sub Workbook_Open()
    Application.OnKey "^.", "ShowNextWorkbook"
    Application.OnKey "^,", "ShowPrevWorkbook"
End Sub

Sub ShowNextWorkbook(): ScrollWorkbooks 1: End Sub
Sub ShowPrevWorkbook(): ScrollWorkbooks -1: End Sub

Sub ScrollWorkbooks(Optional ByVal offset&)
    On Error Resume Next
    Static coll As Collection, Index&, lastFile$, folder$
    folder$ = "путь к папке"
    If coll Is Nothing Then Set coll = FilenamesCollection(folder$)
    If coll.Count = 0 Then MsgBox "Папка «Прайс-листы» не содержит файлов!", vbExclamation: Exit Sub
    Index& = Index& + offset&
    If Index& > coll.Count Then Index = 1
    If Index& <= 0 Then Index = coll.Count

    Application.ScreenUpdating = False
    NewFile$ = coll(Index&)
    Workbooks.Open NewFile$, False ' открытие очередного файла
    If lastFile$ <> "" Then
        Application.DisplayAlerts = False
        Workbooks(Dir(lastFile$, vbNormal)).Close 0 ' закрытие предыдущего
        Application.DisplayAlerts = True
    End If
    lastFile$ = NewFile$
    Application.ScreenUpdating = True
End Sub

Ну и вам понадобится функция FilenamesCollection отсюда:
http://excelvba.ru/code/FilenamesCollection

--------------------

Возможно, ещё это поможет:
http://excelvba.ru/code/SearchCells

Результаты поиска выводятся на форму,
для перехода к найденной ячейке достаточно щелкнуть мышью на нужном результате - автоматически будет активирован нужный лист, и выделена искомая ячейка.

[Puffi.Muffi]

Спасибо EducatedFool Вам большое! код подходит, основная часть задачи решена, над остальным буду работать.