Как отправить мастеру импорта текстов несколько нажатий клавиш

[Oooleg]

Приветствую Вас!

Подскажите пожалуйста, как правильно реализовать следующее:

при открытии, после диалога выбора текстового файла появляется диалог мастера текстов, в котором в три шага необходимо определять параметры импорта текста. Определение всех этих параметров сводится к нажатию следующей комбинации клавиш : Enter-Enter-Tab-Tab-KeyDown-Enter, но нажимать каждый раз эту комбинацию не очень удобно.

Подскажите как в коде правильно описать эти действия

[EducatedFool]

Послать нажатия диалоговому окну вряд ли получится
Но есть способ намного проще (и правильнее) - программно открыть этот текстовый файл, указав параметры его обработки.

Достаточно одной строки кода типа этой:

Workbooks.OpenText Filename:=ИмяФайла, DataType:=xlDelimited, Comma:=True, FieldInfo:=Array(1, 2)

В этой строке и указываются все параметры, которые можно назначить в диалоговом окне мастера текстов.

Пример есть здесь:
http://www.programmersforum.ru/showp...75&postcount=2

Макрос будет выглядеть примерно так:

Sub test()
    ChDrive "D": ChDir "D:\рабочий стол\Заявки 2008г"
    iFullName = Application.GetOpenFilename("Текстовые файлы (*.txt),*.txt")
    If iFullName = False Then Exit Sub
    Workbooks.OpenText Filename:=iFullName, DataType:=xlDelimited, Comma:=True, FieldInfo:=Array(1, 2)
End Sub

Пример использования функции GetOpenFilename

Sub test_GetOpenFilename()
    ChDrive "D"
    'Если необходимо изменить текущий диск
    'Укажите реально существующий диск
    ChDir "D:\рабочий стол\Заявки 2008г"
    'Укажите реально существующую папку
    'Если Вы сомневаетесь в её наличии, то можно использовать
    'предварительную проверку If Dir(iPath, vbDirectory) <> "" Then

    iFullName = Application.GetOpenFilename( _
                FileFilter:="Текстовые файлы (*.txt),*.txt", _
                Title:="Выберите нужный файл и кликните кнопку")

    If iFullName <> False Then
        MsgBox "Вы выбрали файл :  " & iFullName, , ""
    Else
        MsgBox "Вы отказались от выбора файла", , ""
    End If
End Sub

[Oooleg]

открываю файл следующим образом:

ChDir ActiveWorkbook.Path
iFullName = Application.GetOpenFilename("Все файлы (*.*),*.*")
If iFullName = False Then Exit Sub
Workbooks.OpenText Filename:=iFullName _
, Origin:=866, StartRow:=1, DataType:=xlDelimited, TextQualifier:= _
xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=True, Semicolon:=False _
, Comma:=False, Space:=False, Other:=False, FieldInfo:=Array(1, 1), _
TrailingMinusNumbers:=True

все работает, но импортированный текст автоматичесски форматируется Exel'ем, это мне совсем не нужно. Может можно как-нибудь програмно отключить аавтоформатирование или что то изменить в моем коде так чтобы текст в любом случае импортировался как текст.

[EducatedFool]

Попробуйте так:

ChDir ActiveWorkbook.Path
iFullName = Application.GetOpenFilename("Все файлы (*.*),*.*")
If iFullName = False Then Exit Sub
Workbooks.OpenText Filename:=iFullName, Origin:=866, StartRow:=1, DataType:=xlDelimited, _
                   TextQualifier:=xlDoubleQuote, ConsecutiveDelimiter:=False, Tab:=True, Semicolon:=False, _
                   Comma:=False, Space:=False, Other:=False, FieldInfo:=Array(1, 2), TrailingMinusNumbers:=True

[Oooleg]

спасибо, помогло

если не затруднит, не могли бы вы объяснить какая разница между
... FieldInfo:=Array(1, 1), ...
и
... FieldInfo:=Array(1, 2),..

[EducatedFool]

1. Ставим курсор в коде на слово OpenText
2. Нажимаем F1
3. В открывшейся справке по методу находим параметр FieldInfo
4. Находим в описании этого параметра ссылку XlColumnDataType
5. Щелкаем на ней, и читаем подробное описание.

XlColumnDataType can be one of these XlColumnDataType constants.

xlGeneralFormat General ' по умолчанию - 1-й параметр
xlTextFormat Text ' а нам нужен этот
xlMDYFormat MDY date
xlDMYFormat DMY date
xlYMDFormat YMD date
xlMYDFormat MYD date
xlDYMFormat DYM date
xlYDMFormat YDM date
xlEMDFormat EMD date
xlSkipColumn Skip Column

[Oooleg]

познавательно, спасибо.