Добавить столбцы

[Arnold9131]

Здравствуйте!
У меня есть таблица состоящая из 30 строк. Надо вставить новый столбец через каждые 5 столбцов.Реализация в VBA.
Помогите пожалуйста.

[EducatedFool]

http://excelvba.ru/code/RepeatRange

Sub ВставкаСтолбцов() ' пример применения для вашей задачи
    RepeatRange(Cells(6), 10, 5, xlToRight).EntireColumn.Insert
End Sub


Function RepeatRange(ByRef SourceRange As Range, ByVal Count As Long, _
                     ByVal Offset As Long, ByVal Direction As XlDirection) As Range
    ' функция получает в качестве параметра диапазон SourceRange,
   ' количество повторений диапазона Count, и шаг смещения Offset
   ' Возвращает диапазон, являющийся объединением копий диапазона SourceRange,
   ' смещённого на Offset ячеек Count раз в направлении Direction.

    Select Case Direction
        Case xlDown: OffsetX = 0: OffsetY = Offset
        Case xlUp: OffsetX = 0: OffsetY = -Offset
        Case xlToRight: OffsetX = Offset: OffsetY = 0
        Case xlToLeft: OffsetX = -Offset: OffsetY = 0
    End Select

    Set RepeatRange = SourceRange
    For i = 1 To Count - 1
        Set RepeatRange = Union(RepeatRange, SourceRange.Offset(OffsetY * i, OffsetX * i))
    Next i
End Function

[SAS888]

Еще вариант (упрощенный):

Sub qq()
    InsColumns([B2:AD20], 5).Insert
End Sub

Function InsColumns(x As Range, n As Long) As Range
    Dim i As Long
    Set InsColumns = Columns(x.Column + n)
    For i = x.Column + n To x.Column + x.Columns.Count Step n
        Set InsColumns = Union(InsColumns, Columns(i))
    Next
    Set InsColumns = Intersect(InsColumns, x.EntireRow)
End Function

1-й параметр функции - диапазон таблицы.
2-й параметр функции - шаг вставки столбцов.
Пример во вложении.

[IgorGO]

или так:

Sub AddTrouth()
  InsRg([B2:AD20], 7, 5).Insert
End Sub

Function InsRg(rg As Range, AtC As Long, AddC As Long) As Range
  Set InsRg = Intersect(rg, Columns(AtC))
  If AtC + AddC < rg.Column + rg.Columns.Count Then Set InsRg = Union(InsRg, InsRg(rg, AtC + AddC, AddC))
End Function

параметры:
1 - обрабатываемый диапазон
2 - в какой колонке сделать первую вставку
3 - через сколько колонок добавлять следующие