Правильный многоугольник (polygon) как корень из комплексного числа

[Sasha_Smirnov]

Тема, при моральной поддержке форума, получила дальнейшее развитие.

Sub DrawParquetry() ' Макрос записан 27.07.2011 и позволяет замостить всё поле (по F5)
Const RoX = 5, RoY = 5   'масштабы по осям
Static ShiftX, ShiftY    'сдвиг начала "косички" от начала координат (в пунктах)
Dim Nn  As Long: Nn = 18 'количество паркетин
Dim n As Long            'индекс узла
Nn = Nn * 3              'количество узловых точек в одной косичке

ReDim x(0 To Nn) As Single: ReDim y(0 To Nn) As Single

x(0) = ShiftX: y(0) = ShiftY

With ActiveDocument.Shapes.BuildFreeform(msoEditingAuto, x(0), y(0))

    For n = 1 To Nn
    x(n) = ShiftX + ((n Mod 6) \ 2 + ((n Mod 6) \ 4) + n \ 6) * RoX
    y(n) = ShiftY + (((n + 3) \ 2) Mod 3 + (n - 1) \ 6) * RoY
    .AddNodes msoSegmentLine, msoEditingAuto, x(n), y(n)
    Next n
        
    .ConvertToShape.Select 'построение ломаной по найденным узлам
    
End With

ShiftX = ShiftX + 4 * RoX 'сдвиг "косички" вправо при следующем запуске (до выхода из Word)
End Sub

Также назрел вариант мощения под любым углом (в полярных координатах).

(А тем временем в замке Эксселя 7vlad37 уже вовсю передвигает объём!)

[Sasha_Smirnov]

В посте http://programmersforum.ru/showthread.php?t=72695#9 приложен раскидай.doc и в нём (по альт-F8) макрос spiderly, который тоже рисует нечто.

[Sasha_Smirnov]

Код пока не выкладываю.

Оказывается, это было возможно ещё на заре Перестройки: http://programmersforum.ru/showthread.php?t=164491#10, в 1985-м, но до сих пор я был занят чем-то другим.

[Sasha_Smirnov]

Sub DrawClodOfMeanders()        ' Макрос записан 23.10.2011 User
Const pi = 3.1415926535898
Const k = 5, n = 30             'порядок симметрии вращения (k) и число узлов в завитках (n)
Const RoX = 7, RoY = 7, RoXp = 8, RoYp = 8, ShiftX = 300, ShiftY = 200
Dim hor As Long, ver As Long    'промежуточные параметры меандров (одного завитка)
Dim Nn As Long, Nk As Long, fi As Double
Dim x As Double, y As Double, x1 As Double, y1 As Double

ReDim xd(0 To n) As Long: ReDim yd(0 To n) As Long
ReDim xp(0 To k) As Long: ReDim yp(0 To k) As Long

    xd(0) = ShiftX:         yd(0) = ShiftY

For Nn = 1 To n
    hor = ((Nn + 1) Mod 10) \ 2:    ver = (Nn Mod 10 + 2) \ 2 - 3
    xd(Nn) = RoX * 0.5 * (5 + (5 - 2 * hor) * (-1) ^ (((Nn + 1) Mod 10) \ 4) + ((Nn - 1) \ 10) * 10)
    yd(Nn) = RoY * ver * (-1) ^ ver + 2
Next Nn

    xp(0) = RoXp + ShiftX:  yp(0) = ShiftY

With ActiveDocument.Shapes.BuildFreeform(msoEditingAuto, xp(0), yp(0))
    For Nk = 1 To k
        xp(Nk) = RoXp * Cos(Nk * 2 * pi / k) + ShiftX: yp(Nk) = RoYp * Sin(Nk * 2 * pi / k) + ShiftY
        
        For Nn = n To 9 Step -1
            fi = 2 * pi * (Nk + 1) / k
            x = xd(Nn) * Sin(fi) + yd(Nn) * Cos(fi)
            y = -xd(Nn) * Cos(fi) + yd(Nn) * Sin(fi)
            If x1 = 0 Then: x1 = x + xp(1): y1 = y + yp(1)  'замыкающий узел контура
            .AddNodes msoSegmentLine, msoEditingAuto, x + xp(Nk), y + yp(Nk)
        Next Nn
        
    Next Nk
    .AddNodes msoSegmentLine, msoEditingAuto, x1, y1
    .ConvertToShape.Select 'соединение узловых точек в контур
End With

With Selection.ShapeRange.Fill
    .Parent.Nodes.Delete 1             'удаление узла № 1 (стартового)
    .Visible = msoTrue                 'видимость заливки (видна)
    .Solid                             'характер заливки (сплошная)
    .ForeColor.RGB = RGB(255, 0, 255)  'заливка контура (цвет по RGB)
End With
ThisDocument.UndoClear                 'очистка списка возвратов (что по CTRL-Z)
End Sub

Уж не знаю, будет ли он рисовать в Corel Draw, но в ворде легко.

«Пьяного рыцаря» (как на рисунке) можно получить, если сделать Step –2 при n = 29.