Сложение(Add)

[Rymbil]

Напишите мне пожалуста программу чтоб складывала 2 числа и выводила на экран. У меня почему то символ выводится вместо ответа например число 3 это сердечко, а 2 это смайл
Вот мой код:

model small 
stack 256 
.data 
a db 0 
.code 
main: 
mov ax,@data 
mov ds,ax 
mov al,2 
add al,1 
mov a,al 
mov ah,9 
lea dx,a[+'$'] 
int 21h 
mov ah,7 
int 21h 
mov ax,4c00h 
int 21h 
end main

ЗЫ: Tasm

Что делаю не так?

[Sparky]

см вот эту тему http://programmersforum.ru/showthread.php?t=79701 мой ответ на твой вопрос там

[Mikl___]

Rymbil
то что получится в результате вычисления и то что нужно выводить в файл или на экран -- две большие разницы, надеюсь что ты это понял

У меня почему то символ выводится вместо ответа например число 3 это сердечко, а 2 это смайл

для того чтобы на экран вывести число от 0 до 9 требуется выводить на экран символы с кодом от 30h до 39h в твоем случае

mov al,2 
add al,1 
add al,'0'
mov a,al

если требуется вывести на экран число от 10 до 255, то под результат нужно отвести три байта и в конце поставить символ доллара

.data 
a db 0,0,0,'$' 
.code 
...
	mov al,128 
	add al,41; AL=169=0A9h 
 	aam; делим число в AL на 10, частное окажется в AH, остаток в AL  AX=1009h
	add al,'0'
	mov [a+2],al
	shr ax,8; AX=0010h
	aam; AX=0106h
	xchg ah,al; меняем содержимое в AL и AH местами
	add ax,3030h; корректируем перед выводом на экран
	mov a,ax; передаем результат в переменную

код lea dx,a[+'$'] полностью не верный нужно или в data писать a db 0,'$' или если требуется писать в коде mov byte ptr [a+1],'$'
если адрес переменной [a] равен 64h, то команда lea dx,a[+'$'] поместит в DX число 88h (64h+24h=88h код '$'=24h)

[Rymbil]

Типа работает ответ не больше 9 должен быть, и ответ выводится не в верхнем левом углу

model small 
stack 256 
.data 
a db 0 
.code 
main: 
mov ax,@data 
mov ds,ax 
mov al,5 
add al,4
add al,'0'
mov a,al 
mov ah,9 
lea dx,a[+'$']
int 21h 
mov ah,7 
int 21h 
mov ax,4c00h 
int 21h 
end main

Если без lea dx,a[+'$'] то после ответа выводит много мусора и пищит

[Sparky]

не ты издеваешься?
Ладно пишу еще раз

;процедура ввода	
input proc near
	xor ax,ax
	xor dx,dx
	xor bx,bx
	xor di,di
	mov ah,0ah
	mov dx,offset buff ; адрес буфера
	int 21h 
	
;перевести строку
	mov dl,0ah
	mov ah,02h
	int 21h 
	
; обрабатываем содержимое буфера
	mov si,offset buff+2 ;адрес начала строки
start:
	cmp byte ptr[si]," "
	je _prop
	cmp byte ptr [si],"-" ; если первый символ минус
	jnz _poloz	;в противном случае перейти на обработку положительных
	mov di,1  ; устанавливаем флаг
_prop:
	inc si    ; переходим на следующее
	jmp start
_poloz:
	xor ax,ax
	mov bx,10  ; основание системы счисления
_perevod:
	mov cl,[si] ; берем символ из буфера
	cmp cl,0dh  ; проверям равен ли символ переводу строки
	jz _endin	;перейти на конец обработки
	
; если символ не последний, то проверяем его на правильность
	cmp cl,30h  ; если введен неверный символ <0
    	jl _err	
    	cmp cl,39h  ; если введен неверный символ >9
    	ja _err

	sub cl,30h ; делаем из символа число 
	mul bx     ; умножаем на 10
	jc _err
	add ax,cx  ; прибавляем к остальным
	jc _err
	inc si     ; переходим на следующее число

	cmp di,1
	je srav_32768
	cmp ax,32767
	ja _err
	jmp _perevod	; повторяем
srav_32768:
	cmp ax,32768
	ja _err	
	
	jmp _perevod	; повторяем


; если была ошибка, то выводим сообщение об этом и выходим
_err:
	mov dx, offset error
	mov ah,09
	int 21h
	int 20h

; все символы из буфера обработаны число находится в ax
_endin:
	
	cmp di,1 ; если установлен флаг, то
	jnz _endp
	neg ax   ; делаем число отрицательным
	
_endp:	
	ret
endp input

;====================================================================
;процедура вывода
output proc near  
;; Проверяем число на знак.
        test    ax, ax
        jns     @oi1

;; Если оно отрицательное, выведем минус и оставим его модуль.
	  push ax
        mov     ah, 02h
        mov     dl, '-'
        int     21h
        pop ax
        neg ax
        
;; Количество цифр будем держать в CX.
@oi1:  
        xor     cx, cx
        mov     bx, 10
@oi2:   
       ;cwd
       xor dx,dx
       div bx
; Делим число на десять. В остатке получается последняя цифра.
; Сразу выводить её нельзя, поэтому сохраним её в стэке.
        push    dx
        inc     cx
; А с частным повторяем то же самое, отделяя от него очередную
; цифру справа, пока не останется ноль, что значит, что дальше
; слева только нули.
        test    ax, ax
        jnz     @oi2
; Теперь приступим к выводу.
        mov     ah, 02h
@oi3:   pop     dx
; Извлекаем очередную цифру, переводим её в символ и выводим.
        add     dl, 30h
        int     21h
; Повторим ровно столько раз, сколько цифр насчитали.
        loop    @oi3
	ret
endp output

вызывается командой call, то что ввели или вывели на ax

[Doholyan]

Сообщение от Rymbil

Типа работает ответ не больше 9 должен быть, и ответ выводится не в верхнем левом углу

Так понимаю тебе нужно выводить результат именно вверхнем левом углу....тогда тебе нужно переключиться в графический режим или проще всего
прописать положения курсора
mov ah,2
mov dh,? <----столбец
mov dl,? <---- строка ;положения курсора
mov bh,0
int 10h

[Rymbil]

Спасибо всем, все работает!

[Billy Spleen]

Проверил все работает

model small
stack 256
.data
a db 0
.code
main:
mov ax,@data
mov ds,ax
mov al, a
add al,1
mov ah, 2h
mov dl, al
add dl, 30h
int 21h
mov ah, 1h
int 21h
mov ax,4c00h
int 21h
end main