Макрос аля ВПР для формирования свода из закрытых книг

[MaxxVer]

Добрый день, уважаемые эксперты!
Потеряв на поиск аналогичного решения уйму времени, вынужден просить Вашей помощи в написании макроса - аналога функции ВПР, только с расширенным функционалом (указание книги для поиска). Задача довольно банальна - создать свод, но данные должны вытягиваться из нескольких закрытых книг. Пусть у нас есть несколько книг в папке (только те что в папке анализируются макросом), путь к которой мы указываем в начале выполнения макроса. Запустив макрос в книге "Свод", он ищет данные в книге, наименование которой указано в столбце "A", и возвращает значение ячейки по указанному в столбце "B" Показателю и Столбцу, указанному в диапазоне C8:F8. Заранее премного благодарен даже за совет!

[MaxxVer]

И еще скажу что наименование листа во всех книгах одинаковое, в коде макроса можно указать как "Книга1".

[MaxxVer]

Может быть я хочу многого... Эта задача вообще решаема?

[IgorGO]

элементарная задача, просто, пока она ни кому не интересна, наберитесь терпения (мир не без добрых фей) и (или) продолжайте поиски.

[MaxxVer]

Понял. Это обнадеживает. Я верю в мир и в добрых людей).

[Hugo121]

Было немного интересно
Не интересно прописывать код выбора папки - попробуйте сами, если нужно. Сейчас берётся папка из папки книги с макросом.
Ну и лень было буквы
D E H I
кодом менять на цифры - просто замените их на листе на
3 4 7 8
Если это напрягает - нужно в код добавить список соответствий или код преобразования.

Ну и почему "аля"? Вуаля

Sub tt()
    Dim cc As Range, r As Range
    Set r = [c8:f8]

    For Each cc In [a9:a16]
        cc.Offset(, 2).Formula = "=VLOOKUP(" & cc.Offset(, 1).Address(0, 0) & ",'" & ThisWorkbook.Path & "\Данные\[" & cc.Value & ".xlsx]Лист1'!$B:$I," & r(1) & " ,0)"
        cc.Offset(, 3).Formula = "=VLOOKUP(" & cc.Offset(, 1).Address(0, 0) & ",'" & ThisWorkbook.Path & "\Данные\[" & cc.Value & ".xlsx]Лист1'!$B:$I," & r(2) & " ,0)"
        cc.Offset(, 4).Formula = "=VLOOKUP(" & cc.Offset(, 1).Address(0, 0) & ",'" & ThisWorkbook.Path & "\Данные\[" & cc.Value & ".xlsx]Лист1'!$B:$I," & r(3) & " ,0)"
        cc.Offset(, 5).Formula = "=VLOOKUP(" & cc.Offset(, 1).Address(0, 0) & ",'" & ThisWorkbook.Path & "\Данные\[" & cc.Value & ".xlsx]Лист1'!$B:$I," & r(4) & " ,0)"
    Next
End Sub

Ну и в конце, если нужно, можно кодом заменить формулы на полученные значения:

 [c9:f16] = [c9:f16].Value

Версия 2 (модернизированная, но "те же яйца", но короче):

Sub ttt()
    Dim cc As Range, r As Range, i As Byte

    Set r = [c8:f8]
    Application.ScreenUpdating = False

    For Each cc In [a9:a16]
        For i = 1 To 4
            cc.Offset(, i + 1).Formula = _
            "=VLOOKUP(" & cc.Offset(, 1).Address & ",'" _
            & ThisWorkbook.Path & "\Данные\[" & cc.Value _
            & ".xlsx]Лист1'!$B:$I," & r(i) & " ,0)"
        Next
    Next

    [c9:f16] = [c9:f16].Value
    Application.ScreenUpdating = True
End Sub

[MaxxVer]

Спасибо огромное!

[MaxxVer]

Уважаемый Hugo121, подскаажите пожалуйста, как дописать код так, чтобы можно было еще выбирать имя лиса из диапазона (к примеру добавить столбец
B и вставить туда названия листов)?

[Hugo121]

Видите в коде cc.Value - это в формулу подставляется имя книги (по этому столбцу идёт перебор ячеек).
Если нужно добавить ещё и имя листа, то замените в строке ".xlsx]Лист1'!$B:$I," слово Лист1 например на " & cc.Offset(, 1).Value & " - это если имя листа будет левее имени книги.
Ну и остальное чуть скорректировать вероятно придётся, если столбцы будут двигаться.

[MaxxVer]

Еще раз спасибо! Все получилось.