замена значений в формулах

[IgorGO]

if left(c.formula,1) = "=" then ... заменить

[Казанский]

Cells.SpecialCells(xlCellTypeFormulas).Replace What:="1503", Replacement:="1506", LookAt:=xlPart, _
SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
ReplaceFormat:=False

[Jaroslav]

Спасибо, ребята.
У меня такой вопрос: можно ли узнать какой символ идет в формулах, которые имеют текст "1503", перед текстом "1503" и если это число от 0 до 9, тогда производить замену (мне нужно проводить замену только в формулах, которые ссылаются на другие файлы, а файлы имеют разные названия: P8081503, P0011503 и так далее). Может, есть способ узнать, какие именно формулы ссылаются на другие файлы?

[IgorGO]

задача обростает подробностями)

dim cell as range, p as long

for each cell in Cells.SpecialCells(xlCellTypeFormulas).cells
  p = instr(cell, "1503")
  if p > 1 then
    if mid(cell,p-1,1) >= "0" and mid(cell,p-1,1) <= "9" then
      cell = replace(cell, "1503", "1506")
    end if
  end if
next

[Jaroslav]

Вариант:

Dim c As Range
Application.DisplayAlerts = False
With Worksheets(1).Range("A1:GJ1600").SpecialCells(xlCellTypeFormulas)
    Set c = .Find("1503", LookIn:=xlFormulas)
    If Not c Is Nothing Then
        firstAddress = c.Address
        Do
            If c.Formula Like "*.csv*" Then
                c.Replace What:="1503", Replacement:="1506", LookAt:=xlPart, _
                SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
                ReplaceFormat:=False
            End If
            Set c = .FindNext(c)
        Loop While Not c Is Nothing And c.Address <> firstAddress
    End If
End With
Application.DisplayAlerts = True

почему-то не проходит (у меня формулы ссылаются на файлы .csv). Выдает ошибку 1004 "Невозможно получить свойство FindNext класса Range" (ошибку выдает на формуле, которая не имеет ссылок на другие книги)

[Jaroslav]

Спасибо, Игорь.

На строке:

p = InStr(cell, "1503")

выдает ошибку 13 Type mismatch

[IgorGO]

странно...
но вообще речь шла о замене в формулах, видимо, правильно будет так:

  Dim cell As Range, p As Long
  For Each cell In Cells.SpecialCells(xlCellTypeFormulas).Cells
    p = InStr(cell.Formula, "1503")
    If p > 1 Then
      If Mid(cell.Formula, p - 1, 1) >= "0" And Mid(cell.Formula, p - 1, 1) <= "9" Then
        cell.Formula = Replace(cell.Formula, "1503", "1506")
      End If
    End If
  Next

[Jaroslav]

Игорь, так работает. Спасибо

[Jaroslav]

если нужно заменить "1503" на "1506" только в формулах, которые ссылаются на другие книги с расширением .csv, код будет следующим:

Dim cell As Range, p As Long
Worksheets(1).Select
For Each cell In Cells.SpecialCells(xlCellTypeFormulas).Cells
  If cell.Formula Like "*.csv*" Then
      cell.Replace What:="1503", Replacement:="1506", LookAt:=xlPart, _
      SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
      ReplaceFormat:=False
  End If
Next