Транспонирование матрицы

[bloodykz]

Нашел код ,исправил для emu8086 и выдает :this interrupt is not defined yet,it is available for custom functions.You can define this interrupt by modifying interrupt vector table refer to the list of supported interrupts and glodal memory table.

.model small
.code
begin:
;Адресуем сегментные регистры
		mov	ax,data
		mov	ds,ax
		mov	es,ax
;Выводим исходную матрицу
		call	OutMatrix
;Транспонируем матрицу
		call	TranspMatrix
;Выводим полученный результат
		call	OutMatrix
;Ожидаем любую клавишу и завершаем программу
		xor	ax,ax
		int	16h
		mov	ax,4c00h
		int	21h
;
;Вывод матрицы
;устанавливаем внешний индекс цикла
OutMatrix:	mov	cx,4
;сбрасываем указатель в матрице
		xor	si,si
;запоминаем его в стеке
OM1:		push	cx
;устанавливаем внутренний индекс цикла
		mov	cx,4
;считываем значение числа
OM2:		mov	al,[Matrix+si]
;переходим к следующему числу
		inc	si
;выводим число на экран
		call	OutNumber
;проверяем внутренний цикл
		loop	OM2
;переходим на новую строку
		call	NewLine
;востанавливаем внешний индекс цикла
		pop	cx
;проверяем внешний индекс цикла
		loop	OM1
;переходим на новую строку
NewLine:	mov	al,10
		int	29h
		mov	al,13
		int	29h
;возвращаемся из под програмы
		ret
;
;Выводим одно число в АХ
;запоминаем счетчик цикла в стеке
OutNumber:	push	cx
;система счисления, в данном случае 10-ая
		mov	bx,10
;сбрасываем старшую часть слова
		xor	ah,ah
;сбрасываем счетчик цифр
		xor	cx,cx
;сбрасываем остаток
ON1:		xor	dx,dx
;длелим на систему счисления и получаем остаток от деления
		div	bx
;запоминаем остаток в стеке
		push	dx
;считаем запомненую цифру
		inc	cx
;посторяем пока АХ больше нуля
		or	ax,ax
		jnz	ON1
;форматируем вывод чисел
;значение, которое при +30Н даст код пробела
		mov	ax,-10h
;увеличиваем счетчик цифр в стеке
ON2:		inc	cx
;запоминаем в стеке условный код пробела
		push	ax
;повторяем пока в стеке не будет 4-е цифры
		cmp	cx,4
		jnz	ON2
;выводим число на экран
;извлекаем из стека очередную цифру
ON3:		pop	ax
;переводим в символьный код для вывода на экран
		add	al,30h
;выводим на экран символ
		int	29h
;повторяем пока в стеке есть цифры
		loop	ON3
;востанавливаем счетчик цикла
		pop	cx
		ret
;
;трнспонируем матрицу
;устанавливаем индекс внешнего цикла
TranspMatrix:	mov	cx,4
;сбрасываем указатель в матрице
		xor	si,si
;сохраняем индекс внешнего цикла
TM1:		xchg	dx,cx
;устанавливаем индекс внутреннего цикла
		mov	cx,4
;проверяем индексы циклов
TM2:		cmp	cx,dx
;если внешний больше или равен внутреннему пропускаем
		jbe	TM3
;транспонируем указатель на элемент матрицы - строку
		mov	di,si
;получаем младшие биты
		and	di,03h
;умножаем их на 4-е
		shl	di,2
;транспонируем указатель на элемент матрицы - столбец
		mov	ax,si
;делим на 4-е
		shr	ax,2
;суммируем новое транспонированное значение указателя
		add	di,ax
;читаем число из матрицы
		mov	al,[Matrix+si]
;обмениваем его с числом по транспонированному адресу указателя
		xchg	[Matrix+di],al
;записываем транспонированное значение
		mov	[Matrix+si],al
;следующий элемент матрицы
TM3:		inc	si
;проверяем индекс внутреннего цикла
		loop	TM2
;востанавливаем значение индекса внешнего цикла
		xchg	dx,cx
;проверяем индекс внешнего цикла
		loop	TM1
;выход из подпрограммы
		ret
;сегмент данных
data segment
Matrix		db	01,02,03,04
		db	05,06,07,08
		db	09,10,11,12
		db	13,14,15,16
data ends
;сегмент стека
org	100h
;точка входа в программу
end	begin

[Mikl___]

bloodykz,
ему8086 -- жалкая пародия на компилятор и отладчик, в твоем asm-файле ему не нравится int 29h, поэтому замени строки с int 29h на

mov ah,2
mov dl,al
int 21h

[Serge_Bliznykov]

begin:
;Адресуем сегментные регистры
		mov	ax,data
		mov	ds,ax

странно... не знал, что так можно! У меня tasm матерится, требует, чтобы было:

		mov	ax,@data

[Mikl___]

Serge_Bliznykov,
это же emu8086, руки бы выдрал автору по самые плечи, но судя по количеству заданий связанных с этим "емулятором" преподаватели на него "подсели", не понимаю, чего их так в крайности кидает, то пишут программы при помощи debug.exe, то программируют на КР580 (intel8080/8085) где нет команд деления и умножения, то с ДОСом никак не могут проститься

[Serge_Bliznykov]

Сообщение от Mikl___

это же emu8086, руки бы выдрал автору по самые плечи

а может, он его и не руками совсем писал! Или руки у него не из плеч растут...

Ну, в общем, я понял, Mikl___, спасибо за ответ!

[DiemonStar]

Проще всего транспонировать матрицу по дополнительной диагонали - задача сводится к обмену первой и последней ячеек памяти и сдвигать указатели на обмениваемые ячейки к центру массива.

mass db 3 dup (1)
       db 3 dup (2)
       db 3 dup (3)
...
mov si, offset mass
mov di, offset mass + 9 
lp:
mov al, [si]
mov ah, ds:[di]
mov [si], ah
mov [di], al
inc si
dec di
cmp si,di
jl lp

примерно вот так.

[bloodykz]

Emu дал преподаватель. Спасибо, исправил. Работает. Можно еще 1 вопрос?
как называется такой метод когда нужно сформировать матрицу вида ,симметричность матрицы? Оо
1,2,3,4
2,3,4,1
3,4,1,2
4,1,2,3

[Mikl___]

bloodykz
набери в викепедии в поисковой строке "Матрицы", "симметричность матрицы"

[bloodykz]

Хорошо.Погуглил

[Mikl___]

bloodykz,
хорошо погуглил?