Где находится серийный номер windows xp

[kreiver]

Подскажите где находится серийный номер windows xp?

[Stilet]

В реестре конечно )

[ROD]

Серийный номер или код активации? Если второе - на системник приклеен.

[Arigato]

Если запустить такой скрипт:

@echo off
setlocal enabledelayedexpansion

for /f "tokens=3" %%i in ('reg.exe query "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v DigitalProductId') do (
    set x=%%~i
)

for /l %%z in (104, 2, 132) do (
    set /a array[%%z]=0x!x:~%%z,2!
)

call :GetKey
echo ProductKey: %GetKey%
pause

endlocal
exit /b 0

:GetKey
    setlocal enabledelayedexpansion
    set out=%~0
    set pc=BCDFGHJKMPQRTVWXY2346789
    set x=0
    for /l %%i in (0, 1, 28) do (
        if !x! gtr 28 goto :Break

        set a=0

        for /l %%j in (132, -2, 104) do (
            set /a a=array[%%j] + !a! * 256
            set /a array[%%j]="( !a! / 24 ) & 255"
            set /a a%%=24
            set /a n=%%j
        )

        for %%z in (!a!) do set key=!pc:~%%z,1!!key!
        set /a f="( !x! + 2 ) %% 6"

        if !f! equ 0 if !x! lss 28 (
            set /a x+=1
            set key=-!key!
        )

        <nul set /p sTemp=.
        set /a x+=1
    )
:Break
    echo.
    endlocal & set %out:~1%=%key%
    exit /b

То увидим ключ Windows. А код активации - это то, что ставится в соответствие ключу. На наклейке находится именно ключ.

[Sciv]

У кого как, а у меня без всяких скриптов в свойствах Мойкомпьютера выводится

[Arigato]

Это не ключ установки вашей пиратской копии винды.

[Sciv]

Это не ключ установки вашей пиратской копии винды.

Каюсь, пиратка. Зато у меня к ней есть Microsoft Licensing Kit, до которого руки все никак не дотягиваются (на самом деле я этот наборчик засунул куда-то и найти теперь не могу )

Естественно это не ключ установки. Так и ТС нужен был не ключ установки, а серийный номер?

Хотя по отношению к винде их часто отождествляют, однако это принципиально разные вещи: ключ установки может использоваться один на несколько компов (в корпоративной версии), но при этом на каждом компе будет версия винды со своим уникальным ID (то есть как раз серийным номером).

Видимо, я слишком буквально расшифровал вопрос автора темы

[Arigato]

Что именно было нужно ТС не ясно.

[Utkin]

Опять же если пиратка, существуют программы вырезающие такую информацию. У меня стояла 7-ка как-то в которой не было ни номеров, ни службы проверки лицензии. Просто ничего и звать никак. Все работало и обновлялось...