выделение

[StasSv]

Здравствуйте,
подскажите пожайлуста, возможноли выделить например в выделенном столбце все ячейки отформатированные "с отступом в право" или все ячейки имеющие жирный шрифт
заранее спасибо

[EducatedFool]

Да, можно. Например, так:

Sub test()
    Dim ra As Range, cell As Range
    For Each cell In ThisWorkbook.Worksheets(1).UsedRange.EntireRow.Columns(2).Cells
        If cell.Font.Bold Then If ra Is Nothing Then Set ra = cell Else Set ra = Union(ra, cell)
    Next
    ra.Select ' выделяем все ячейки с жирным шрифтом на листе 1 в столбце 2
End Sub

[StasSv]

Огромное спасибо, а как поменять формат выделения т.е. если например надо будет выделить не жирный текст?

[EducatedFool]

Замените If cell.Font.Bold Then на If cell.Font.Bold=false Then

Тогда будут выделены ячейки с обычным (не полужирным) шрифтом.

[StasSv]

И еще раз большое спасибо
Но, что то я тупанул несвязанные диапазоны нельзя срыть
Подскажите плз. как скрыть все ячейки (соответственно строки) не жирные

[slan]

а еще есть такие средства как найти все в меню поиска(можно ведь и по формату), а так же правка-перейти-выделить..

[StasSv]

найти не ищет обычный формат "полужирный" ищет а обычный перебирает все вкл. и полужирный

[EducatedFool]

как скрыть все ячейки (соответственно строки) не жирные

Sub СкрытьСтрокиСОбычнымШрифтомВоВторомСтолбцеИПустыеСтроки()
    Dim ra As Range, cell As Range, c2 As Range
    Set c2 = ThisWorkbook.Worksheets(1).Columns(2)

    ' выбираем все ячейки с нежирным шрифтом на листе 1 в столбце 2
    For i = 1 To c2.Cells.SpecialCells(xlCellTypeLastCell).Row    ' со строки 1 до последней занятой строки
        Set cell = c2.Cells(i)
        If Not cell.Font.Bold Then If ra Is Nothing Then Set ra = cell Else Set ra = Union(ra, cell)
    Next

    If i <= c2.Parent.Rows.Count Then    ' добавляем неиспользованную область листа
        Set clearRange = c2.Cells(i).Resize(c2.Parent.Rows.Count - i + 1)
        If ra Is Nothing Then Set ra = clearRange Else Set ra = Union(ra, clearRange)
    End If

    ra.EntireRow.Hidden = True    ' скрываем соответствующие строки
End Sub

Sub ОтобразитьВсеСтроки()
    ThisWorkbook.Worksheets(1).Rows.Hidden = False
End Sub

[StasSv]

Большое Спасибо