сложить цифры или убрать текст, что проще?

[Serge_Bliznykov]

IgorGO, гениально!!

позволю себе привести текст функции здесь:

Option Explicit

Function SummD(rg As Range) As Double
  Dim re, m, s As Double, i%
  With CreateObject("VBScript.RegExp")
    .Global = True: .Pattern = "- \d+"
    If .test(rg.Value) Then
      Set m = .Execute(rg.Value)
      For i = 0 To m.Count - 1
        s = s + Val(Right(m(i), Len(m(i)) - 2))
      Next
    End If
  End With
  SummD = s
End Function

я бы через регэкспы не смог написать, парсил бы строчку вручную.
Кода у меня было бы на порядок больше. И писал бы отлаживал я его соответственно долго и мучительно!

Спасибо за код! Получил эстетическое наслажение!

[IgorGO]

Спасибо, Серегей!

я рад)))

в функции порядка 300 символов и реально затраты времени на ее написание свелись к попаданию пальцами по 300 кнопкам в определенном порядке

все, что нужно РегЭскпрессу - это корректный шаблон поиска. в данном случае и над этим элементом думать не пришлось (даже при моих скромных знаниях РегЭксп)

[xelen5]

Спасибо , приятно очень!
Это макрос? Но что-то когда тяну на нижнюю ячейку, не работает. пишет #ИМЯ?

[svsh2016]

добрый день,еще вариант функции в столбце N

Function SummD1#(t$)
  Dim m As Object, i%
  With CreateObject("VBScript.RegExp"): .Global = True: .Pattern = "- \d+"
    If .test(t) Then
      Set m = .Execute(t)
      For i = 0 To m.Count - 1
        SummD1 = SummD1 + Mid(m(i), 3)
      Next
    End If
  End With
End Function

[IgorGO]

в файле, который я выложил в колонку К скопируйте данных с Вашего (другого) файла
в колонке М видите результаты
можете теперь скопировать колонку М с результатами обратно в исходный файл специальной вставкой, "как значения"

[svsh2016]

добрый вечер,еще два варианта функций
в столбце P

Function SummD3#(t$)
  Dim m As Object, i%
  With CreateObject("VBScript.RegExp")
    .Global = True: .Pattern = "-\s+(\d+)"
    If .test(t) Then
      Set m = .Execute(t)
      For i = 0 To m.Count - 1
        SummD3 = SummD3 + m(i).Submatches(0)
      Next
    End If
  End With
End Function

в столбце O для данного файл-примера или чисел от 0 до 9

Function SummD2#(t$)
  Dim i%
  With CreateObject("VBScript.RegExp"): .Global = True: .Pattern = "- \d"
    If .test(t) Then
      For i = 0 To .Execute(t).Count - 1
     SummD2 = SummD2 + Mid(t, .Execute(t)(i).FirstIndex + 3, 1)
      Next
    End If
  End With
End Function