выполнение макроса на всех листах кроме первого

[moose123]

Всем привет!
Подскажите пожалуйста как сделать чтобы созданый макрос выполнялся на всех листах кроме первого
Спасибо

[IgorGO]

for i = 2 to sheets.count
with sheets(i)
...
end with
next

[moose123]

спасибо IgorGO но не хочет работать
проблема такая
если запускать на первом листе выдает ошибку "run-time error 13 type mismatch "
если запускать на другом тогда на нем обрабатывает а на других нет.

Я пробывал и ваш вариант, и другие тоже самое

вот как выглядит мой код

Sub myMacro2() 
    Dim li As Integer, lLastRow As Integer 
    Dim maxDate As Date 
    Dim YY As Long 
    Dim i As Integer 
    With ThisWorkbook 
         
        lLastRow = Cells(Rows.Count, 4).End(xlUp).Row 
        maxDate = Application.Max(Cells(2, 4), Cells(lLastRow, 4)) 
        For i = 2 To .Worksheets.Count 
            With .Worksheets(i) 
                 
                For li = 2 To lLastRow 
                    YY = (DateValue("31.12." & Year(Cells(li, 4))) - DateValue("01.01." & Year(Cells(li, 4))) + 1) 
                    If CLng(maxDate) - CLng(Cells(li, 3)) > YY Then 
                        Cells(li, 5) = 0 
                    End If 
                Next li 
            End With 
        Next i 
    End With 
     
End Sub

может проблема не в коде, а в чем то другом. я код добавил в модуль.
прикрепляю также файл с данными

[ShAM66]

Если используете With, то ставьте точки в нужных местах. Например:

Sub myMacro2()
Dim li As Integer, lLastRow As Integer
Dim maxDate As Date
Dim YY As Long
Dim i As Integer
    For i = 2 To Worksheets.Count
        With Worksheets(i)
        lLastRow = .Cells(Rows.Count, 4).End(xlUp).Row
        maxDate = Application.Max(.Cells(2, 4), .Cells(lLastRow, 4))

    For li = 2 To lLastRow
       YY = (DateValue("31.12." & Year(.Cells(li, 4))) - DateValue("01.01." & Year(.Cells(li, 4))) + 1)
       If CLng(maxDate) - CLng(.Cells(li, 3)) > YY Then .Cells(li, 5) = 0
    Next li
       End With
    Next i
End Sub