Автоматический подгон ширины колонок под шапку таблицы средствами VBA в MS Word

[Prokopulka]

Доброго времени суток! Помогите, пожалуйста, решить такую проблему.

Из Lotus Notes в Word выводятся данные, затем автоматически заносятся в таблицу.
В таблицу все заносится, как надо, но проблема в том, что ширина колонок таблицы не совпадает с шириной колонок в ее шапке. (Шапка в Word написана заранее)

Что надо дописать в коде, чтобы макрос автоматом подгонял ширину колонок самой таблицы под ширину колонок в шапке?

PS: Пересмотрела темы по этому разделу форума - ничего подходящего не смогла найти.
Помогите, ПОЖАЛУЙСТА.

[viter.alex]

Гораздо проще будет не подгонять ширину столбцов первой строки, а создать эту строку заново:

Sub AddHeaderRow()
  'Если курсор не в таблице, то выходим
  If Not Selection.Information(wdWithInTable) Then
    MsgBox "Поставьте курсор в первую строку таблицы!", vbInformation, "Добавить заголовок"
    Exit Sub
  End If
  
  Dim oRow As Row
  Dim bm As Bookmark
  'Добавляем строку сверху
  Set oRow = Selection.Rows.Add(Selection.Rows(1))
  With oRow.Cells
    'Вертикальное положение текста в ячейке по центру
    .VerticalAlignment = wdCellAlignVerticalCenter
    'Текст и горизонтальное выравнивание первой ячейки в строке
    With .Item(1).Range
      .Text = "Должность"
      .ParagraphFormat.Alignment = wdAlignParagraphCenter
    End With
    'Текст и горизонтальное выравнивание второй ячейки в строке
    With .Item(2).Range
      .Text = "ФИО"
      .ParagraphFormat.Alignment = wdAlignParagraphCenter
    End With
    'Текст и горизонтальное выравнивание пятой ячейки в строке
    With .Item(5).Range
      .Text = "Решение"
      .ParagraphFormat.Alignment = wdAlignParagraphCenter
    End With
    'Текст и горизонтальное выравнивание шестой ячейки в строке
    With .Item(6).Range
      .Text = "Комментарии"
      .ParagraphFormat.Alignment = wdAlignParagraphCenter
    End With
    'Выделяем треью ячейку
    .Item(3).Select
  End With
  
  Dim cell3 As Cell, cell4 As Cell, cell1 As Cell
  With Selection
    'Временная закладка, чтобы к ней вернуться после разбиения ячеек
    Set bm = .Bookmarks.Add("ttt", .Range)
    'Расширяем выделение вправо
    .MoveRight Extend:=wdExtend
    'Разбиваем ячейки на две строки
    .Cells.Split 2, 1, False
    'Выделяем закладку и расширяем выделение вправо, чтобы охватить все ячейки после разбиения
    bm.Select
    .MoveRight Extend:=wdExtend
    'Удаляем временную закладку
    bm.Delete
    'Горизонтальное выравнивание в ячейках
    .ParagraphFormat.Alignment = wdAlignParagraphCenter
    'Запоминаем ячейки
    Set cell1 = .Cells(1)
    Set cell3 = .Cells(3)
    Set cell4 = .Cells(4)
    'Заносим текст в ячейки
    cell3.Range.Text = "поступления"
    cell4.Range.Text = "окончания"
    'Выделяем ячейку и объединяем её с соседней
    cell1.Select
    .MoveRight Extend:=wdExtend
    .Cells.Merge
    .Text = "Дата и время"
    .ParagraphFormat.Alignment = wdAlignParagraphCenter
  End With
End Sub

Но может я ошибаюсь

[Prokopulka]

Спасибо большое за ответ, я об этом тоже думала, но хотела отделаться небольшой корректировкой кода Буду тогда так делать.