Как считать из файла Text.LOG

[Алекс7]

Есть программа

Sub Test1()
Open "C:\Text.LOG" For Input As #1
Dim s As String, c As Range
Set c = Range("A1") 'первая ячейка
While Not EOF(1)
Input #1, s
c = s
Set c = c(2)
Wend
Close #1
End Sub

но она немного зависает, не может ли это быть связано с расширением файла Text.LOG?

[Казанский]

С расширением - нет, с длиной файла - да

Попробуйте Данные - Получить внешние данные - Из текста, запишите это действие в макрос.

[EducatedFool]

Ну или можете открыть этот файл при помощи Excel - командами Workbooks.Open или Workbooks.OpenText
Тоже макрос несложный получится

[Казанский]

Или так - сначала в массив, потом на лист:

Sub Test1()
Open "C:\Text.LOG" For Input As #1
Dim s$(), d$(), i&, j&
ReDim s(1 To Rows.Count)
While Not EOF(1)
    i = i + 1
    Input #1, s(i)
Wend
Close #1
ReDim d(1 To i, 1 To 1)
For j = 1 To i
    d(j, 1) = s(j)
Next
Range("A1:A" & i).Value = d
End Sub

[nilem]

Еще вариантик:

Sub ertert()
Dim i As Long, p As String, x, y()
p = ThisWorkbook.Path & "\oscam.log" 'задайте свой путь
x = Split(CreateObject("Scripting.FileSystemObject").OpenTextFile(p, 1, False).ReadAll, vbCrLf)
ReDim y(UBound(x), 0)
For i = LBound(x) To UBound(x): y(i, 0) = x(i): Next
[a1].Resize(UBound(x)).Value = y
End Sub

[Казанский]

Поэкспериментировал с файлом 912 кб ( http://forum.ixbt.com/topic.cgi?id=23:41951#13 ). Время в секундах:

Исходный макрос: 2,08
Через массив: 0,27
nilem: 0,36
данные - Из текста: 1,06
Workbooks.OpenText: 0,56
Workbooks.Open: 0,28

[R Dmitry]

Сообщение от Казанский

Поэкспериментировал с файлом 912 кб ( http://forum.ixbt.com/topic.cgi?id=23:41951#13 ). Время в секундах:

Исходный макрос: 2,08
Через массив: 0,27
nilem: 0,36
данные - Из текста: 1,06
Workbooks.OpenText: 0,56
Workbooks.Open: 0,28

Алексей если не сложно замерь на своих условиях и такой вариант:

Option Explicit
Sub ImportTxtFile()
'R Dmitry dg_rusak@mail.ru
Dim cn, rs
Application.ScreenUpdating = False
Set cn = CreateObject("ADODB.Connection")
cn.Open "Provider=Microsoft.Jet.OLEDB.4.0;" & _
    "Data Source=D:\;Extended Properties='text;HDR=No'" ' полный путь к файлу
Set rs = CreateObject("ADODB.Recordset")
Set rs = cn.Execute("SELECT * FROM DANNYE.txt") 'указать файл
Cells(1, 1).CopyFromRecordset rs
cn.Close
Set cn = Nothing
Application.ScreenUpdating = True
End Sub

[R Dmitry]

хотя похоже что будет долго

[Казанский]

Дмитрий,
не получается вставить путь к файлу - ошибка в команде cn.Open:

Строка 'c:\temp\File14.txt' задает ошибочный путь

Пробовал и в апострофах, и в кавычках. Как составить правильную команду?

[R Dmitry]

Сообщение от Казанский

Дмитрий,
не получается вставить путь к файлу - ошибка в команде cn.Open:

Строка 'c:\temp\File14.txt' задает ошибочный путь

Пробовал и в апострофах, и в кавычках. Как составить правильную команду?

из темпа адо обычно не работает
я там чуть неправильно написал
"Data Source=c:\temp\;Extended Properties='text;HDR=No'" ' полный путь к файлу, правильно к папке
а в selecte указываем файл как таблицу просто его имя File14.txt

Set rs = cn.Execute("SELECT * FROM File14.txt")

но при таком подходе все считывает довольно быстро, но автоматом разбивает на столбцы, поэтому медленно получается

в Ваших вариантах один столбец а в моем 19
копался в MSDN так и не нашел параметр который устанавливает разделитель по столбцам в ADO