Сравнение элементов массива.

[anon321]

Добрый вечер!
Сравниваю два элемента: (указатель на a передан функцией)
mov eax, [a]
add eax, 1
xor ebx, ebx
mov ebx, [eax]
mov temp_char, ebx
add eax, 1
mov ebx, [eax]
cmp temp_char, ebx
JNE exit
mov [eax], 's'

Но в ebx почему-то кладется не сам элемент массива, а страшное многозначное число. Почему?

(Это ассемблерная вставка в си. Есть массив, нужно с помощью ассемблерной вставки в си найти одинаковые элементы и убрать заменить их всех кроме одного, скажем, на '$'. Это задача полностью. Здесь я пытался просто посмотреть работу сравнения: он должен сравнить второй и третий элементы, в случае совпадения поставить вместо третьего s. В переменной я сохранял потому, что cmp не захотел сравнивать два регистра.)

[|{ot]

mov eax, [a]

Если а - указатель на массив, то верно, в еах попадет адрес массива, потому как указатель это (если не ошибаюсь) адрес, который указывает на адрес
Это зависит от того как параметр передаешь в ф-цию

add eax, 1

Поскольку в еах адрес первого элемента массива, а массив типа char(1 байт) то после этой команды eax указывает на второй элемент массива

xor ebx, ebx

Эта команда бессмысленна, поскольку следующая команда полностью задает значение еbх, это примерно тоже что и

int _ebx;
_ebx = 0;
_ebx = a[1];

mov ebx, [eax]

Вот здесь уже проблема, поскольку в ebx ложится DWORD(4 байта), которые находятся по адресу еах, то есть следующие 4 элемента массива, так как один элемент массива = 1 байт в данном случае

надо так вместо этого сделать:

mov bl, byte ptr [eax]

или

mov bl,[eax]

теперь команда

xor ebx, ebx

уже не бессмыслена, так как она обнуляет весь регистр, а

mov bl, byte ptr [eax]

заносит значение только в младший байт регистра

Эти две команды можно заменить на одну:

movzx ebx, byte ptr [eax]

означает положить в ebx один байт, все остальное обнулить

mov temp_char, ebx
add eax, 1

тут понятно, все ОК

mov ebx, [eax]

Тут так само как сверху написал!

cmp temp_char, ebx
JNE exit

тут все ОК

mov [eax], 's'

здесь опять же, лучше укажи размерность явно

mov byte ptr [eax], 's'

И вот еще, зачем тебе temp_char ?
можно так:

mov eax, [a]
inc eax //add eax,1, только быстрее
mov bl, byte ptr [eax]
inc eax
cmp bl, byte ptr [eax]
JNE exit
mov byte ptr [eax], 's'

или еще короче:

mov eax, [a]
mov bl, byte ptr [eax+1]
cmp bl, byte ptr [eax+2]
JNE exit
mov byte ptr [eax+2], 's'

или еще короче и быстрее:

mov eax, [a]
mov bx, word ptr [eax+1] // ложу в bx второй и третий элементы сразу
cmp bh,bl
JNE exit
mov byte ptr [eax+2], 's'

[Son Of Pain]

"Страшное число" берется, видимо, потому, что массив состоит из однобайтовых элементов, а регистры eax и ebx - 32-битные (четырехбайтовые). Потому, соответственно, в них загружалось 4 элемента массива, а не один.

Должно быть так:

mov eax, [a]
add eax, 1
mov bl, [eax]
mov temp_char, bl
add eax, 1
mov bl, [eax]
cmp temp_char, bl
JNE exit
mov [eax], 's'

Вместо "add eax, 1", кстати, лучше писать просто "inc eax".