Вывести дату

[Max00766]

Есть программа которая выводит дату через 1Аh, но препод забраковал и сказал сделать через 70h и 71h с такими индексами:
Индекс 07h RTC день месяца
Индекс 08h RTC месяц
Индекс 09h RTC год (две последние цифры)
Помогите пожалуйста под это переделать мой код:

.model small                         
.386                    
 
.data                  
Messd   db 'Current date: $'
dt_     db ?,?,'-',?,?,'-',?,?,?,?,0Ah,0Dh,'$'
 
.stack                  
    db  256 dup(?)      
 
.code                              
start:                  
    mov ax,@data        
    mov ds,ax           
                        
    
    mov ax,00h          
    mov al,03h          
    int 10h             
                        
    
    xor ax,ax           
    xor dx,dx          
    
    mov ah,09h         
    mov dx,offset Messd 
    int 21h             
    
    xor dx,dx          
    
    call getdate
    
    mov ah,4Ch                      
    mov al,00h         
    int 21h             
    
    getdate proc        
        mov ah,04h      
                       
        int 1Ah         
    
        xor ah,ah       
        mov al,dl       
        call toasci     
                            
        mov word ptr dt_,ax
        
        xor ah,ah      
        mov al,dh       
        call toasci     
                        
        mov word ptr dt_+3,ax
        
        xor ah,ah      
        mov al,ch      
        call toasci    
                       
        mov word ptr dt_+6,ax
        
        xor ah,ah      
        mov al,cl    
        call toasci   
                       
        mov word ptr dt_+8,ax
        
        mov ah,09h   
        mov dx,offset dt_
        int 21h       
        
        ret           
    getdate endp      
    
    toasci proc   
                   
        ror ax,4        
        shr ah,4      
        
        or ax,'00'      
    
        ret            
    toasci endp         
end start

[R71MT]

сделать через 70h и 71h с такими индексами:

Чтоб считать данные с порта(71), ты должен отправить нужный индекс в порт(70). Ответ получишь в формате BCD, который нужно перевести в ASCII и вывести на экран. BCD-to-ASCII можно организовать или через инструкцию AAM со-значением 10h, или-же ручками передвинув биты. Таблица первых 10-ти индексов выглядит так (в дефолте BCD):

---------------------------------------------------
00h: — текущая секунда (00–59h)
01h: — секунды будильника
02h: — текущая минута (00–59h)
03h: — минуты будильника
04h: — текущий час (0–23h) для 24-часового режима
05h: — часы будильника
06h: — текущий день недели (1–7, 1—воскресенье)
07h: — текущий день месяца (01–31h)
08h: — текущий месяц (01–12h)
09h: — текущий год (00–99h)
---------------------------------------------------

; FASM code....
org 100h
jmp start

mes0    db  ' Current date: '
        db  0,0,':',0,0,':',0,0,'$'

start:  mov   di,mes0+15      ; приёмник для запись (текст пропущен)
        mov   al,7            ; день
        call  port70          ;
        mov   al,8            ; месяц
        call  port70          ;
        mov   al,9            ; год
        call  port70          ;

        mov   ah,9            ; выводим строку на экран
        mov   dx,mes0         ;
        int   21h             ;

exit:   xor   ax,ax           ;
        int   16h             ;
        int   20h             ;

;eeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeee
; Процедура читает из CMOS по индексу AL ------------------------

port70: out   70h,al          ; задаём индекс
        in    al,71h          ; читаем данные
        xor   ah,ah           ; bcd-2-asc
        shl   ax,4            ; ^
        shr   al,4            ; ^
        or    ax,3030h        ; ^
        xchg  ah,al           ;
        stosw                 ; запись в буфер
        inc   di              ; пропускаем ':' в буфере
        ret                   ;