Печать числа

[Vistar]

Подскажите почему не выводится сумма чисел. И вообще не получается вывести число. Программа просто запустилась, подождала нажатия клавиши и все.

	.model	small
	.stack	100h	

	.data
x db 8h
y db 10h

	.code
start:
	mov ax, @data
	mov ds, ax

	mov dl, x
	add dl, y
	add dl, '0'
	mov ah, 2 			; печатаем символ
	int 21
	mov ah, 0
	int 16h				; ожидаем нажатия любой клавиши
	mov ax, 4c00h
	int 21h          	        ; выходим из программы

end start

[Ant1971on]

Надо h поставить после int 21.

И вместо

        add dl, '0'
	mov ah, 2 			; печатаем символ
	int 21

правильнее(для двузначных чисел) написать так:

        xor ax,ax
        mov al,dl
        aam 
        add ax,3030h 
        mov dl,ah 
        mov dh,al 
        mov ah,02 
        int 21h 
        mov dl,dh 
        int 21h

Просто добавление '0' сработает только для вывода одной цифры.

[Vistar]

Ant1971on, большое спасибо. А 3030h мы добавляем как конец строки?

[Ant1971on]

3030h добавляется к AX, где после команды aam будет уже лежать сумма в двоично-десятичном (неупакованном) представлении. После добавления 3030h сумма в AX преобразуется в ее ASCII-символы, которые затем и выводятся на экран.

[Vistar]

а как печатать двойное слово? после суммирования этих чисел выводится I5

d0	dd	12345678
d1	dd	87654321

		; d0 <- d0+d1
		mov eax, [d0]
		add eax, [d1]
		mov edx, eax
		
		; печатаем число
		xor ax,ax
                mov al,dl
                aam 
                add ax,3030h
                mov dl,ah 
                mov dh,al 
                mov ah,02 
                int 21h 
                mov dl,dh 
                int 21h

[Ant1971on]

Я же предупредил, что прежний способ годится только для двузначных чисел. Для вывода двойного слова можно сделать так:

;Предполагается, что выводимое число в eax
;проверка знака числа:

	test eax,80000000h ;число положительное ?
	jz cnvrt	;да, преобразуем в десятичное
	push eax
	mov al,'-'	;выводим минус
	int 29h
	pop eax
	neg eax		;берем модуль

;перевод числа в eax в десятичную сист. счисления:

cnvrt:	
	xor ecx,ecx	;счетчик десятичных цифр
	mov ebx,10	;основание сист. счисления
ckl:
	xor edx,edx	;расширим делимое
	div ebx
	push edx	;получаемые цифры кладем в стек
	inc cx
	test eax,eax	;делитель - ноль ?
	jnz ckl		;еще нет, продолжим

outpt:			;вывод числа на экран

	pop eax
	add al,'0'	;десятичную цифру -> в ASCII
	int 29h		;вывод цифры
	
	loop outpt

Если числа беззнаковые, кусок кода до метки cnvrt нужно убрать.