Сравнение 2х листов, и если нет совпадений удаление.

[MASRUB]

Помогите отредактировать макрос:
То что он сейчас выполняет, сверяет данные из листа1 на листе2, если есть совпадение, то удаляет их на Листе 1.
А нужно изменить код, что бы сверял данные лист 1 и лист 2, и если небыло совпадений, то удалял строчку из лист 1, а те которые совпадают с Лист 2 оставлял.

Dim a, b, i As Long, j As Long

With Sheets("Лист1")
a = .Range(.Cells(1, 1), .Cells(.Rows.Count, 1).End(xlUp)).Value
End With
With Sheets("Лист2")
b = .Range(.Cells(1, 1), .Cells(Rows.Count, 1).End(xlUp)).Value
End With
For i = UBound(a) To 1 Step -1
For j = 1 To UBound(b)
If a(i, 1) = b(j, 1) Then Sheets("Лист1").Rows(i).EntireRow.Delete
Next j, i

End Sub

[nilem]

Так, наверное

Sub MASRUB()
Dim a, i As Long, j As Long, rd As Range
With Sheets("Лист2")
    a = .Range(.[a1], .Cells(Rows.Count, 1).End(xlUp)).Value
End With
With CreateObject("Scripting.Dictionary")
    .CompareMode = 1
    For i = 1 To UBound(a, 1): .Item(a(i, 1)) = 1: Next i
    a = Range([a1], Cells(Rows.Count, 1).End(xlUp)).Value
    For i = 1 To UBound(a, 1)
        If Not .Exists(a(i, 1)) Then
            If rd Is Nothing Then Set rd = Cells(i, 1) Else Set rd = Union(rd, Cells(i, 1))
        End If
    Next
End With
If Not rd Is Nothing Then rd.EntireRow.Delete
End Sub

Активным должен быть лист Лист1

[MASRUB]

Большое спасибо за ответ, а как еще добавить строчечку что бы просто совпадения копировались на новый лист, скажем "Лист3"?

[nilem]

Сообщение от MASRUB

Большое спасибо за ответ, а как еще добавить строчечку что бы просто совпадения копировались на новый лист, скажем "Лист3"?

Sub MASRUB2()
Dim a, b(), i As Long, j As Long
With Sheets("Лист2")
    a = .Range(.[a1], .Cells(Rows.Count, 1).End(xlUp)).Value
End With
With CreateObject("Scripting.Dictionary")
    .CompareMode = 1
    For i = 1 To UBound(a, 1): .Item(a(i, 1)) = 1: Next i
    a = Range([a1], Cells(Rows.Count, 1).End(xlUp)).Value
    ReDim b(1 To UBound(a), 1 To 1)
    For i = 1 To UBound(a, 1)
        If .Exists(a(i, 1)) Then j = j + 1: b(j, 1) = a(i, 1)
    Next
End With
Sheets("Лист3").[a1].Resize(j).Value = b
End Sub

В предыдущем посте j As Long лишняя - остаточные явления.