замена текста

[evdss]

Здравствуйте! Подскажите, пожалуйста, как можно в выделенном столбце в каждой ячейке перед текстом подставить пробел?
например:
сельское хозяйство
промышленность
рыболовство и т.д.
надо:
сельское хозяйство
промышленность
рыболовство

[The_Prist]

Разници не заметил. Но если по описанию:
-в любом пустом столбце пишите формулу: =" "&A1
-в столбце А непосредственно текст, к которому пробел надо добавить;
-заменяете формулы на значения в столбце с новой формулой;
-теперь можете заменить этим столбцом исходные данные.

[evdss]

Пробелы в тексте не видны. Сейчас делаю формулой, но очень неудобно, так как этих таблиц много и надо во всех править. так конечно может кто поможет макросом

[DiemonStar]

Sub AddSpace()
  For I = 1 To Cells(Rows.Count, 1).End(xlUp).Row
    Range("A" & I) = " " & Range("A" & I)
  Next I
End Sub

можно так попробовать сделать) работает только с активным листом

[evdss]

спасибо большое, все работает

[Скрипт]

Код работает с выделенными столбцами.

Чтобы выбрать столбцы, в которых нужно обработать данные, достаточно выделить только одну ячейку, находящуюся в нужном столбце.
Обрабатываются все ячейки в выбранных столбцах, кроме пустых ячеек.

Sub Procedure_2()

    Dim myColumns As Excel.Range
    Dim myFind As Excel.Range, myAddress As String
    
    '1. Даём имя "myColumns" выделенным столбцам.
    'Через это имя будем обращаться к ячейкам выделенных столбцов.
    'Чтобы не обрабатывать все ячейки в столбцах (чтобы было быстрее),
        'берём только используемые части столбцов.
    Set myColumns = Application.Intersect(Selection.EntireColumn, ActiveSheet.UsedRange)
    
    '2. Обрабатываем ячейки в выделенных столбцах.
    '2.1. В столбцах могут быть и пустые ячейки.
        'Чтобы пропустить пустые ячейки, буду использовать команду "Find".
        'С помощью команды "Find" будут искаться ячейки,
        'которые содержат хотя бы один любой символ.
    'У команды "Find" надо указывать все параметры, т.к.
        'команда "Find" связана с окном "Найти и заменить" и
        'параметры окна "Найти и заменить" могут повлиять на результаты
        'поиска с помощью команды "Find".
    'What:="?" - знак вопроса в данном случае - это специальный символ.
    Set myFind = myColumns.Find(What:="?", LookIn:=xlValues, _
        LookAt:=xlPart, SearchOrder:=xlByColumns, SearchDirection:=xlNext, _
        MatchCase:=False, SearchFormat:=False)
    
    'Если есть результат поиска.
    If Not myFind Is Nothing Then
    
        '2.2. Запоминаем адрес первой найденной ячейки,
            'чтобы потом остановить цикл.
        myAddress = myFind.Address
        
        Do
            '2.3. Добавляем пробел в ячейку.
            'Переменная "myFind" представляет собой ячейку,
                'где было что-то найдено.
            myFind.Value = " " & myFind.Value
            
            '2.4. Продолжаем поиск.
            Set myFind = myColumns.FindNext(myFind)
            
        Loop While myFind.Address <> myAddress
        
    End If
    
End Sub

Примечание

1. Команда Find не всегда работает, если на листе есть объединённые ячейки. Поэтому, если есть объединённые ячейки, то вместо команды Find нужно использовать что-нибудь другое.
2. Чтобы код работал быстрее, можно отключить с помощью самого кода на время работы кода:
   1. обновление монитора;
   2. обработку событий;
   3. пересчёт формул.

[Hugo121]

Alt+F11
Ctrl+G
[a1:a3]=[" " & A1:A3]
Enter