Не работает "уравнение" :(

[SlimBr0ther]

Error 1004
Application-defined or object-defined error

Ругается на следующую строчку:

Worksheets("Общий").Range(Cells(13, 1), Cells(13, 9)) = Worksheets("4x16x4").Range(Cells(13 , 1), Cells(13, 9))

Что может быть? Уже голову сломал...

P.S. в справке указан пример:
Worksheets("Sheet1").Range(Cells(1, 1), Cells(5, 3)). _
Font.Italic = True

Меняю имя листа, но тоже ругается Как же так, даже пример из справки не работает!!!
Office 2002 - может поетому?

[Pavel55]

а если вот так ? )

Worksheets("4x16x4").Range("A13:I13").Copy Worksheets("Общий").Range("A13:I13")

[SlimBr0ther]

Сообщение от Pavel55

а если вот так ? )

Worksheets("4x16x4").Range("A13:I13").Copy Worksheets("Общий").Range("A13:I13")

это работает, но дело в том, что мне нужно в операторе Range использовать переменые, а в таком формате оного не получается
Или может я просто не знаю как?
Как-то можно использовать оператор Range примерно в следующем виде:

Начало = Cells(1, 1)
Конец = Cells(2,2)
Range("НАчало;Конец").ClearCcontents

[Pavel55]

у мя тоже так не работает с Cells )

А вот так не пойдёт?

Sub Макрос2()
Dim FirstCol$, LastCol$, iRow&
    FirstCol = "A"
    LastCol = "I"
    iRow = 13
    Worksheets("4x16x4").Range(FirstCol & iRow & ":" & LastCol & iRow).Copy Worksheets("Общий").Range(FirstCol & iRow & ":" & LastCol & iRow)
End Sub

[SlimBr0ther]

Супер, щас попробую... думаю должно заработать

P.S. ДА, заработало... спасибо агромнейшее

[infinitiv]

Объект Range можно задать не только с помощью "A1:B1" и т. д. но и так: Range(Cells(1,1),Cells(2,1)), где указаны координаты левой верхней и правой нижней ячеек через прямое написание номеров строк и столбцов. В данном случае диапазон начинается с ячейки, находящейся на пересечении первой строки и первого столбца, а заканчивается ячейкой, находящейся на пересечении второй строки и первого столбца.
Номер строк и столбцов можно указать через числовые переменные.

[pashulka]

Сообщение от SlimBr0ther

Как же так, даже пример из справки не работает!!!

Справка, всё-таки, существует не для бездумного копирования примеров, поэтому, если немного изучить об'ектную модель Excel, то станет очевидным, что Cells(13, 1) ссылается на ячейку активного листа, а стало быть конструкция : Worksheets("Sheet1").Range(Cells(1, 1), Cells(5, 3)) есть не что иное, как : ActiveWorkbook.Worksheets("Sheet1") .Range(ActiveSheet.Cells(1, 1), ActiveSheet.Cells(5, 3))

Стало быть - вышеприведённый пример может работать только при условии, что в активной рабочей книге, в момент выполнения этой инструкции, активным будет рабочий лист с именем "Sheet1"

Что касается решений, то если не искать обходных путей, то с точки зрения об'ектной модели обсуждаемого приложения, наиболее правильным будет второй из нижеопубликованных вариантов решения.

Вариант I.

 iRow = 13
iMinColumn = 1
iMaxColumn = 9
iAddress = Range(Cells(iRow, iMinColumn), Cells(iRow, iMaxColumn)).Address
'Этот способ будет работать только при условии, что
'в момент выполнения этой инструкции - активным является лист, имеющий ячейки
 
Worksheets("Общий").Range(iAddress).Value = Worksheets("4x16x4").Range(iAddress).Value

Вариант II.

Dim iSource As Worksheet, iDestination As Worksheet
Set iSource = Worksheets("4x16x4")
Set iDestination = Worksheets("Общий")
 
iDestination.Range(iDestination.Cells(13, 1), iDestination.Cells(13, 9)).Value = _
iSource.Range(iSource.Cells(13, 1), iSource.Cells(13, 9)).Value ' и т.п.