Добавить только не существующие значения.

[KOSTIK1]

Доброго дня всем! Есть код -

Private Sub CommandButton1_Click()    'Добавить строки
    Application.ScreenUpdating = False
    Dim iLastRow As Long
    Dim sh As Worksheet
    Set sh = Sheets("Структура")
    If Me.ComboBox1 = "" Then MsgBox "Не введён отдел", vbCritical, "Ошибка": Exit Sub
    If Me.ComboBox2 = "" Then MsgBox "Не введена должность", vbCritical, "Ошибка": Exit Sub

    iLastRow = sh.Cells(Rows.Count, 1).End(xlUp).Row
    sh.Cells(iLastRow + 1, 1) = UserForm1.ComboBox1
    sh.Cells(iLastRow + 1, 2) = UserForm1.ComboBox2
    sh.Range("a2:b" & iLastRow + 1).Sort key1:=sh.Range("a1"), order1:=xlAscending, key2:=sh.Range("b1"), order2:=xlAscending, SortMethod:=xlPinYin

    Application.ScreenUpdating = True
    MsgBox ("Информация добавлена")
End Sub

Он вставляет данные из двух ComboBox'ов, что нужно добавить чтобы данные не дублировались, то есть, если уже имеется значение ComboBox2 в соответствующем столбце, тогда не вставлять, а просто вывести типа MsgBox ("Уже имеется")? Спасибо заранее.

[The_Prist]

В этом куске:

 iLastRow = sh.Cells(Rows.Count, 1).End(xlUp).Row
    sh.Cells(iLastRow + 1, 1) = UserForm1.ComboBox1
    sh.Cells(iLastRow + 1, 2) = UserForm1.ComboBox2
    sh.Range("a2:b" & iLastRow + 1).Sort key1:=sh.Range("a1"), order1:=xlAscending, key2:=sh.Range("b1"), order2:=xlAscending, SortMethod:=xlPinYin

добавить

 iLastRow = sh.Cells(Rows.Count, 1).End(xlUp).Row
 If Not sh.Range("a2:b" & iLastRow + 1).Find(UserForm1.ComboBox1, , xlValues, xlWhole) Is Nothing Then MsgBox "Есть"

Ну и для второго Combo

[KOSTIK1]

Спасибо The_Prist! Только у меня что то не получается, сообщения выходят, но и строки всё же дублируются(или я чтото не туда вставил?). Немного уточню, если есть строка(столбцы А и В) с сочетанием Комбобокс1(А)+Комбобокс2(В), тогда содержимое (Комбобокс1+Комбобокс2) вносится не должно, тогда MsgBox "Есть" и End Sub. Спасибо.

[The_Prist]

Я привел строку для общего понимания, как это сделать. Тогда полностью:

Private Sub CommandButton1_Click()    'Добавить строки
    Application.ScreenUpdating = False
    Dim iLastRow As Long
    Dim sh As Worksheet
    Set sh = Sheets("Структура")
    If Me.ComboBox1 = "" Then MsgBox "Не введён отдел", vbCritical, "Ошибка": Exit Sub
    If Me.ComboBox2 = "" Then MsgBox "Не введена должность", vbCritical, "Ошибка": Exit Sub

    iLastRow = sh.Cells(Rows.Count, 1).End(xlUp).Row
    With sh.Range("a2:b" & iLastRow + 1)
        If Not .Find(UserForm1.ComboBox1, , xlValues, xlWhole) Is Nothing Then
            MsgBox "Уже ж есть такое! - " & UserForm1.ComboBox1 & " Зачем нам два?!", vbExclamation, "Лишнее": Exit Sub
        Else
            sh.Cells(iLastRow + 1, 1) = UserForm1.ComboBox1
        End If

        If Not .Find(UserForm1.ComboBox2, , xlValues, xlWhole) Is Nothing Then
            MsgBox "Уже ж есть такое! - " & UserForm1.ComboBox2 & " Зачем нам два?!", vbExclamation, "Лишнее": Exit Sub
        Else
            sh.Cells(iLastRow + 1, 2) = UserForm1.ComboBox2
        End If
        .Sort key1:=sh.Range("a1"), order1:=xlAscending, key2:=sh.Range("b1"), order2:=xlAscending, SortMethod:=xlPinYin
    End With
    Application.ScreenUpdating = True
    MsgBox ("Информация добавлена")
End Sub

[KOSTIK1]

