Можно ли макросом, отключить колесико мышки

[valerij]

Можно ли макросом, отключить колесико мышки?

[EducatedFool]

Можно, но очень сложно. Даже не буду приводить примеры - там очень много строк кода...

Можно для этого использовать сторонние программы, но управлять ими из Excel тоже не очень просто.

Самый простой и надёжный способ (без макроса) - вытащить / выломать колёсико из мыши. Для надёжности можно вообще отключить мышь (ну и клавиатуру заодно).

Кстати, полностью отключить мышь (программно) не так сложно - делается одной командой... Правда, для её включения соответствующей команды нет...

Может, Вам пригодятся стандартные функции Excel:

Например, ActiveSheet.ScrollArea = "f77" отображает ячейку f77 и запрещает скроллинг (и ручную прокрутку) листа.

А команда ActiveSheet.ScrollArea = "" восстанавливает возможность перехода к другим ячейкам.

[valerij]

Сообщение от EducatedFool

Можно для этого использовать сторонние программы.

Знаю, но не желательно, мне именно в одном файле xls, желательно скролл отключить
Сделал так
ActiveSheet.ScrollArea = "A1:O27"
Класс, кадр как в копаный, но переключить на др. кадр A29:O55, не могу.

вытащить / выломать колёсико из мыши..

Супер мысль, поставить микрик, надо – не надо!!(на полном серьезе)

[EducatedFool]

Сделал так
ActiveSheet.ScrollArea = "A1:O27"
Класс, кадр как в копаный, но переключить на др. кадр A29:O55, не могу.

Всё нормально переключается... (Excel 2003 rus)

Sub test()
    ' работаем с одним диапазоном
    ActiveSheet.ScrollArea = "A11:O57"
    ' потом переключаемся на другой
    ActiveSheet.ScrollArea = "A211:O257"
End Sub

Или так:

Sub test2()
    ' прокручиваем экран до нужной строки
    ActiveWindow.ScrollRow = 40
    ' блокируем все ячейки кроме А40
    ActiveSheet.ScrollArea = "A40"
    ' или оставляем доступным диапазон ячеек
    ActiveSheet.ScrollArea = "A40:h80"
    ' потом, если надо, отключаем блокировку
    ActiveSheet.ScrollArea = ""
    ' и снова ставим блокировку
    ActiveSheet.ScrollArea = "A140:h180"
End Sub

[valerij]

Сообщение от EducatedFool

Всё нормально переключается... (Excel 2003 rus)

То же Excel 2003 rus, а как Вы переключаете(чем)?

Поясню, мне надо, что бы на экране, стоял кадр в диап. "A1:O27", при нажатии кл. PgDn, кадр сменился с шагом 28, т. е. "A29:O55" и т. д.(вниз), а при нажатии кл. PgUp, назад(вверх) и при этом колесико не должно работать(Что бы не возможно, колесиком, установить кадр, вне шага 28)
У меня есть, замечательный макрос, написанный Уважаемым SAS888, вот он

Public Const St = 28 'Требуемый шаг
Public AdrR As Long
Public AdrC As Long
Sub Vniz()
    AdrR = ActiveCell.Row + St: AdrC = ActiveCell.Column
    If AdrR > 1582 Then AdrR = 3
    On Error Resume Next
    Application.Goto Cells(ActiveWindow.ScrollRow + St, ActiveWindow.ScrollColumn), True
    Cells(AdrR, AdrC).Select
End Sub
Sub Vverh()
    AdrR = ActiveCell.Row - St: AdrC = ActiveCell.Column
    If AdrR < 0 Then AdrR = 3
    On Error Resume Next
    Application.Goto Cells(ActiveWindow.ScrollRow - St, ActiveWindow.ScrollColumn), True
    Cells(AdrR, AdrC).Select
End Sub

Запускается он так

Private Sub Workbook_Open()
    With Application
        .ScreenUpdating = False
        .EnableEvents = False
                .OnKey "{PGDN}", "Vniz"
                .OnKey "{PGUP}", "Vverh"
        .EnableEvents = True
        .ScreenUpdating = True
    End With
End Sub

Может мона тут "подхимичить" для колесика?

[EducatedFool]

а как Вы переключаете(чем)?

Как чем? Макросом, естественно...
Привёл же пример:

