Из буфера в файл txt

[imber]

Подскажите, пожалуйста, как из буфера вставить в файл txt с помощью vba
уже отчаялся найти.
...............................
Selection.Copy
Shell "NOTEPAD.EXE", vbNormalFocus
AppActivate "Блокнот"
' Здесь вставка не срабатывает
Selection.Paste

[Serge_Bliznykov]

а какая задача стоит?
И зачем Вам блокнот? Пишите в файл напрямую.
Например, так:

Sub SaveSelection()
  Dim c As Range
  Open "C:\Temp\Сохранение.txt" For Output As #2
  For Each c In Selection
    Print #2, c.Value
  Next
  Close #2
  MsgBox "Содержимое выделенных ячеек сохранено в файл C:\Temp\Сохранение.txt"
End Sub

[EducatedFool]

Для записи в текстовый файл совсем необязательно запускать NOTEPAD.
И буфер обмена использовать не надо.

Сначала в переменную поместите текст выделенного диапазона: http://excelvba.ru/code/Range2TXT
а потом текст из этой переменной запишите в файл: http://excelvba.ru/code/txt

Если объединить эти 2 функции, получится вот что:
(перед нажатием на кнопку выделите диапазон ячеек)

Sub ОсновнойМакрос()
    txt = Range2TXT(Selection)
    SaveTXTfile "C:\Текст диапазона.txt", txt
End Sub

Function Range2TXT(ByRef ra As Range, Optional ByVal ColumnsSeparator$ = vbTab, _
                   Optional ByVal RowsSeparator$ = vbNewLine) As String
    If ra.Cells.Count = 1 Then Range2TXT = ra.Value & RowsSeparator$: Exit Function
    If ra.Areas.Count > 1 Then
        Dim ar As Range
        For Each ar In ra.Areas
            Range2TXT = Range2TXT & Range2TXT(ar, ColumnsSeparator$, RowsSeparator$)
        Next ar
        Exit Function
    End If
    arr = ra.Value
    For i = LBound(arr, 1) To UBound(arr, 1)
        txt = "": For j = LBound(arr, 2) To UBound(arr, 2): txt = txt & ColumnsSeparator$ & arr(i, j): Next j
        Range2TXT = Range2TXT & Mid(txt, Len(ColumnsSeparator$) + 1) & RowsSeparator$
    Next i
End Function

Function SaveTXTfile(ByVal filename As String, ByVal txt As String) As Boolean
    On Error Resume Next: Err.Clear
    Set fso = CreateObject("scripting.filesystemobject")
    Set ts = fso.CreateTextFile(filename, True)
    ts.Write txt: ts.Close
    SaveTXTfile = Err = 0
    Set ts = Nothing: Set fso = Nothing
End Function

[Serge_Bliznykov]

EducatedFool, посмотрите мой ответ тут:
Из буфера в файл txt

p.s. заметьте, я раньше написал!

[EducatedFool]

Сообщение от Serge_Bliznykov

p.s. заметьте, я раньше написал!

Вот как всегда - сначала ответил в теме, а потом обнаружил её дубль с ответом))
Да уж, Serge, в этот раз вам удалось меня опередить))

PS: Темы объединил.

[imber]

Мне не надо писать в файл, вопрос задан как пример,
а файл может быть jpg, bmp, psd

[EducatedFool]

' Здесь вставка не срабатывает
Selection.Paste

А она и не будет работать.
Объект Selection относится к приложению Excel, а команда Paste - к стороннему приложению.

Попробуйте посылать приложению комбинацию клавиш Ctrl + V
В виде кода это выглядит так: (проверил - всё работает)

Sub test()
    Selection.Copy
    Shell "NOTEPAD.EXE", vbNormalFocus
    For i = 1 To 1000: DoEvents: Next ' ждём, пока приложение запустится
    Application.SendKeys "^v" ' вставка из буфера обмена в активное приложение
End Sub

[Evgeniy_Rindya]

Добрый день, уважаемые форумчане!

Есть столбец с данными, например 150 тыс. значений, а нужно, чтоб данные из этого столбца, сохранялись в файл txt по 3 тыс. значений.
Т.е. чтоб на выходе получить 50 файлов, в каждом из которых 3 тыс. строк.

Можно это сделать автоматически?

Я пока смог сделать только вот так:

Sub Макрос1()  
  
    Range("A2:A3000").Select  
    Range("A3000").Activate  
    Selection.Copy  
      
    Shell "NOTEPAD.EXE", vbNormalFocus  
    For i = 1 To 1000: DoEvents: Next ' ждем пока приложение запустится  
    Application.SendKeys "^v" ' вставка из буфера обмена в активное приложение  
    
    Rows("2:3000").Select  
    Application.CutCopyMode = False  
    Selection.Delete Shift:=xlUp  
    Range("B2").Select  
End Sub

Но получившийся txt нужно сохранять вручную, а можно, чтоб автоматически создавались txt документы, например с названием 1.txt, 2.txt ... n.txt и в них автоматически происходила запись данных в столбец?

[valerij]

Нечто похожее мне также было нужно, решение Здесь
Может что либо подскажет!!!