Спасибо ещё раз, но тогда я не могу внести в "Отдел" новую "Должность", а это мне необходимо.

[KOSTIK1]

Разобрался! Подправил

Private Sub CommandButton1_Click()    'Добавить строки
    Application.ScreenUpdating = False
    Dim iLastRow As Long
    Dim sh As Worksheet
    Set sh = Sheets("Структура")
    If Me.ComboBox1 = "" Then MsgBox "Не введён отдел", vbCritical, "Ошибка": Exit Sub
    If Me.ComboBox2 = "" Then MsgBox "Не введена должность", vbCritical, "Ошибка": Exit Sub

    iLastRow = sh.Cells(Rows.Count, 1).End(xlUp).Row
    With sh.Range("a2:b" & iLastRow + 1)
        If Not .Find(UserForm1.ComboBox2, , xlValues, xlWhole) Is Nothing Then
            MsgBox "Уже ж есть такое! - " & UserForm1.ComboBox2 & " Зачем нам два?!", vbExclamation, "Лишнее": Exit Sub
        Else
            sh.Cells(iLastRow + 1, 1) = UserForm1.ComboBox1
            sh.Cells(iLastRow + 1, 2) = UserForm1.ComboBox2
        End If
        .Sort key1:=sh.Range("a1"), order1:=xlAscending, key2:=sh.Range("b1"), order2:=xlAscending, SortMethod:=xlPinYin
    End With
    Application.ScreenUpdating = True
    MsgBox ("Информация добавлена")
End Sub

Спасибо!!!!!!!!

[KOSTIK1]

Прошу ещё помогите! Теперь если такая должность есть, не могу внести её в другой отдел, нужно что бы

если есть строка(столбцы А и В) с сочетанием Комбобокс1(А)+Комбобокс2(В)

только тогда не добавлялась должность, а в другие отделы эта должность вноситься могла. Спасибо.

[The_Prist]

Так что ли?

Private Sub CommandButton1_Click()    'Добавить строки
    Application.ScreenUpdating = False
    Dim iLastRow As Long
    Dim sh As Worksheet, rFndRng As Range
    Set sh = Sheets("Структура")
    If Me.ComboBox1 = "" Then MsgBox "Не введён отдел", vbCritical, "Ошибка": Exit Sub
    If Me.ComboBox2 = "" Then MsgBox "Не введена должность", vbCritical, "Ошибка": Exit Sub

    iLastRow = sh.Cells(Rows.Count, 1).End(xlUp).Row
    Set rFndRng = sh.Range("a2:a" & iLastRow + 1).Find(UserForm1.ComboBox1, , xlValues, xlWhole)
    If Not rFndRng Is Nothing Then
        If rFndRng.Offset(, 1).Value = UserForm1.ComboBox2 Then
            MsgBox "Уже ж есть такое! - " & UserForm1.ComboBox1 & " Зачем нам два?!", vbExclamation, "Лишнее": Exit Sub
        Else
            sh.Cells(iLastRow + 1, 1) = UserForm1.ComboBox1
            sh.Cells(iLastRow + 1, 2) = UserForm1.ComboBox2
        End If
    Else
        sh.Cells(iLastRow + 1, 1) = UserForm1.ComboBox1
        sh.Cells(iLastRow + 1, 2) = UserForm1.ComboBox2
    End If
    sh.Range("a2:b" & iLastRow + 1).Sort key1:=sh.Range("a1"), order1:=xlAscending, key2:=sh.Range("b1"), _
                                         order2:=xlAscending, SortMethod:=xlPinYin

    Application.ScreenUpdating = True
    MsgBox ("Информация добавлена")
End Sub

Или я вообще не так понял?

[KOSTIK1]

Принцип такой, в каждом "отделе" может быть только по одной например "уборщице" если я хочу добавить ещё раз "уборщицу" то эта "Должность" в выбранном "отделе" дублироваться не должна. Примерно так.

[The_Prist]

Сообщение от KOSTIK1

Принцип такой, в каждом "отделе" может быть только по одной например "уборщице" если я хочу добавить ещё раз "уборщицу" то эта "Должность" в выбранном "отделе" дублироваться не должна. Примерно так.

Ну так вариант выше не подходит? Хотя, наверное, не очень. Т.к. в результате, у Вас и отделы и должности дублируются в каждом столбце. Т.е. надо делать цикл по всем должностям одного отдела, чтобы понять - есть ли там уже такая или нет.