Помощь с выводом приглашения

[ChestIotVaga]

помогите написать код со следующим алгоритмом:
− вывести на экран приглашение, и ввести с клавиатуры символьную
подстроку для поиска;
− вывести на экран еще одно приглашение, и ввести с клавиатуры
символьную строку с именем файла;
− открыть файл, прочитать его в буфер и найти в содержимом подстроку,
используя строковые инструкции;
− вывести результат поиска в виде сообщения «Найдено» или «Не найдено»;
− завершить программу.
очень нужна помощь буду очень благодарен.

  .model small
    .code
 
;
; CALL PTHIS
; db 'Hello World!', 0
;
PTHIS:
MOV     CS:temp1, SI  ; store SI register.
POP     SI            ; get return address (IP).
PUSH    AX            ; store AX register.
push    dx
next_char:      
        MOV     AL, CS:[SI]
        INC     SI            ; next byte.
        CMP     AL, 0
        JZ      printed        
        MOV     AH, 2  ; эряхўрЄрЄ№ ёшьтюы
        mov     dl,al
        INT     21h
        JMP     next_char     ; loop.
printed:
pop     dx
POP     AX            ; re-store AX register.
; SI should point to next command after
; the CALL instruction and string definition:
PUSH    SI            ; save new return address into the Stack.
MOV     SI, CS:temp1  ; re-store SI register.
RET
temp1  DW  ?    ; variable to store original value of SI register.
 
; ввод строки в переменную buf длиной buflen
input   macro buf,buflen
     local m1
     jmp short m1
     db buflen+1
     db 0
buf  db buflen+1 dup (0)
m1:  mov dx,offset buf-2 ; ввод строки
     mov ah,0Ah
     int 21h
     endm
 
file dw 0 ; дескриптор файла
filesize dw 0 ; длина прочитанного файла
findlen  dw 0 ; длина строки поиска
found    db 0 ; флаг "строка найдена"
 
start: push cs
    pop ds
    push cs
    pop es
        call pthis
        db 13,10,"Find>",0
        input finds,64
        mov di,offset finds
        mov cl,[di-1]
        mov ch,0
        mov findlen,cx
        cmp cl,0
        jnz cont1 
        jmp exerr
cont1:  add di,cx
        mov [di],ch ; [di]=0 - конец строки
    call pthis
    db 13,10,"File>",0
        input finame,64
        mov di,offset finame
        mov cl,[di-1]
        mov ch,0
        jcxz exerr
    add di,cx
        mov [di],ch ; [di]=0 - конец строки
    mov dx,offset finame
    mov ax,3D00h ; открыть файл для чтения
        int 21h
        jc  erropen ; выход по ошибке
    mov file,ax ; сохранить дескриптор файла
 
        mov bx,file
; Для простоты мы читаем файл только 1 раз в достаточно длинный буфер
        mov cx,8000h ; макс длина фрагмента чтения (пример)
    mov dx,offset filebuf
    mov ah,3Fh   ; читать файл Если длина файла <= cx он будет прочитан целиком
        int 21h
        jc  eread   ; выход по ошибке чтения
        mov filesize,ax ; сколько байт прочитано (нет ошибки)
; теперь в ОЗУ по адресу filebuf длиной filesize байт находится прочитанный файл
    mov bx,file ; закрыть файл. По окончании работы с файлом его обязательно надо закрыть.
        mov ah,3Eh
        int 21h
        call findstr ; поиск строки в файле
        mov ax,4C00h ; выход в Дос
        int 21h
 
; Ошибки можно обрабатывать более сложно, используя код ошибки AX
erropen:call pthis
        db 13,10, "Cant open file",0 ; Файл невозможно открыть для чтения, если нет файла с таким именем
exerr:  mov ax,4C01h
        int 21h
eread:  call pthis
        db 13,10, "Cant read file",0 ; Например, если не читается файл на флопике.
    jmp exerr
 
