Скрестить 2 скрипта vbs+удалить файл

[Karyuudo]

Здравствуйте. Просьба помочь сделать следующее:

Дано: много файлов в ворде, большие и маленькие.
Задача: отделить большие (по количеству страниц, допустим больше 1 для примера)
Что есть:
Путем помощи на форумах и гугла удалось вот что найти:

скрипт который обрабатывает пачку файлов docx на удаление ссылок, только сюда вместо удаления ссылок надо проверку и удаление файла.

With CreateObject("word.application")
  For Each x In CreateObject("scripting.filesystemobject").getfile(wscript.scriptfullname).parentfolder.Files
    If LCase(Mid(x.Name, InStrRev(x.Name, ".") + 1, 4)) = "docx" Then
      With .documents.open(x.Path)
        numDocs = numDocs + 1
 
 //сюда что-то надо вставить для счета страниц и удаления если счет больше указанного числа страниц
        .Range.Fields.Unlink 'Ctrl+A, Ctrl+Shift+F9  
        .Close True 'save changes 
 
      End With
    End If
  Next
  .Quit
End With
wscript.echo "Обработано документов " & numDocs

а вот скрипт,который для конкретного файла считает страницы и если >1 то.... надо как-то удалить

Set objWord = CreateObject("Word.Application")
Const wdStatisticPages = 2
Set objDoc = objWord.Documents.Open("C:\Новая папка\имя файла.docx")
 
   if objDoc.ComputeStatistics(wdStatisticPages)>1 then удалить и продолжить проверять следующий файл
   objDoc.Close
   objWord.Quit

Как теперь это соединить?
нашел функцию удаления, но она чего-то не работает. к тому же после open и delete надо указать путь. а тут нет конкретного пути.. пытался как-то сделать, но не работает...

[Казанский]

With CreateObject("word.application")
  For Each x In CreateObject("scripting.filesystemobject").getfile(wscript.scriptfullname).parentfolder.Files
    If LCase(Mid(x.Name, InStrRev(x.Name, ".") + 1, 4)) = "docx" Then
      With .documents.open(x.Path)
        np = .ComputeStatistics(2)  '2=wdStatisticPages
        .Close False                'don't save changes         
      End With
      if np < 2 then x.delete: numDel = numDel + 1
    End If
  Next
  .Quit
End With
wscript.echo "Удалено документов " & numDel