Удалить ячейки из Нех массива

[valerij]

Всем привет, опять вопрос.
Есть массив в А-А от 1 - 529646
38F09FE538F09FE5
65534F4C2D654269
6E6465722D4C0000
0000A0E10000A0E1
Нужно удалить ячейки содержащие первые любые буквы, т. е. оставить только цифры и удалить пустые ячейки.
Рекодер

For x = 1 To 529646
    Cells.Find(What:="F", After:=ActiveCell, LookIn:=xlFormulas, LookAt:= _
        xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=False _
        , SearchFormat:=False).Activate
    Selection.ClearContents
Next

Меняю букву от А до F и всё как бы ОК, но как собрать в кучу, без пустых ячеек???
Бо просмотреть остаток - !!!!!

[IgorGO]

нужно удалить ячейки содержащие букву в первой позиции или в любой?

[valerij]

Сообщение от IgorGO

нужно удалить ячейки содержащие букву в первой позиции или в любой?

В любой позиции.
Вот например число
65534F4C2D654269

Есть первая буква F и удалить эту ячейку и не важно, что там ещё есть буквы.
Мне из массива нужно отсеять числа с буквами.

[IgorGO]

Sub DelCharAndBlank()
  Dim r As Long, rg As Range, a
  Columns("A:A").NumberFormat = "@"
  r = Cells(Rows.Count, 1).End(xlUp).Row
  Cells(1, 1).Resize(r, 1).TextToColumns Destination:=Range("A1"), DataType:=xlFixedWidth, _
    FieldInfo:=Array(Array(0, 1), Array(1, 1), Array(2, 1), Array(3, 1), Array(4, 1), Array _
    (5, 1), Array(6, 1), Array(7, 1), Array(8, 1), Array(9, 1), Array(10, 1), Array(11, 1), Array _
    (12, 1), Array(13, 1), Array(14, 1), Array(15, 1), Array(16, 1)), TrailingMinusNumbers:=True
  On Error Resume Next
  Set rg = Cells(1, 1).Resize(r, 16).SpecialCells(xlCellTypeConstants, xlTextValues).EntireRow
  Application.Union(rg, rg).Delete
  
  r = Cells(Rows.Count, 1).End(xlUp).Row:  a = Cells(1, 1).Resize(r, 16).Value
  For r = 1 To r
    a(r, 1) = Join(Application.Index(a, r), "")
  Next
  Cells(1, 1).Resize(r - 1, 1).Value = a:  Range("B:P").ClearContents
End Sub

[valerij]

Сообщение от IgorGO

Sub DelCharAndBlank()

Игорь вот сам глянь, чито он, макрос - делает.

Игорь ты понял правильно?
Вот пример - данные

202053657269616C
3A20257300000000
0008101820283038
4048505860687078
800A0A0A0A0A0A0A
0A06060606050505
0505050504040404
0000000000000001

После выполнения - удалить с буквой

пустая яч.
пустая яч.
0008101820283038
4048505860687078
пустая яч.
пустая яч.
0505050504040404
0000000000000001

После выполнения - упорядочить.

0008101820283038
4048505860687078
0505050504040404
0000000000000001

[pashulka]

valerij, Если будет время и желание, то можете попробовать :

Private Sub Test()
    Dim iCount1&, iCount2&, iArr As Variant, Item As Variant
    iArr = Range(Cells(1), Cells(Rows.Count, 1).End(xlUp))
    
    For iCount1 = 1 To UBound(iArr)
        Item = iArr(iCount1, 1)
        If Not Item Like "*[A-z]*" Then 'Or? If IsNumeric(Item)
           iCount2 = iCount2 + 1
           iArr(iCount2, 1) = Item
        End If
    Next
    
    Columns(1).ClearContents '.Clear
    Cells(1).Resize(iCount2).NumberFormat = "@"
    Cells(1).Resize(iCount2) = iArr
End Sub

P.S. Если у ячеек столбца [A:A] уже установлен текстовый формат, то соответствующую строку в макросе можно удалить/закомментировать.

[valerij]

Сообщение от pashulka

можете попробовать .

Спасибо!!
СУПЕР!!!

[IgorGO]

макрос из 8 этих строк
202053657269616C
3A20257300000000
0008101820283038
4048505860687078
800A0A0A0A0A0A0A
0A06060606050505
0505050504040404
0000000000000001

оставил 4-е этих:
0008101820283038
4048505860687078
0505050504040404
0000000000000001

[pashulka]

IgorGO, Вы использовали SpecialCells a этот метод имеет ограничения, которые, при таком количестве строк, вполне могут проявиться.

[IgorGO]

pashulka,

согласен - это заготовка. Профессионал, а именно такой статус у Валерия, несколькими уверенными движениями напильника подогнал бы ее строго под свою задачу.