перенос строки с пустой ячейки

[HospodySave]

Приветствую всех программистов.
Помогите пожалуйста с такой задачеи:
Исходный файл 1.JPEG
Должен получиться файл 2.JPEG
Задача заключается в том что, с Листа1 нужно перенести строки которые начинаются с пустой ячейки на Лист2 с помощью кода
И эти строки с пустыми ячейками могут быть не только
в диапозоне "A2:D2" "A5:D5" они могут распалагаться в любой строке колонке на Листе1. Было бы легко сам сделал бы но для миня это трудно.
Так что прощу помощи профи Помогите Пож

[SAS888]

Можно обойтись без циклов, сравнений и перебора ячеек. Например, так:

Sub Main()
    Dim x As Range: Application.ScreenUpdating = False
    Rows(1).AutoFilter: Rows(1).AutoFilter Field:=1, Criteria1:="="
    With ActiveSheet.AutoFilter.Range.Columns(1)
        Set x = .Offset(1).Resize(.Rows.Count - 1).SpecialCells(xlVisible)
        x.EntireRow.Copy Sheets(2).[A1]
    End With: Rows(1).AutoFilter
End Sub

[nilem]

Application.ScreenUpdating = True
вместо
Rows(1).AutoFilter
Или так и надо?

[HospodySave]

оО спасибо очень благодарен за вашу помощь!! А можете описать что делают Эти строчки
Rows(1).AutoFilter: Rows(1).AutoFilter Field:=1, Criteria1:="="
With ActiveSheet.AutoFilter.Range.Column s(1)
Set x = .Offset(1).Resize(.Rows.Count - 1).SpecialCells(xlVisible)

[HospodySave]

Есть у кого-то ешо варианты как это сделать?

[EugeneS]

с позволения уважаемого SAS888 предлагаю добавить в код:

Sub Main()
Dim x As Range: Application.ScreenUpdating = False
Rows(1).Insert Shift:=xlDown    
Rows(1).AutoFilter: Rows(1).AutoFilter Field:=1, Criteria1:="="
    With ActiveSheet.AutoFilter.Range.Columns(1)
        Set x = .Offset(1).Resize(.Rows.Count - 1).SpecialCells(xlVisible)
        x.EntireRow.Copy Sheets(2).[a1]
    End With: Rows(1).AutoFilter: Rows(1).Delete: Application.ScreenUpdating = True:End Sub

Так как иначе, если в первой строке строка с пустой ячейкой, она не будет скопирована, и, заодно, включить обновление экрана

[HospodySave]

Спасибо всем в принципе я получил ответ можно закрыть тему.
Но есть ещо 1 вопрос что означает этот код
Rows(1).AutoFilter: Rows(1).AutoFilter Field:=1, Criteria1:="="
With ActiveSheet.AutoFilter.Range.Column s(1)
Set x = .Offset(1).Resize(.Rows.Count - 1).SpecialCells(xlVisible)

что такое Field почему именно 1 может кто обьяснить в кратце что делают эти строки?))

[HelperAwM]

+1 что означают те строки?

[SAS888]

Rows(1).AutoFilter: Rows(1).AutoFilter Field:=1, Criteria1:="="
Устанавливаем автофильтр по 1-й строке и критерий автофильтра по 1-му столбцу = "пустые значения".

With ActiveSheet.AutoFilter.Range.Column s(1)
Используем метод With, задавая ему диапазон в пределах 1-го столбца автофильтра.

Set x = .Offset(1).Resize(.Rows.Count - 1).SpecialCells(xlVisible)
Присваиваем переменной x (As Range) диапазон в пределах диапазона автофильтра из ячеек 1-го столбца за исключением заголовка, в который входят только видимые ячейки. Иными словами, диапазон x будет содержать отфильтрованные ячейки 1-го столбца по заданному критерию (если "пусто").
Попробуйте добавить в макрос последней строкой код

x.Select

и Вам все станет ясно.

P.S. Если 1-я строка не является заголовком, то примите к сведению замечания от EugeneS
P.P.S. По поводу обязательности Application.ScreenUpdating = True - вопрос дискуссионный. В 99% случаев его можно не выполнять.

[HospodySave]

Спасипки.