findstr:
; поиск подстроки в строке
    mov found,0
    mov cx,filesize
        sub cx,findlen
    jc out_result ; данные в файле короче строки поиска
        inc cx
    cld
        mov di,offset filebuf
        mov al,finds ; al=первый символ искомой строки
search1:cmp al,[di]
    jnz search2
    push cx ; первый символ найден
        push di
        mov si,offset finds
        mov cx,findlen
        repe cmpsb ; найдена ли строка целиком ?
        jne search3
        mov found,1 ; да
search3:pop di
        pop cx
search2:inc di ; следующий символ файла
        loop search1
out_result:
        cmp found,0
        jz text_no
        call pthis
        db 13,10,"Found !",0
        ret
text_no:call pthis
        db 13,10,"Not found",0
        ret
 
filebuf label byte
 
    end start

[macomics]

Сообщение от ChestIotVaga

PTHIS:
MOV     CS:temp1, SI  ; store SI register.
POP     SI            ; get return address (IP).
PUSH    AX            ; store AX register.
push    dx
next_char:      
        MOV     AL, CS:[SI]
        INC     SI            ; next byte.
        CMP     AL, 0
        JZ      printed        
        MOV     AH, 2  ; эряхўрЄрЄ№ ёшьтюы
        mov     dl,al
        INT     21h
        JMP     next_char     ; loop.
printed:
pop     dx
POP     AX            ; re-store AX register.
; SI should point to next command after
; the CALL instruction and string definition:
PUSH    SI            ; save new return address into the Stack.
MOV     SI, CS:temp1  ; re-store SI register.
RET
temp1  DW  ?    ; variable to store original value of SI register.

Что за жуть вы тут устроили. Лень метку придумать для определения текстовой константы? Это очень плохой подход, даже не надо к такому привыкать.

Сообщение от ChestIotVaga

mov bx,file
; Для простоты мы читаем файл только 1 раз в достаточно длинный буфер
        mov cx,8000h ; макс длина фрагмента чтения (пример)
    mov dx,offset filebuf
    mov ah,3Fh   ; читать файл Если длина файла <= cx он будет прочитан целиком
        int 21h

А если длина файла больше 32 кб?

Сообщение от ChestIotVaga

search1:cmp al,[di]

Если надо использовать строковые команды, тогда проще написать repne scasb

findstr: ; Поиск строки с использованием строковых инструкций. Возвращает 0 в ax, если строка не найдена иначе ax = 1.
    mov si, offset finds
    mov cx, filesize
    mov di, offset filebuf
    sub cx, findlen
    jb not_found
    cld
    lodsb ; Считали первый символ из искомой строки
test_cycle:
    repne scasb ; Ищем первый символ в буфере
    jnz not_found ; До конца буфера не нашлось первого символа искомой строки
    push cx
    push si
    mov cx, findlen
    push di
    dec cx
    repe cmpsb ; Сравниваем остаток строки без первого символа со строкой в буфере
    pop di
    pop si
    pop cx
    jnz test_cycle ; Не совпало (продолжаем)
    mov ax, 1
    ret
not_found:
    xor ax, ax
    ret

[ChestIotVaga]

извините первый раз сталкиваюсь с ассемблером и чутка не понимаю некоторые моменты

[ChestIotVaga]

То есть как я понял вот целый код теперь будет работать?

    .model small
    .code
 
;
; CALL PTHIS
; db 'Hello World!', 0
;
PTHIS:
MOV     CS:temp1, SI  ; store SI register.
POP     SI            ; get return address (IP).
PUSH    AX            ; store AX register.
push    dx
next_char:      
        MOV     AL, CS:[SI]
        INC     SI            ; next byte.
        CMP     AL, 0
        JZ      printed        
        MOV     AH, 2  ; эряхўрЄрЄ№ ёшьтюы
        mov     dl,al
        INT     21h
        JMP     next_char     ; loop.
