помогите преобразовать (Ассемблер)

[help_me_plz]

В этом коде дата выводится как 27 9 2015
а надо 27 сентябрь 2015 (помогите пожалуйста)

model tiny
.186
.code
org 100h
begin:
;устанавливаем текстовый режим
  mov ax,3
  int 10h

;получаем дату
  mov ah,2ah
  int 21h
;вывод дня
  mov al,dl
  xor ah,ah
  call OutNumber
;вывод месяца
  mov al,dh
  xor ah,ah
  call OutNumber
;вывод года
  mov ax,cx
  call outNumber
;любая клавиша
  xor ax,ax
  int 16h
  ret
;подпограмма вывода числа в десятичной системе
outNumber:
  pusha
;устанавливаем систему и счетчик цифр
  mov bx,10
  xor cx,cx
;делим на основание системы
isDiv:  xor dx,dx
  div bx
;запоминаем в стеке и увеличиваем счетчик цифр в стеке
  push dx
  inc cx
;повторяем пока Ах не равно 0
  or ax,ax
  jnz isDiv
;извлекаем из сткека число
isOut:  pop ax
;переводим его в символ
  or ax,30h
;выводим
  int 29h
  loop isOut
;выводим разделяющий пробел
  mov al,20h
  int 29h
  popa
  ret
end begin

[R71MT]

Можно командой XLAT закодировать месяцы и потом выводить их, а можно прямым/табличным доступом. В любом случае есть один недостаток: чтоб не уродовать вывод, нужно сокращать имя месяца по-самому короткому, т.е. до 3-х символов (Май).

Ниже, вариант прямого доступа на FASM'e:

 
use16
org 100h
jmp start

Temp    db '         ','$'          ; сюда будем писать текущий месяц
monTab  db 'January  '              ; таблица месяцев.
        db 'February '              ; ..длинна каждого поля,
        db 'March    '              ; ...выбрана по-Сентябрю (9 симв)
        db 'April    '
        db 'May      '              ; т.к. самый/короткий месяц "Май",
        db 'June     '              ; ..удобно кастрировать её до 3-х
        db 'July     '
        db 'August   '
        db 'September'
        db 'October  '
        db 'November '
        db 'December '

start:
 ;устанавливаем текстовый режим
 mov   al,3
 int   10h

 ;получаем дату
 mov   ah,2ah
 int   21h

 ;вывод дня
 mov   al,dl
 xor   ah,ah
 call  OutNumber

 ;вывод месяца =========================================================//
 pusha
 xor   ax,ax
 mov   al,dh                ; AX = номер месяца (BCD)
 dec   ax                   ; у нас в таблице отсчёт c нуля, поэтому AX-1
 mov   bx,9                 ; BX = макс.число символов в месяце
 mul   bx                   ; AX = адрес текущего месяца в таблице
 mov   si,monTab            ; SI = начальный адрес таблицы
 add   si,ax                ; выбираем в ней нужный месяц
 mov   cx,9                 ; сколько символов копировать?
 mov   di,Temp              ; куда копировать?
 rep   movsb                ; копируем текущий месяц в переменную
 mov   ah,9                 ; fn(9) INT-21h
 mov   dx,Temp
 int   21h                  ; выводим месяц на экран
 mov   al,'/'               ; вставляем разделитель
 int   29h
 popa
;======================================================================//

 ;вывод года
 mov   ax,cx
 call  OutNumber

 ;любая клавиша
 xor ax,ax
 int 16h
 ret

;=================================================================
OutNumber:
   pusha
   mov   bx,10
   xor   cx,cx
isDiv:
   xor   dx,dx
   div   bx
   push  dx
   inc   cx
   or    ax,ax
   jnz   isDiv
isOut:
   pop   ax
   cmp   al,9
   jle   noHex
   add   al,7
noHex:
   add   al,30h
   int   29h
   loop  isOut

   mov   al,'/'
   int   29h
   popa
ret

[Stilet]

В любом случае есть один недостаток: чтоб не уродовать вывод, нужно сокращать имя месяца по-самому короткому
А это смотря каким выводом пользоваться. Если DOS прерываниями, то можно пробелы заменить на $.
А вообще я бы составил массив строковых констант, и массив ссылок на них (индексов), а уже в xlat использовал бы именно эти индексы.

[R71MT]

Сообщение от Stilet

А вообще я бы составил массив строковых констант, и массив ссылок на них (индексов), а уже в xlat использовал бы именно эти индексы.

..согласен. При желании можно организовать.