Макрос для выборки из таблицы Excel, для разговоров свыше 10 минут

[Otellka]

Приветствую Вас, нужна помощь.
Приходит на работу выписка по телефону, надо сделать выборку разговоров превышающие лимит в 10 минут, в ручную очень долго получается, а списки телефонов очень большие.
Можно сделать скрипт/макрос, что бы он искал значения равные или больше "10" и копировал строки на новый лист?
Но при этом необходимо сохранить сам номер телефона.
То есть получается копировалась строка "Номер телефона...." а дальше уже отсеивалось значение, вот.
Или как это можно сделать другими способами?
Спасибо за внимание :-)

[IgorGO]

сделайте активным лист с данными
выполните этот

Sub OnlyMore10()
  Dim r As Long, lr As Long, Phone As String
  lr = Cells(Rows.Count, 1).End(xlUp).Row: r = 1
  Do While r <= lr
    If Cells(r, 1) Like "Номер телефона: *" Then Phone = "№" & Mid(Cells(r, 1), 16, InStr(Cells(r, 1), "(") - 17)
    If (Cells(r, 8) < 10 And Cells(r, 19) < 10) Or Cells(r, 8) = "Длит." Then Rows(r).Hidden = True Else Cells(r, 22) = Phone
    r = r + 1
  Loop
End Sub

макрос ничего не удаляет не переносит, просто скрывает не нужные строки.
отметить все, правая кнопка мыши, отобразить и снова все видно.

[kuklp]

Public Sub www()
    Dim a, i&, n&, s$
    a = Range("a2:u" & Cells(Rows.Count, 1).End(xlUp).Row).Value
    ReDim b(1 To UBound(a), 1 To 6)
    For i = 1 To UBound(a)
        If a(i, 1) Like "Номер телефона:*" Then s = a(i, 1)
        If IsNumeric(a(i, 8)) And a(i, 8) > 10 Then
            n = n + 1: b(n, 1) = s: b(n, 2) = a(i, 1): b(n, 3) = a(i, 3)
            b(n, 4) = a(i, 4): b(n, 5) = a(i, 8): b(n, 6) = a(i, 9)
        End If
        If IsNumeric(a(i, 19)) And a(i, 19) > 10 Then
            n = n + 1: b(n, 1) = s: b(n, 2) = a(i, 11): b(n, 3) = a(i, 13)
            b(n, 4) = a(i, 15): b(n, 5) = a(i, 19): b(n, 6) = a(i, 21)
        End If
    Next
    [w2].Resize(n, 6) = b
End Sub

[Казанский]

Ctrl+A, отменить объединение ячеек. Выделить всю таблицу (можно F5 - выделить - последнюю ячейку, потом Ctrl+Shift+Home). Включить автофильтр - Числовые фильтры - больше или равно - 10.

[kuklp]

Леш, так номера телевонов спрячет.

[IgorGO]

я упростил макрос.
спрятал все строки, а телефон добавил в конце строки

[Otellka]

Спасибо большое парни.
Для простого поиска и просмотра хорошо подходит первый вариант (правда слега офис подвисает пока строки все прячет)
А второй способ подошел для составления отчета :-) Я там еще по аналогии добавил выборку для другого формата записи.

А что надо дописать, чтобы он заливку ячейки в какой нибудь цвет делал?