HTML как текстовый файл

[Fierce]

Есть определенная страница, которая находится по адресу, допустим http://www.programmersforum.ru . Можно ли при помощи VBA сохранить эту страницу как текстовый файл?

[EducatedFool]

Sub test()
    Set IE = CreateObject("InternetExplorer.Application"): DoEvents

    IE.Navigate "http://ExcelVBA.ru"
    While IE.readyState <> 4: DoEvents: Wend    ' ждем, пока загрузится страница
    Set ieDoc = IE.Document

    For i = 0 To IE.Document.all.Length - 1
        MsgBox IE.Document.all.Item(i).innerText, vbInformation, "Элемент № " & i
    Next

    IE.Quit
    Set IE = Nothing
End Sub

[Aent]

Или так

Private Declare Function URLDownloadToFile Lib "urlmon" Alias "URLDownloadToFileA" (ByVal pCaller As Long, _
ByVal szURL As String,ByVal szFileName As String, ByVal dwReserved As Long, ByVal lpfnCB As Long) As Long

Public Function DownloadFile(URL As String, LocalFilename As String) As Boolean
    Dim lngRetVal As Long
    lngRetVal = URLDownloadToFile(0, URL, LocalFilename, 0, 0)
    If lngRetVal = 0 Then DownloadFile = True
End Function

Private Sub Form_Load()
    DownloadFile "http://www.programmersforum.ru", "d:\\forum.htm"
End Sub

[Fierce]

EducatedFool, спасибо, почти то что нужно. Только мне кажется, цикл здесь не нужен. Достаточно вместо i поставить 1 (по-крайне мере для http://ExcelVBA.ru). Да и строка Set ieDoc = IE.Document тоже вроде не нужна

Aent, тоже спасибо, только код сохраняет файл как html, а мне нужен текстовый файл

А где можно почитать про свойства и методы объекта ie? В идеале хочеться добиться действия в браузере сохранить как => текстовый файл

[EducatedFool]

Sub ВебСтраницаВТекстовыйФайл()
    Set IE = CreateObject("InternetExplorer.Application"): DoEvents
    IE.Navigate "http://www.programmersforum.ru"
    filename = "c:\test.txt"
    While IE.busy Or (IE.readyState <> 4): DoEvents: Wend    ' ждем, пока загрузится страница
    txt = IE.Document.body.innerText    ' пишем текст страницы в переменную txt
    IE.Quit: Set IE = Nothing
    SaveTXTfile filename, txt
    MsgBox txt, vbInformation, "Текст страницы сохранён в файл: " & filename
End Sub

Function SaveTXTfile(ByVal filename As String, ByVal txt As String) As Boolean
    On Error Resume Next: Err.Clear
    Set fso = CreateObject("scripting.filesystemobject")
    Set ts = fso.CreateTextFile(filename, True)
    ts.Write txt: ts.Close
    SaveTXTfile = Err = 0
    Set ts = Nothing: Set fso = Nothing
End Function

[Fierce]

EducatedFool, спасибо. Кинул тебе остатки своего R-кошелька