Как получить название диапазона активной ячейки?

[The_Prist]

Тогда не понимаю. У меня вот этот код

Sub Intersect_Name()
    Dim nn As Name
    For Each nn In ActiveWorkbook.Names
        If Mid$(nn, 2, InStr(nn, "!") - 2) = ActiveCell.Parent.Name Then
            If Not Intersect(Range(Mid$(nn, InStr(nn, "!") + 1)), ActiveCell) Is Nothing Then MsgBox nn.Name: Exit Sub
        End If
    Next
    MsgBox "Выделенная ячейка не входит ни в один именованный диапазон", vbInformation, "Hay_from_The_Prist"
End Sub

Нормально отрабатывает с таким именным диапазоном - =Отопление!$17:$20.

[kipish_lp]

А вот так работает! Спасибо!

[The_Prist]

Сообщение от kipish_lp

А вот так работает! Спасибо!

Так этот код практически ничем не отличается от того кода, который я привел в сообщении #7. Вы его пробовали?

[The_Prist]

А вот обещанный код, работающий с именованными диапазонами, заданными через формулы. Так же код игнорирует ошибочные имена.

Sub Intersect_Name()
    Dim nn As Name, rRange As Range
    For Each nn In ActiveWorkbook.Names
        On Error Resume Next: Set rRange = Sheets(Range(nn.Name).Parent.Name).Range(nn.Name)
        On Error GoTo 0
        If Not rRange Is Nothing Then
            If rRange.Parent.Name = ActiveCell.Parent.Name Then
                If Not Intersect(rRange, ActiveCell) Is Nothing Then MsgBox nn.Name: Exit Sub
            End If
            Set rRange = Nothing
        End If
    Next
    MsgBox "Выделенная ячейка не входит ни в один именованный диапазон", vbInformation, "Hay_from_The_Prist"
End Sub

[kipish_lp]

Так этот код практически ничем не отличается от того кода, который я привел в сообщении #7. Вы его пробовали?

Пробовала, ошибка выводилась. Может из-за того, что в #7 nn был как объект?
Ваш последний код тоже замечательно работает. Спасибо!