Форматирование ячейки по условию

[Severny]

Добрый день!
В файле выложен пример собственной разработки.
Задача такая: если белые ячейки в строке моей таблицы не пусты то в значение в закрашеной должно становится курсивом, если только одна из белых ячее пуста то соответственно должно делаться не курсивом
В примере я выложил собственный макрос но он не отслеживает собитие в в белых ячейках и все делает если только я изменяю желтую, хотя желтая вводится первая, а уже вслед за ней заполняются все остальные ячейки строки. Пример - модель реальной ,более громоздкой задачи.

[Казанский]

Без макроса, условное форматирование:

[IgorGO]

Ваш вопрос, как бы уже содержит ответ:
условное форматирование (и не надо макросы писать, которых Вы написать не можете).
в условное форматирование вот этот

=СЧЁТЗ(RC5:RC6)=2

[Severny]

Казанский, IgorGO спасибо!
IgorGO, я думаю если бы Вы не пробовали программировать, то и не научились бы программировать Собственно вот так же и я. Пытаюсь научится писать макросы, использую возникающие вопросы в процессе моей работы. Хотелось бы решить и данный пример с помощью макроса. Если поможете, я буду благодарен, если нет - тоже
Казанский, можно и Вас попросить помочь с макросом.

[Казанский]

Попробуйте. Вычисления оптимизированы для случая, когда меняется сразу несколько ячеек заданного диапазона: просматриваются только те строки диапазона, в которых произошло изменение.

Private Sub Worksheet_Change(ByVal Target As Range)
Dim r As Range, cc&, c1&, r1&
On Error Resume Next
With Range("E18:F20")   'диапазон, от которого зависит условное форматирование
                        'можете изменить его тут, в одном месте - все остальное пересчитается
    cc = .Columns.Count
    c1 = .Column - 1
    r1 = .Row - 1
    For Each r In Intersect(Target, .Cells).Rows
        Cells(r.Row, c1).Font.Italic = Application.Count(.Rows(r.Row - r1)) = cc
    Next
End With
End Sub

[IgorGO]

если бы Вы не пробовали программировать, то и не научились бы

с этим не поспоришь...
но более интесивный путь освоить программирование, разбираться и писать самому. очевидно, что в данной ситуации, контролировать необходимо не те ячейки, в которых меняем стиль шрифта, а ячейки правее. Set rg = [e18:f20] - задает габариты контролируемого диапазона.
пробуйте этот

Private Sub Worksheet_Change(ByVal Target As Range)
  Dim rg As Range, cl As Range, cc As Long, bc As Long, ec As Long
  Set rg = [e18:f20]
  bc = rg.Column: ec = rg.Columns.Count: cc = bc - 1: Set rg = Application.Intersect(Target, rg)
  If rg Is Nothing Then Exit Sub
  For Each cl In rg.Rows
    Cells(cl.Row, cc).Font.Italic = WorksheetFunction.CountA(Cells(cl.Row, bc).Resize(1, ec)) = ec
  Next
  Set rg = Nothing
End Sub