Передача одного из параметров в регистре EDX

[chertovich]

Всем привет.
Вопрос такой. Пишу процедуру на встроенном ассемблере в Delphi.
Вот код:

procedure TSoundData.FRearrange(var Data, Buffer; Count: Integer);
var
  // Размер блока в словах, на который разделены данные
  HalfSize: Integer;

  // Размер данных в словах
  Size: Integer;

  // Содержит количество блоков, на которые разделены данных
  HalfCount: Integer;
asm
  push EBX
  push ESI
  push EDI

  cld

  // Получение размера данных в словах
  mov EAX, Count
  shr EAX, 1
  mov Size, EAX

  // Инициализация HalfSize размером данных
  mov HalfSize, EAX

  // Инициализация количества блоков данных
  mov HalfCount, 1

@main:
  // Если половинный размер <= 2 (в двойных словах) то выход из цикла
  cmp HalfSize, 2
  jbe @exit

  // Копирование в буфер
  mov ESI, Data
  mov EDI, Buffer
  mov ECX, Size
  shr ECX, 1
  rep movsd

  // Установка количества блоков данных
  mov ECX, HalfCount

@copy:
  // Уменьшаем на 1, чтобы вычислить адрес блока
  dec ECX

  // Вычисление адреса приемника данных
  mov EAX, ECX
  mul HalfSize
  shl EAX, 1
  add EAX, Data
  mov EDI, EAX

  //mov EDI, Data
  // Вычисление относительного адреса источника данных
  mov EAX, ECX
  mul HalfSize
  shl EAX, 1

  // Вычисление количества итераций для копирования четных или нечетных слов
  mov EBX, HalfSize
  shr EBX, 1

  // Установка адреса источника данных
  mov ESI, EAX
  add ESI, Buffer

  // Установка количества итераций
  mov EDX, EBX

// Копирование четных данных
@copy_even:
  add ESI, 2
  movsw
  dec EDX
  jnz @copy_even

  // Установка адреса источника данных
  mov ESI, EAX
  add ESI, Buffer

  // Установка количества итераций
  mov EDX, EBX

// Копирование нечетных данных
@copy_odd:
  movsw
  add ESI, 2
  dec EDX
  jnz @copy_odd

  // Если не все половинки обработаны то продолжаем, иначе выход
  cmp ECX, 0
  ja @copy

  // Делим HalfSize на 2
  shr HalfSize, 1

  // Определение количества блоков данных
  shl HalfCount, 1

  jmp @main

@exit:
  pop EDI
  pop ESI
  pop EBX
end;

Соглашение о передаче параметров стоит по умолчанию, то есть "register" не ставил.
Но адрес, который передается как параметр Data передается не через стек, а через регистр EDX.
При выполнении команды mul (строчку кода выделил жирным и подчеркнул, этот же код на изображении ниже) регистр EDX "затирается" и вместе с ним и мой парметр Data.
Прикрепляю код в отладчике:


Хотелось бы узнать, я где-то ошибаюсь или это компилятор что-то попутал? Я же его не прошу передавать параметры через регистры.

[chertovich]

Оказывается передача параметров через регистры стоит по умолчанию.
Какой посоветуете ставить соглашение вызова? Pascal или stdcall, и почему?

[Пепел Феникса]

я бы оставил по умолчанию если нет нужды экспорта, иначе stdcall.

[chertovich]

Сообщение от Пепел Феникса

я бы оставил по умолчанию если нет нужды экспорта, иначе stdcall.

По умолчанию не подходит, ко причине проблемы о которой я написал выше. Я поставил stdcall

[Пепел Феникса]

ну тогда совет напоследок, для асм процедур строго указывайте соглашение о вызове.

[chertovich]

Сообщение от Пепел Феникса

ну тогда совет напоследок, для асм процедур строго указывайте соглашение о вызове.

Спасибо. Оно и логично, поскольку от соглашения о вызове зависит и код)