Cells. Application-defined or object-defined error

[mau6]

Добрый день,

Помогите разобраться. Есть код

Sub GetValues(f As Variant)
 
Dim last_row As Long, last_col As Long
Dim wb As Workbook
Set wb = Excel.Application.Workbooks.Open(f)
 
For Each sh In wb.Sheets
    With sh
         last_row = .Cells.Find("*", .Range("A1"), xlFormulas, , xlRows, xlPrevious).Row
        last_col = .Cells.Find("*", .Range("A1"), xlFormulas, , xlColumns, xlPrevious).Column
        .Range(.Cells(1, 1), .Cells(last_row, last_column)).Copy
        .Range(.Cells(1, 1), .Cells(last_row, last_column)).PasteSpecial xlPasteValues
    End With
Next
 
wb.Close
End Sub

На строчке .Range(.Cells(1, 1), .Cells(last_row, last_column)).Copy выскакивает Application-defined or object-defined error 1004.
Помогите , пожалуйста, разобраться, почему так происходит?
Спасибо!

[EducatedFool]

А так не проще?

Sub GetValues(ByVal f As String)
    Dim sh As Worksheet
    With Workbooks.Open(f)    ' открываем файл
        For Each sh In .Worksheets    ' перебираем листы
            ' заменяем все формулы значениями
            sh.UsedRange.Value = sh.UsedRange.Value
        Next
        .Close True ' закрываем файл с сохранением
    End With
End Sub

[Skif-F]

а где определяется last_column? или переименуй её в last_col:

.Range(.Cells(1, 1), .Cells(last_row, last_col)).Copy

[mau6]

Сообщение от Skif-F

а где определяется last_column? или переименуй её в last_col:

.Range(.Cells(1, 1), .Cells(last_row, last_col)).Copy

блин, конечно last_col! простая невнимательность стоила мне фиг знает сколько времени, большое спасибо!

[mau6]

Сообщение от EducatedFool

А так не проще?

Sub GetValues(ByVal f As String)
    Dim sh As Worksheet
    With Workbooks.Open(f)    ' открываем файл
        For Each sh In .Worksheets    ' перебираем листы
            ' заменяем все формулы значениями
            sh.UsedRange.Value = sh.UsedRange.Value
        Next
        .Close True ' закрываем файл с сохранением
    End With
End Sub

спасибо за предложенный вариант! он гораздо проще.

[Skif-F]

Используй:

 Option Explicit    'Все переменные должны быть объявлены

и подобные ошибки будет обнаруживать легче