FASM ввод строки с клавиатуры

[Kurtojkeee]

Добрый день, помогите пожалуйста. Нужен ввод строки с клавиатуры для программы. Код.Пока только так. И как искать все буквы z не только большие, но и маленькие?

PHP код:

format PE  GUI 4.0
include 'D:\FASM\include\win32ax.inc'
include 'D:\FASM\include\encoding\win1251.inc'

.data
caption  db  'Работа со строкой',0
text     db  '   Èñõîäíàÿ ñòðîêà: zZabral Zaseyal Rojb',13,13,\
             '   Позиция пробела:  '      
buff1    db  0,0,' ',13,\                 
             'Количество букв Z в строке:  '       
buff2    db  0,0,0                        

stroka   db  'Zabral Zaseyal Rojb'             
size     =   $ - stroka                   

.code
start:
;---------- Ищем первый пробел ------------------------------------
     mov   ecx,size             
     push  ecx                  
     mov   edi,stroka          
     mov   al,' '               
     repne scasb                
     pop   eax                  
     sub   eax,ecx             
     aam                        
     or    ax,3030h             
     xchg  ah,al                
     mov   word[buff1],ax       

;Ищем букву Z
     xor   ebx,ebx              
     mov   esi,stroka          
     mov   ecx,size            
     mov   ah,'Z'               
@1:  lodsb                      
     cmp   ah,al                
     jnz   @2                  
     inc   ebx                  
@2:  loop  @1                 .
     mov   eax,ebx              
     aam                        
     or    ax,3030h             
     xchg  ah,al                
     mov   word[buff2],ax     


     invoke  MessageBox,0,text,caption,MB_OK
     invoke  ExitProcess,0

.end start 


[R71MT]

Тебе обязательно GUI надо, или консоль тоже пойдёт?

[Kurtojkeee]

Сообщение от R71MT

Тебе обязательно GUI надо, или консоль тоже пойдёт?

Без разницы можно GUI, можно консоль главное ввод с клавы был.

[R71MT]

Сообщение от Kurtojkeee

Без разницы

для тебя может без разницы, а для того кто пишет - большая разница.

[Kurtojkeee]

Сообщение от R71MT

для тебя может без разницы, а для того кто пишет - большая разница.

Где легче для того кто пишет)))

[Kurtojkeee]

С символами Z,z решил проблему

[Kurtojkeee]

Думал надо позицию пробела, оказывается надо количество символов после пробела

[Kurtojkeee]

Сообщение от R71MT

для тебя может без разницы, а для того кто пишет - большая разница.

Друже, есть решение по вводу строки с клавиатуры?

[R71MT]

Вот тебе досовская консоль:

; fasm code.......
org 100h
jmp start

mes0    db  13,10,' Введите строку........: $'
mes1    db  13,10,' Заглавных "Z".........: $'
mes2    db  13,10,' Прописных "z".........: $'
mes3    db  13,10,' Символов после пробела: $'
buff    db  80,0,80 dup(0)   ; буфер для строки

start:  mov   dx,mes0        ;
        call  message        ;
        mov   ah,0Ah         ; fn(0A) ввод в буфер
        mov   dx,buff        ;
        int   21h            ;

        mov   dx,mes1        ;
        call  message        ;
        xor   cx,cx          ;
        mov   al,'Z'         ; символ для поиска
        call  findSymbol     ; зовём функцию..

        mov   dx,mes2        ;
        call  message        ;
        mov   ax,'z'         ;
        call  findSymbol     ;

        mov   dx,mes3        ;
        call  message        ;
        mov   cl,[buff+1]    ;
        mov   al,' '         ; символ для поиска
        mov   di,buff+1      ;
        repne scasb          ; поиск..
        xchg  ah,cl          ; AH = длина хвоста после пробела
        call  print          ; выводим её на экран

exit:   xor   ax,ax          ;
        int   16h            ;
        int   20h            ; выход!
;eeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeeee
message:                     ;
        mov   ah,9           ; досовская мессага
        int   21h            ;
        ret                  ;
;------------------------------------------------------
findSymbol:                  ; символ для поиска в AL
        xor   ah,ah          ; AH будет счётчиком
        mov   cl,[buff+1]    ;
        mov   di,buff+2      ;
cycle:  repne scasb          ; поиск..
        or    cx,cx          ; всю строку проверили?
        jz    print          ;
        inc   ah             ; счётчик +1
        jmp   cycle          ;
print:  shr   ax,8           ; отправляем результат в AL
        aam                  ; переводим в распакованное BCD
        or    ax,3030h       ;        ..и в символы
        xchg  ah,al          ;
        int   29h            ;
        shr   ax,8           ;
        int   29h            ; выводим число на экран
        ret                  ;