Как присвоить один объект другому

[alex_079]

Уважаемые форумчане прошу помочь по следующему вопросу:
У меня не получается присвоить один объект другому с одинаковым типом в VBA.
Поясняю - Создаю модуль класса, именую его "TEST" и наполняю нижеследующим кодом:

Public propertyInt As Integer
Public propertyBool As Boolean
Public propertyStr As String

Затем создаю модуль под именем Module1 и наполняю следующим содержимым:

Dim obj1 As New TEST
Dim obj2 As New TEST
Sub a()
obj1.propertyBool = False
obj1.propertyInt = 0
obj1.propertyStr = "a"
obj2.propertyBool = True
obj2.propertyInt = 1
obj2.propertyStr = "b"
obj1 = obj2
End Sub

Нажимаю F5 и запускаю процедуру a(). В результате появляется нижеследующая ошибка:

Run-time error '91':
Object doesn't support this property or method

Если же я вместо строчки obj1 = obj2 напишу Set obj1 = obj2 то в результате получу две ссылки (obj1 и obj2) на один и тот же объект.
А мне лишь нужно чтобы при операции присваивания одного объекта другому все свойства одного объекта присваивались свойствам другого объекта т.е. obj1.propertyBool = obj2.propertyBool, obj1.propertyInt = obj2.propertyInt, obj1.propertyStr = obj2.propertyStr. Подскажите как это правильно сделать в VBA?

[doober]

Если я правильно вас понял

'''''TEST
Private p_Int As Integer
Private p_Bool As Boolean
Private p_Str As String

Public Property Get propertyInt() As Integer
propertyInt = p_Int
End Property

Public Property Let propertyInt(ByVal vNewValue As Integer)
p_Int = vNewValue
End Property
Public Property Get propertyStr() As String
 propertyStr = p_Str
End Property

Public Property Let propertyStr(ByVal vNewValue As String)
p_Str = vNewValue
End Property

Public Property Get propertyBool() As Boolean
propertyBool = p_Bool
End Property

Public Property Let propertyBool(ByVal vNewValue As Boolean)
p_Bool = vNewValue
End Property

Dim obj1 As New TEST
 Dim obj2 As New TEST
 Sub a()
 obj1.propertyBool = False
 obj1.propertyInt = 0
 obj1.propertyStr = "a"
 obj2.propertyBool = True
 obj2.propertyInt = 1
 obj2.propertyStr = "b"
 obj1.propertyBool = obj2.propertyBool
 obj1.propertyInt = obj2.propertyInt
obj1.propertyStr = obj2.propertyStr
  
 
 End Sub

[doober]

Вариант №2

Private p_Int As Integer
Private p_Bool As Boolean
Private p_Str As String

Public Property Get propertyInt() As Integer
propertyInt = p_Int
End Property

Public Property Let propertyInt(ByVal vNewValue As Integer)
p_Int = vNewValue
End Property
Public Property Get propertyStr() As String
 propertyStr = p_Str
End Property

Public Property Let propertyStr(ByVal vNewValue As String)
p_Str = vNewValue
End Property

Public Property Get propertyBool() As Boolean
propertyBool = p_Bool
End Property

Public Property Let propertyBool(ByVal vNewValue As Boolean)
p_Bool = vNewValue
End Property

Public Sub Присвоить(ByVal X As TEST)
Me.propertyBool = X.propertyBool
Me.propertyInt = X.propertyInt
Me.propertyStr = X.propertyStr
End Sub

 Dim obj1 As New TEST
 Dim obj2 As New TEST
 Sub a()
 obj1.propertyBool = False
 obj1.propertyInt = 0
 obj1.propertyStr = "a"
 obj2.propertyBool = True
 obj2.propertyInt = 1
 obj2.propertyStr = "b"
 obj1.Присвоить obj2
 
 End Sub

[IgorGO]

или один раз это:

Sub SetO1toO2(Source, Destin)
  With Source
    Destin.propertyBool = .propertyBool
    Destin.propertyInt = .propertyInt
    Destin.propertyStr = .propertyStr
  End With
End Sub

а затем Ваше

Sub a()
  obj1.propertyBool = False
  obj1.propertyInt = 0
  obj1.propertyStr = "a"
  obj2.propertyBool = True
  obj2.propertyInt = 1
  obj2.propertyStr = "b"
  SetO1toO2 obj2, obj1
End Sub

[alex_079]

Большое спасибо Вам doober и IgorGO за примеры кода! Я воспользуюсь Вашим кодом. Просто я понадеялся что в VBA конструкция присваивания одного объекта другому может быть также лаконична как например в С++:

class c
{
public:
        int a;
        char b;
};

int main(int argc, char *argv[])
{
    c obj1, obj2;
    obj1.a = 0;
    obj1.b = 'a';
    obj2.a = 1;
    obj2.b = 'b';

    obj1 = obj2;

    return EXIT_SUCCESS;
}

Но по всей видимости механизм в VBA несколько иной. Буду привыкать) Еще раз спасибо за помощь!

[IgorGO]

Просто я понадеялся что в VBA конструкция присваивания одного объекта другому

тут Вам не Англия, тут надо глубже копать...