Sub test()
    ' работаем с одним диапазоном
    ActiveSheet.ScrollArea = "A11:O57"
    ' потом переключаемся на другой
    ActiveSheet.ScrollArea = "A211:O257"
End Sub

Поработали с одним диапазоном (к примеру, "A11:O57"), потом, когда надо, переключились на следующий командой ActiveSheet.ScrollArea = "A211:O257"

Может мона тут "подхимичить" для колесика?

Попробуйте такой вариант:

Sub Vniz()
    AdrR = ActiveCell.Row + St: AdrC = ActiveCell.Column
    If AdrR > 1582 Then AdrR = 3
    On Error Resume Next
'    Application.Goto Cells(ActiveWindow.ScrollRow + St, ActiveWindow.ScrollColumn), True
'    Cells(AdrR, AdrC).Select
    ActiveSheet.ScrollArea = "" ' временно отключаем блокировку, чтобы можно было пролистать экран
    ActiveWindow.ScrollRow = ActiveWindow.ScrollRow + St ' проматываем экран на St = 28 строк вниз
    Dim area As Range ' area - диапазон доступных для редактирования ячеек
    Set area = Range(Cells(ActiveWindow.ScrollRow, "A"), Cells(ActiveWindow.ScrollRow + St - 1, "O"))
    ActiveSheet.ScrollArea = area.Address: area.Cells(1).Select
End Sub

Sub Vverh()
    AdrR = ActiveCell.Row - St: AdrC = ActiveCell.Column
    If AdrR < 0 Then AdrR = 3
    On Error Resume Next
    'Application.Goto Cells(ActiveWindow.ScrollRow - St, ActiveWindow.ScrollColumn), True
    'Cells(AdrR, AdrC).Select
    ActiveSheet.ScrollArea = "" ' временно отключаем блокировку, чтобы можно было пролистать экран
    ActiveWindow.ScrollRow = ActiveWindow.ScrollRow - St ' проматываем экран на St = 28 строк вверх
    Dim area As Range ' area - диапазон доступных для редактирования ячеек
    Set area = Range(Cells(ActiveWindow.ScrollRow, "A"), Cells(ActiveWindow.ScrollRow + St - 1, "O"))
    ActiveSheet.ScrollArea = area.Address: area.Cells(1).Select
End Sub

[valerij]

Сообщение от EducatedFool

Попробуйте такой вариант:

Попробовал, сори, не-до-объяснил в задачи.
У меня сидят полные ламера, они в жизни не догадаются(объяснять....), что бы сработал макрос нужно щелкнуть кл. PgDn.
Поэтому нужно, что бы открыл файл и все, кадр "A1:O27", вкопанный, кнопками листаем....

[EducatedFool]

Так в чём проблема?

Добавьте при запуске книги команду ActiveSheet.ScrollArea = "A1:O27", и всё.

Теперь Вашим "ламерам" только и останется, что листать файл заданными Вами кнопками - "{PGDN}"и "{PGUP}"

Получится примерно так:

Private Sub Workbook_Open()
    Application.OnKey "{PGDN}", "Vniz"
    Application.OnKey "{PGUP}", "Vverh"
    ActiveSheet.ScrollArea = "A1:O27"
    [a1].Select
End Sub

они в жизни не догадаются(объяснять....), что бы сработал макрос нужно щелкнуть кл. PgDn.

А Вы им ко всему прочему хотите ещё и прокрутку заблокировать...
Так разъясните им, что и как надо нажимать, а потом и блокируйте прокрутку...

[valerij]

Сообщение от EducatedFool

А Вы им ко всему прочему хотите ещё и прокрутку заблокировать...

Если я не заблокирую прокрутку, умудрятся, чуть прокрутить и в разные числа будут вводить данные!

Теперь все работает, только как сделать что бы курсор прыгал не в А1, А29...., а при перещелкивании на D3, D31....
ActiveSheet.ScrollArea = "A1:O27"
[D3].Select

А еще лучше, сохраниться на месте выхода из файла

Разобрался, все ОК
при запуске книги, убрал команду ActiveSheet.ScrollArea = "A1:O27", но добавил
Run "Vniz"
Run "Vverh"
А в макросах "Vniz, Vverh" поменял значение на
area.Cells(St - 25, 4).Select