Вопрос по VB

[Mr_ViK]

Привет всем!
У меня такой вопрос: возможно ли реализовать в программе поиск всех возможных подключений к интернету и чтобы потом юзер смог выбрать нужное, если да то как это реализовать.
ПС: есть подобная программа:

[Mr_ViK]

Значит никто не знает?

[*PB*]

Можно.
Только у меня нет исходника именно на VB, но есть на PureBasic.
Переписать будет не трудно.

Enumeration
  #Window_0
EndEnumeration

;- Gadget Constants
;
Enumeration
  #ListIcon_0
  #Button_0
  #Button_1
EndEnumeration



#RAS_MaxEntryName = 256;
#RAS_MaxPhoneNumber = 128;
#RAS_MaxCallbackNumber = 128;
#RAS_MaxAreaCode = 10;
#RAS_MaxDeviceType = 16;
#RAS_MaxDeviceName = 128;
#RAS_MaxPadType = 32;
#RAS_MaxX25Address = 200;
#RAS_MaxFacilities = 200;
#RAS_MaxUserData = 200;
#UNLEN = 256;
#PWLEN = 256;
#DNLEN = 15;

Structure RASDIALPARAMS
  dwSize.l
  szEntryName.c[#RAS_MaxEntryName+1]
  szPhoneNumber.c[#RAS_MaxPhoneNumber+1]
  szCallbackNumber.c[#RAS_MaxCallbackNumber+1]
  szUserName.c[#UNLEN+1 ]
  szPassword.c[#PWLEN+1 ]
  szDomain.c[#DNLEN+1 ]
  dwSubEntry.l
  *dwCallbackId
  dwIfIndex.l
EndStructure

Structure  RASENTRYNAME95
  dwSize.l
  szEntryName.s{#MAX_PATH}
EndStructure

Structure RASCONNSTATUS
  dwSize.l
  RasConnState.l
  dwError.l
  szDeviceType.b[16]
  szDeviceName.b[32]
EndStructure

#RASBASE = 600
#ERROR_BUFFER_TOO_SMALL = #RASBASE+3;

Procedure GetConnectList(Gadget) ; Список подключений
  Protected  Dim ConnectList.RASENTRYNAME95(255)
  ConnectList(0)\dwSize = SizeOf(RASENTRYNAME95) 
  Size=256 * ConnectList(0)\dwSize
  v=RasEnumEntries_(#Null, #Null, @ConnectList(), @Size, @ln) 
  If v=#ERROR_BUFFER_TOO_SMALL
    RasEnumEntries_(#Null, #Null, @ConnectList(), @Size, @ln)
  EndIf
  For l = 0 To ln - 1
    AddGadgetItem(Gadget, -1, ConnectList(l)\szEntryName)
  Next 
  ProcedureReturn ln
EndProcedure

Procedure Connect(ConnectName.s) ; Установка связи с инетом. ConnectName - имя учетки инета
  FParams.RASDIALPARAMS
  pass.c
  FParams\dwSize = 1052;SizeOf(RASDIALPARAMS)
  PokeS(@FParams\szEntryName, ConnectName, Len(ConnectName))
  RasGetEntryDialParams_(#Null,@FParams,@pass)
  FConnHandle = 0
  RasDial_(0,0, @FParams, 0, 0, @FConnHandle)
  ProcedureReturn FConnHandle
EndProcedure

Procedure StatusConnect(ConnectionID, *Point.RASCONNSTATUS)
  ProcedureReturn RasGetConnectStatus_(ConnectionID, *Point)
EndProcedure


Procedure DisConnect(ConnectionID) ; Разрыв связи с инетом. ConnectionID - идентификатор подключения, полученый процедурой Connect
  Protected Result=0
  If ConnectionID
    If RasHangUp_(ConnectionID)=#ERROR_SUCCESS
      Result=1
    EndIf
  EndIf
  ProcedureReturn Result
EndProcedure

Procedure Open_Window_0()
  If OpenWindow(#Window_0, 257, 202, 285, 200, "Connect inet",  #PB_Window_Invisible | #PB_Window_MinimizeGadget | #PB_Window_ScreenCentered | #PB_Window_TitleBar )
    ;If CreateGadgetList(WindowID(#Window_0))
      ListIconGadget(#ListIcon_0, 5, 4, 184, 194, "Список инет-учёток", 170,#PB_ListIcon_GridLines|#PB_ListIcon_AlwaysShowSelection|#PB_ListIcon_FullRowSelect)
      GetConnectList(#ListIcon_0)
      ButtonGadget(#Button_0, 195, 80, 85, 25, "Соеденится")
      ButtonGadget(#Button_1, 195, 110, 85, 25, "Разъеденится")
      HideWindow(#Window_0, 0)
    ;EndIf
  EndIf
EndProcedure

ConnectStatus.RASCONNSTATUS

Open_Window_0()


Repeat  
  Event=WaitWindowEvent()
  If Event=#PB_Event_Gadget
    Select EventGadget()
      Case #Button_0
        Pos=GetGadgetState(#ListIcon_0)
        If Pos>=0
          If Inet_ConnectionID<>0
            DisConnect(Inet_ConnectionID)
            Inet_ConnectionID=0
          EndIf
          ConnectName.s=GetGadgetItemText(#ListIcon_0,Pos,0)
          If ConnectName
            Inet_ConnectionID=Connect(ConnectName)
            If Inet_ConnectionID
              ConnectStatus\dwSize = SizeOf(RASCONNSTATUS)
              StatusConnect(ConnectionID, @ConnectStatus)
              If  ConnectStatus\RasConnState
                DisableGadget(#ListIcon_0,1) : DisableGadget(#Button_0,1)
              Else
                MessageRequester("", "Произошла ошибка при установке связи", #MB_OK|#MB_ICONWARNING)
              EndIf
            EndIf
          EndIf
        Else
          MessageRequester("", "Выберите учетку в списке!", #MB_OK|#MB_ICONWARNING)
        EndIf
        
      Case #Button_1
        DisableGadget(#ListIcon_0,0) : DisableGadget(#Button_0,0)
        If Inet_ConnectionID<>0
          DisConnect(Inet_ConnectionID)
          Inet_ConnectionID=0
        EndIf
    EndSelect
  EndIf
Until Event=#PB_Event_CloseWindow

Во вложении исходник и скомпилированная прога.

[Mr_ViK]

*PB* Большое спасибо... но я нифига не могу разобраться в этом языке... можешь обьснить? мне нужна только процедура обнаружения учеток, еще раз спасибо!

[*PB*]

Сообщение от Mr_ViK

мне нужна только процедура обнаружения учеток

Список учеток.

#ERROR_BUFFER_TOO_SMALL = 603
 
Structure  RASENTRYNAME95
  dwSize.l
  szEntryName.s{#MAX_PATH}
EndStructure

Procedure.s GetConnectList() ; Список подключений.
  Protected  Dim ConnectList.RASENTRYNAME95(255)
  String.s=""
  ConnectList(0)\dwSize = SizeOf(RASENTRYNAME95) 
  Size=256 * ConnectList(0)\dwSize
  v=RasEnumEntries_(#Null, #Null, @ConnectList(), @Size, @ln) 
  If v=#ERROR_BUFFER_TOO_SMALL
    RasEnumEntries_(#Null, #Null, @ConnectList(), @Size, @ln)
  EndIf
  For l = 0 To ln - 1
    String + ConnectList(l)\szEntryName + Chr(10)
  Next 
  ProcedureReturn String
EndProcedure

MessageRequester("Список учеток", GetConnectList())
End

Ищите описание WinAPI функции RasEnumEntries.
Именно она вам нужна в этом случае.

[Mr_ViK]

*PB* Если ты можешь, перепиши этот кусок, я не понимаю этого языка

[*PB*]

Тогда читайте это http://msdn.microsoft.com/en-us/libr...(v=vs.85).aspx

PS.
Может лучше создам DLL из кода?
И из VB будете ее вызывать?