сложить значения в диапазонах

[Vja4eslav]

Здравствуйте, уважаемые форумчане. Пытаюсь с помощью мароса сложить значения в двух одинаковых диапазонах на разных листах, но макрос не "фурычит". Подскажите, пожалуйста, что я делаю не так. В VBA я самоучка с начальным стажем.
Файл прилагаю.

[nilem]

Пробуйте так

Sub Метод_тыка()
Dim i As Long, ARange As Range, BRange As Range
Set ARange = Sheets(1).Range("A1:F23")
Set BRange = Sheets(2).Range("A1:F23")
For i = 1 To ARange.Cells.Count
    BRange.Cells(i).Value = BRange.Cells(i).Value + ARange.Cells(i).Value
Next
End Sub

а лучше так

Sub Метод_тыка2()
Sheets(1).Range("A1:F23").Copy
Sheets(2).Range("A1").PasteSpecial Paste:=xlValues, Operation:=xlAdd
Application.CutCopyMode = False
End Sub

[Vja4eslav]

Большое спасибо! Сейчас попробую

[Vja4eslav]

Не мог бы кто- нибудь подсказать, как изменить код, чтобы он работал при разрыве диапазона, т.е., например:
Sub Метод_тыка_2()
Dim i As Long, ARange As Range, BRange As Range
Set ARange = Sheets(1).Range("A1:F1,A3:F3")
Set BRange = Sheets(2).Range("A1:F1,A3:F3")
For i = 1 To ARange.Cells.Count
BRange.Cells(i).Value = BRange.Cells(i).Value + ARange.Cells(i).Value
Next
End Sub
Потому что
For Each x In ARange
For Each y In BRange
If y.Address = x.Address Then y = x + y
Next
Next
почему то не действует

[Казанский]

> почему то не действует
Будет действовать, если написать

        If y.Address = x.Address Then y.Value = x + y

или объявить переменные:

Dim  x As Range, y As Range

Хотя делать вложенный цикл - это жестоко

[Казанский]

Sub Метод_тыка_2()
Dim i As Long, ARange As Range, BRange As Range, y As Range
Set BRange = Sheets(2).Range("A1:F1,A3:F3")
For Each y In BRange
    y = y + Sheets(1).Range(y.Address)
Next
End Sub

[Vja4eslav]

Спасибо, Казанский! Сейчас попробую

[Vja4eslav]

Пытаюсь прописать, чтобы макрос считал только те ячейки, в которых находятся числовые значения (т.е. если в ячейке вместо числа будет, например прочерк "-", то значение этой ячейки не суммируется). Однако мой макрос ругается:"несоответствие типа". Что я делаю не так?
Вот мой скрипт:
Sub Метод_тыка_3()
Dim i As Long, ARange As Range, BRange As Range, y As Range
Set BRange = Sheets(2).Range("A1:F1,A3:F3")
For Each y In BRange
If Not IsNumeric(y.Value) Then GoTo lable
y = y + Sheets(1).Range(y.Address)
lable:
Next
End Sub

[kuklp]

Set BRange = Sheets(2).Range("A1:F1,A3:F3")
For Each y In BRange.specialcells(2,1).cells
y = y + Sheets(1).Range(y.Address)
Next

[Vja4eslav]

Большое спасибо, kuklp! Сейчас попробую