vba выводить сообщение при введении в ячейку данные

[johny_03]

если производится попытка ввести в любую ячейку из диапазона [A8:X500] информацию, то выводить сообщение "Нажмите кнопку "Очистить""

Как это реализовать на vba? Чтобы я мог этот код привязать к другой кнопке, по нажатию которой активировалось бы вышенаписанное условие

Заранее спасибо!

[Казанский]

Пробуйте. Код в модуле листа:

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
If ToggleButton1 Then
    Set Target = Intersect(Target, Range("A8:X500"))
    If Not Target Is Nothing Then
        Application.EnableEvents = False
        Application.Undo
        Application.EnableEvents = True
        MsgBox "Нажмите кнопку 'Очистить'", vbExclamation
    End If
End If
End Sub

[johny_03]

Спасибо! А как мне активировать это не используя выключатель ToogleButton, а используя ClickButton? Т.е. чтобы при нажатии кнопки Старт (в примере) блокировка активировалась, а при нажатии Очистить - деактивировалась?
Спасибо!

[Казанский]

Вторую строку вышеприведенной процедуры замените на

If [A1] <> "" Then

[Казанский]

Можно в качестве "флажка" использовать не ячейку, а переменную. Код модуля листа:

Option Explicit

Dim flag As Boolean

Private Sub CommandButton1_Click()
flag = True
End Sub

Private Sub CommandButton2_Click()
flag = False
End Sub

Private Sub Worksheet_Change(ByVal Target As Range)
If flag Then
    Set Target = Intersect(Target, Range("A8:X500"))
    If Not Target Is Nothing Then
        Application.EnableEvents = False
        Application.Undo
        Application.EnableEvents = True
        MsgBox "Нажмите кнопку 'Очистить'", vbExclamation
    End If
End If
End Sub