Переименование группы файлов по имени заданной ячейки

[Сергей Ч.]

Помогите плиз.
MS Excel 2010
Имею порядка 200 файлов выгруженных из веб-интерфейса в одной папке.
Требуется переименовать файлы по ячейке "В1" первого листа, каждой книги соответственно.
Заранее благодарен.

[Казанский]

Сохраните как .VBS в папку с файлами и запустите.

set xlApp=createobject("excel.application")
With CreateObject("scripting.filesystemobject")
  For Each f In .GetFile(wscript.scriptfullname).ParentFolder.Files
    ext=.GetExtensionName(f.Path)
    If UCase(Left(ext, 3)) = "XLS" Then
      With xlApp.Workbooks.Open(f.Path)
        s=.worksheets(1).range("B1").value
	.close 0
      end with
      f.name=s & "." & ext
    end if
  next
end with
xlapp.quit

[Hugo121]

Может чуть дополнить для надёжности?

set xlApp=createobject("excel.application")
With CreateObject("scripting.filesystemobject")
  For Each f In .GetFile(wscript.scriptfullname).ParentFolder.Files
    ext=.GetExtensionName(f.Path)
    If UCase(Left(ext, 3)) = "XLS" Then
      With xlApp.Workbooks.Open(f.Path)
      with .worksheets(1)
        s=.range("B1").value & "_" & .range("B3").value & .range("C3").value & .range("D3").value 
        s=replace(s,"/","_")
      end with
   .close 0
      end with
      f.name=s & "." & ext
    end if
  next
end with
xlapp.quit

[Сергей Ч.]

Все работает, спасибо большое!!