printed:
pop     dx
POP     AX            ; re-store AX register.
; SI should point to next command after
; the CALL instruction and string definition:
PUSH    SI            ; save new return address into the Stack.
MOV     SI, CS:temp1  ; re-store SI register.
RET
temp1  DW  ?    ; variable to store original value of SI register.
 
; ввод строки в переменную buf длиной buflen
input   macro buf,buflen
     local m1
     jmp short m1
     db buflen+1
     db 0
buf  db buflen+1 dup (0)
m1:  mov dx,offset buf-2 ; ввод строки
     mov ah,0Ah
     int 21h
     endm
 
file dw 0 ; дескриптор файла
filesize dw 0 ; длина прочитанного файла
findlen  dw 0 ; длина строки поиска
found    db 0 ; флаг "строка найдена"
 
start: push cs
    pop ds
    push cs
    pop es
        call pthis
        db 13,10,"Find>",0
        input finds,64
        mov di,offset finds
        mov cl,[di-1]
        mov ch,0
        mov findlen,cx
        cmp cl,0
        jnz cont1 
        jmp exerr
cont1:  add di,cx
        mov [di],ch ; [di]=0 - конец строки
    call pthis
    db 13,10,"File>",0
        input finame,64
        mov di,offset finame
        mov cl,[di-1]
        mov ch,0
        jcxz exerr
    add di,cx
        mov [di],ch ; [di]=0 - конец строки
    mov dx,offset finame
    mov ax,3D00h ; открыть файл для чтения
        int 21h
        jc  erropen ; выход по ошибке
    mov file,ax ; сохранить дескриптор файла
 
        mov bx,file
; Для простоты мы читаем файл только 1 раз в достаточно длинный буфер
        mov cx,8000h ; макс длина фрагмента чтения (пример)
    mov dx,offset filebuf
    mov ah,3Fh   ; читать файл Если длина файла <= cx он будет прочитан целиком
        int 21h
        jc  eread   ; выход по ошибке чтения
        mov filesize,ax ; сколько байт прочитано (нет ошибки)
; теперь в ОЗУ по адресу filebuf длиной filesize байт находится прочитанный файл
    mov bx,file ; закрыть файл. По окончании работы с файлом его обязательно надо закрыть.
        mov ah,3Eh
        int 21h
        call findstr ; поиск строки в файле
        mov ax,4C00h ; выход в Дос
        int 21h
 
; Ошибки можно обрабатывать более сложно, используя код ошибки AX
erropen:call pthis
        db 13,10, "Cant open file",0 ; Файл невозможно открыть для чтения, если нет файла с таким именем
exerr:  mov ax,4C01h
        int 21h
eread:  call pthis
        db 13,10, "Cant read file",0 ; Например, если не читается файл на флопике.
    jmp exerr
 
findstr: ; Поиск строки с использованием строковых инструкций. Возвращает 0 в ax, если строка не найдена иначе ax = 1.
    mov si, offset finds
    mov cx, filesize
    mov di, offset filebuf
    sub cx, findlen
    jb not_found
    cld
    lodsb ; Считали первый символ из искомой строки
test_cycle:
    repne scasb ; Ищем первый символ в буфере
    jnz not_found ; До конца буфера не нашлось первого символа искомой строки
    push cx
    push si
    mov cx, findlen
    push di
    dec cx
    repe cmpsb ; Сравниваем остаток строки без первого символа со строкой в буфере
    pop di
    pop si
    pop cx
    jnz test_cycle ; Не совпало (продолжаем)
    mov ax, 1
    ret
not_found:
    xor ax, ax
    ret

[macomics]

После команды call findstr вы не обрабатываете результат. Надо проверить:

    call findstr
    test ax, ax
    jz show_not_found
    call pthis
  db 13, 10, "Found", 0
    mov ax, 4C00h
    int 21h

show_not_found:
    call pthis
  db 13, 10, "Not found", 0
    mov ax, 4C00h
    int 21h