Упростить макрос

[valerij]

Как мона это упростить???

i = CLng(Left(Sheets(12).Range("D1"), 2))
If i = 1 Then выбор = 35
-----------------------
If i = 31 Then выбор = 1355

Значение, выбор, меняется с шагом 44

[EducatedFool]

    i = CLng(Left(Sheets(12).Range("D1"), 2))
    выбор = 35 + (i - 1) * 44

PS: Тебе на лень было прописывать все эти строки вручную? На калькуляторе считал?

[valerij]

Сообщение от EducatedFool

Тебе на лень было прописывать все эти строки вручную? На калькуляторе считал?

Игорь, какой калькулятор, а Excel, зачем, A1 = if i = 1, В1 = then выбор =, С1=35, С2 = С1+44, мышкой потянул до 31 и все! Копирую А1:С31 и в модуль.

Сбил меня!!
СПАСИБО!!!
Ну голова-ааа!!!

[valerij]

Все ли, так(я уже все подзабыл, большой перерыв был....)??

Private Sub Worksheet_Change(ByVal Target As Excel.Range)
Dim iL%, i%, a%, b%
Application.EnableEvents = False
[a15] = Sheets(11).[L6]
[a16] = Sheets(11).[k6]
i = CLng(Left(Sheets(12).Range("D1"), 2))
If [h15] = "НЕТ" Then a = 1: b = 5: GoTo 1
If [h16] = "НЕТ" Then a = 6: b = 9: GoTo 1
GoTo 3
1:
выбор = 35 + (i - 1) * 44
        For iL = a To b
        хз = хз + Sheets(iL).Cells(выбор, 6)
        сумма = сумма + Sheets(iL).Cells(выбор, 12)
         With Sheets(12)
            .Cells(16, 2) = хз
                .Cells(16, 4) = сумма
                .Cells(15, 2) = .Cells(12, 2) - .Cells(16, 2)
            .Cells(15, 4) = .Cells(12, 4) - .Cells(16, 4)
         End With
        Next iL
3:
Application.EnableEvents = True
End Sub

[SAS888]

Все ли, так??

Кроме Вас, этого не скажет никто. Другое дело, если Вам нужны советы по оптимизации кода.
1. Вместо функции CLng(...), в данном случае, лучше использовать функцию Val(...). Это не допустит возможную ошибку, в случае, если аргумент функции невозможно преобразовать в число. Т.е. текст и т.п.
2. По-возможности, не используйте оператор безусловного перехода GoTo. Это, во-первых, очень часто ни к чему, во-вторых, тормозит выполнение процедуры и расходует лишнюю память.
3. Держитесь подальше от функций без значка "$" таких как Left, Mid и т.п., т.к. они возвращают значение типа Variant. Обычные функции Left$ и Mid$ возвращают результат немедленно, без его неявного преобразования в Variant.
4. Все переменные лучше объявлять. В данном случае, если переменные выбор, хз и сумма не объявлены глобально, то нужно определить их тип в коде данной процедуры. (Убедитесь, что объявленные Вами переменные типа Integer будут действительно целыми числами и не превысят предел).
5. Рациональнее, сначала проверить условия, а затем выполнять (если это нужно) требуемые действия. У Вас же, выполняется действие безусловно (вычисление переменной i), а затем проверяются условия. При определенных условиях осуществляется выход из процедуры. Значит выполненное действие было ни к чему.
6. Учитывая все вышесказанное, Ваш код можно чуть оптимизировать (не с точки зрения уменьшения кода, а с точки зрения корректности и скорости), примерно так:

Private Sub Worksheet_Change(ByVal Target As Excel.Range)
    Dim iL%, a%, b%, выбор%, хз As Double, сумма As Double: Application.EnableEvents = False
    [a15] = Sheets(11).[L6]: [a16] = Sheets(11).[k6]
    Select Case "НЕТ"
        Case [h15]: a = 1: b = 5
        Case [h16]: a = 6: b = 9
        Case Else: Application.EnableEvents = True: Exit Sub
    End Select
    With Sheets(12)
        выбор = 35 + (Val(Left$(.[D1], 2)) - 1) * 44
        For iL = a To b
            хз = хз + Sheets(iL).Cells(выбор, 6): сумма = сумма + Sheets(iL).Cells(выбор, 12)
            .[B16] = хз: .[D16] = сумма: .[B15] = .[B12] - .[B16]: .[D15] = .[D12] - .[D16]
    Next: End With: Application.EnableEvents = True
End Sub

[valerij]

Сообщение от SAS888

если Вам нужны советы по оптимизации кода

Сергей!!!!!!!!
Огромное СПАСИБО!!!
______________
| ^^пиво^^ \\|""\\_,_
|___________||___|__|)
(@)(@)""*|(@)(@)**(@)

[valerij]

Можно этот код, упростить и что бы формулы не светились, только значения?

With ActiveCell
    Range("N3").Select
    .FormulaR1C1 = _
        "='F:\Док_Офис\Офисный Учет\2010\4_Квартал\[Сбор 4 кв. 2010.xls]ОБЩИЕ'!R5C6"
    Range("N4").Select
    .FormulaR1C1 = _
        "='F:\Док_Офис\Офисный Учет\2010\4_Квартал\[Сбор 4 кв. 2010.xls]ОБЩИЕ'!R6C6"
    Range("N5").Select
    .FormulaR1C1 = _
        "='F:\Док_Офис\Офисный Учет\2010\4_Квартал\[Сбор 4 кв. 2010.xls]ОБЩИЕ'!R7C6"
    Range("N6").Select
    .FormulaR1C1 = _
        "='F:\Док_Офис\Офисный Учет\2010\4_Квартал\[Сбор 4 кв. 2010.xls]ОБЩИЕ'!R3C6"
    Range("N7").Select
    .FormulaR1C1 = _
        "='F:\Док_Офис\Офисный Учет\2010\4_Квартал\[Сбор 4 кв. 2010.xls]ОБЩИЕ'!R4C6"
    Range("N8").Select
    .FormulaR1C1 = _
        "='F:\Док_Офис\Офисный Учет\2010\4_Квартал\[Сбор 4 кв. 2010.xls]ОБЩИЕ'!R9C6"
    Range("N9").Select
    .FormulaR1C1 = _
        "='F:\Док_Офис\Офисный Учет\2010\4_Квартал\[Сбор 4 кв. 2010.xls]ОБЩИЕ'!R11C6"
End With

[SAS888]

Попробуйте так:

Sub Main()
    Dim s As String, i As Integer, a(): Application.ScreenUpdating = False
    s = "='F:\Док_Офис\Офисный Учет\2010\4_Квартал\[Сбор 4 кв. 2010.xls]ОБЩИЕ'!"
    a = Array("R5C6", "R6C6", "R7C6", "R3C6", "R4C6", "R9C6", "R11C6")
    For i = 3 To 9: Cells(i, "N").FormulaR1C1 = s & a(i - 3): Next
    [N3:N9].Value = [N3:N9].Value
End Sub

[valerij]

Сообщение от SAS888

Попробуйте так

Сереж, как всегда, СУПЕР!!!!
Спасибо!!!!