Выбор и перенос данных в другой лист

[sergey77]

Ребята помоги, пожалуйста, очень надо.
Суть проблемы: Есть прайс - лист, в нем выборочно, в графе количество проставляются цифры и надо что бы при нажатии кнопки « сформировать заказ» все строки, где проставлено графа кол-во, перенеслись в новый лист.
Пример прилагаю, заранее Большое спасибо.

[nilem]

PHP код:

Sub СформироватьЗаказ()
    Dim X, i As Long, j As Long, k As Integer
    X = Range("A2:F" & Cells(Rows.Count, 1).End(xlUp).Row).Value
    Application.ScreenUpdating = False: j = 1
        For i = 1 To UBound(X, 1)
            If X(i, 6) > 0 Then
                For k = 1 To 6
                    X(j, k) = X(i, k)
                    If i > j Then X(i, k) = Empty
                Next k: j = j + 1
            Else
                For k = 1 To 6: X(i, k) = Empty: Next k
            End If
        Next i
    Sheets("Zakaz").Activate
    With Range("A2").Resize(UBound(X, 1), UBound(X, 2))
        .EntireRow.Hidden = False
        .Value = X
        .Columns(1).SpecialCells(4).EntireRow.Hidden = True
    End With
    Application.ScreenUpdating = True
End Sub 


[SAS888]

А я опять про то, что Excel - мощный инструмент. Если можно применить его методы, то нужно это использовать. Данная задача решается в две строки, без всяких циклов:

Private Sub Main()
    Application.ScreenUpdating = False: Sheets("Zakaz").Activate
    Cells.Delete: Sheets("Price").Cells.Copy [A1]
    Range([A1], Cells(Rows.Count, 1).End(xlUp)).Offset(, 5).SpecialCells(xlCellTypeBlanks).EntireRow.Delete
End Sub

Пример во вложении.

[A_L_E_X]

Уважаемый SAS888.

Ваш код работает. Это хорошо.
У меня аналогичная задача решается кодом в 50 строк - и это обидно.

Но обиднее всего - я совершенно не понимаю Ваш код.

Может расшифруете?

[SAS888]

Тот же код с подробными комментариями:

Private Sub Main()

'Запрещаем обновление экрана и активируем лист "Zakaz"
    Application.ScreenUpdating = False: Sheets("Zakaz").Activate
    
'Очищаем лист от предыдущих данных и копируем все значения из листа "Price"
'Если копировать лист целиком, то скопируется и кнопка, чего нам не нужно.
    Cells.Delete: Sheets("Price").Cells.Copy [A1]
    
'Определяем диапазон от ячейки "A1" до последней заполненной ячейки столбца "A" со смещением 5 (столбец "F"),
'содержащий пустые значения и удаляем эти строки целиком. Определять диапазон сразу по столбцу "F"
'будет не правильно, т.к. этот столбец может быть заполнен произвольно.
    Range([A1], Cells(Rows.Count, 1).End(xlUp)).Offset(, 5).SpecialCells(xlCellTypeBlanks).EntireRow.Delete
    
End Sub

[A_L_E_X]

Огромное спасибо!!!

[sergey77]

"nilem"
"SAS888"
ОГРОМНОЕ Спасибо!